Discussion :

[boboss123]

Bonjour,


J'ai une liste de correspondance de mots qui doivent être remplacé par un autre mot.
Ex : si la chaine contient le mot tutu, tutu doit être remplacé par toto. si la chaine contient le mot titi, titi doit etre remplacé par tata...

J'ai vu que la fonction SUBSTITUE permet de remplacer un mot par un autre mais comment faire pour gérer une liste de mot à remplacer ? (je peux mettre des SUBSTITUE dans des SUBSTITUE mais c'est super lourd à gérer)

Merci d'avance

[riaolle]

Bonjour,
Tu peux peut-être utiliser RECHERCHEV pour trouver dans ta liste par quel mot tu dois remplacer.

[boboss123]

je ne vois pas trop comment faire avec cette fonction vu qu'il faut au départ balayer la liste (et non pas rechercher une valeur figée dans une liste)

[Caracthale]

je ne vois pas trop comment faire avec cette fonction vu qu'il faut au départ balayer la liste (et non pas rechercher une valeur figée dans une liste)

Si la contrainte est de le faire en Excel uniquement avec des formules, il y a au moins deux façons simples et un peu bourrines de le faire.
Tout dépend du contexte de besoin et d'utilisation.

1 Si tu veux juste appliquer ta liste de temps en temps à une chaîne de texte particulière et que ta liste soit aisément maintenable.
Exemple : Tu écrits le texte en entrée dans une cellule. Le nouveau texte est disponible dans une autre.

2 Si tu veux pouvoir appliquer ta fonction à plusieurs champs texte en ligne ou en colonne quitte à gâcher de la puissance de calcul.
Exemple : Tous les textes sont sur une ligne ou une colonne. Les nouveaux textes sur une autre ligne ou colonne.

Si tu as la possibilité de faire du VBA dans ton fichier, ton moteur de recherche préféré pourra t'expliquer comment créer une "substitue" sur mesure qui travaille sur une liste de texte à remplacer.

Dans chacun des trois cas je peux te fournir la méthodologie appropriée et les formules/code VBA.

[boboss123]

Je cherche une solution avec 4 colonnes de manière à pouvoir facilement modifier mes différents éléments :
- liste ancien texte
- liste nouveau texte
- liste chaines à traiter
- liste de sortie

=> Pas besoin que ça soit rapide (car 500 chaines a traiter max)
=> Si possible utiliser une formule

=> j'ai peut-être trouvé une solution mais il faudrait une colonne qui me renvoie le numéro de la ligne de l'éléemnt trouvé avec RECHERCHEV

Merci d'avance

[Caracthale]

En mode bourrin pas optimisé du tout je te propose la solution suivante en 2 onglets.
Ce n'est pas de la top conception mais çà répond au besoin...

Onglet 1

Liste ancien texte	Liste nouveau texte
Ancien texte 1	Nouveau texte 1
Ancien texte 2	Nouveau texte 2
Ancien texte 3	Nouveau texte 3

Onglet 2

		=SI(INDEX('Onglet 1'!$A$1:$B$500;COLONNE()-1;1)<>"";INDEX('Onglet 1'!$A$1:$B$500;COLONNE()-1;1);"COLONNE_STOP")
liste de sortie	liste chaines à traiter	=SI(INDEX('Onglet 1'!$A$1:$B$500;COLONNE()-1;2)<>"";INDEX('Onglet 1'!$A$1:$B$500;COLONNE()-1;2);"COLONNE_STOP")
=C3	Chaines à traiter 1 - Ancien texte 1	=SI(C$1="COLONNE_STOP";$B3;SUBSTITUE(D3;C$1;C$2))
=C4	Chaines à traiter 2 - Ancien texte 2	=SI(C$1="COLONNE_STOP";$B4;SUBSTITUE(D4;C$1;C$2))

Étendre la dernière ligne autant de fois que besoin.
Étendre la dernière colonne autant de fois que besoin (jusqu'à la COLONNE_STOP inclus).

Attention si tu as plus de valeurs de texte à substituer que le nombre de colonne disponibles dans ton fichier Excel, il faut faire plusieurs onglet ou passer à une autre méthode.

[papouclo]

Bonjour,
Autre possibilité avec formule, les listes ancien texte, nouveau texte, chaines à traiter, chaines traitées étant respectivement en colonnes A, B, D, E, la formule en E2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SUBSTITUE(D2;INDEX($A$2:$A$4;SOMMEPROD({1;2;3}*ESTNUM(CHERCHE($A$2:$A$4;D2))));INDEX($B$2:$B$4;SOMMEPROD({1;2;3}*ESTNUM(CHERCHE($A$2:$A$4;D2)))))

Dans la formule de l'exemple choisi, la matrice {1;2;3} peut si l'on veut se remplacer par LIGNE(1:3) ou encore par LIGNE($A$2:$A$4)-1.
Une remarque : ceci ne fonctionne qu'à la condition qu'une chaine à traiter ne comporte pas plus d'un texte à remplacer. Dans le cas contraire, il vaut mieux se tourner vers le VBA.
Cordialement
Claude

[boboss123]

ok merci beaucoup