Discussion :

[aleximan]

Bonjour,
J'ai un formulaire de démarrage que je paramètre dans les options de la base.
J'ai un bouton d'initialisation des liens (lorsque je met la base sur le serveur) qui reparamètre toutes mes tables attachées.
A la fin de cette procèdure, je souhaiterai pouvoir définir un nouveau formulaire de démarrage (maintenant que les liens sont re-créés, je n'ai plus besoin du premier formulaire).
Est-ce possible ?
Merci de votre aide

[tee_grandbois]

Bonjour,
essaie la propriété StartUpForm :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CurrentDb.Properties("StartUpForm").Value = "MonFormdeDemarrage"

[tee_grandbois]

J'avais déjà oublié que ce n'est pas si simple avec les propriétés de certains objets vu que c'est dynamique quelquefois (c.à.d. qu'elles n'existent pas tant qu'elles ne sont pas créées), je livre donc un code trouvé sur le net :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Sub SetNewFEMDBOptions()
Dim intX As Integer
 
    intX = AddAppProperty("StartUpForm", dbText, "Sample Start Up Form")
    intX = AddAppProperty("AppTitle", dbText, "Sample Application Title")
    intX = AddAppProperty("StartUpMenuBar", dbText, "Sample Startup Menu Bar")
    intX = AddAppProperty("StartUpShowDBWindow", dbBoolean, False)
 
End Sub
 
Function AddAppProperty(strName As String, varType As Variant, _
        varValue As Variant) As Integer
    Dim prp As Property
    Const conPropNotFoundError = 3270
 
    On Error GoTo AddProp_Err
    CurrentDb.Properties(strName) = varValue
 
    AddAppProperty = True
 
AddProp_Bye:
    Exit Function
 
AddProp_Err:
    If Err = conPropNotFoundError Then
        Set prp = CurrentDb.CreateProperty(strName, varType, varValue)
        CurrentDb.Properties.Append prp
        Resume
    Else
        AddAppProperty = False
        Resume AddProp_Bye
    End If
End Function

[aleximan]

Dans mon cas le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CurrentDb.Properties("StartUpForm").Value = "MonFormdeDemarrage"

fonctionne
Merci beaucoup tee_grandbois