Discussion :

[Andre49]

Bonjour,

Une question qui devrait bien avoir déjà une réponse quelque part, mais que je n'ai pas trouvée...

En maths, la relation de division euclidienne de a par b dans Z (entiers relatifs) est l’unique écriture : a=bq+r, où ∶ 0≤r<|b|
La division dite euclidienne impose que le reste soit positif ou nul, et bien sûr inférieur à la valeur absolue du diviseur..

Par exemple, pour diviser -53 par -17 , on écrira : -53 = -17 x 4 + 15 ; on a bien : reste = 15 < |-17|

Au risque d'en faire trop, je précise que le reste devant être positif, il faut calculer -17 x ?, de sorte que cette valeur soit ≤-53, afin de pouvoir rajouter un reste >=0 pour arriver à -53 ; ceci impose donc le produit -17 x 4.

Ceci dit, je suis intrigué car je pensais que la fonction MOD donnait justement le reste de la division euclidienne, mais ce n'est pas le cas. Dans mon tableur, j'obtiens : MOD(-53;-17) = -2

Certes, il est bien vrai que : -53 = -17 x 3 - 2, mais ce n'est pas la définition d'une division euclidienne.

Y a-t-il une façon d'obtenir le bon reste, qui devrait être +15 dans ce cas de figure ?

Merci.

[Marc-L]

Bonjour,

la fonction MOD comme pourtant énoncé dans l'aide d'Excel renvoie juste le reste d'une division !

Pour une division "euclidienne" il suffit donc d'écrire sa propre formule …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Stockholm, London, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

[Menhir]

En supposant que le divisé et le diviseur soient de même signe.
En supposant que le premier est en A1 et le second en A2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOD(A1;A2)-SI(MOD(A1;A2)<0;A2;0)

Encore plus simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOD(A1;ABS(A2))

Il doit sans doute y avoir une bonne dizaine d'autres formules pour obtenir ce résultat.

[Andre49]

Encore plus simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOD(A1;ABS(A2))

Effectivement... Merci !

[papouclo]

Bonjour ,
Dans les exemples ci-dessous, les formules des colonnes C et D semblent fonctionner dans tous les cas. Celles traditionnellement utilisées semblent ne fonctionner que pour des diviseurs positifs quel que soit le signe du dividende.

La formule de C2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ENT(PLANCHER.MATH(A2;B2)/B2)

La formule de D2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=A2-B2*ENT(PLANCHER.MATH(A2;B2)/B2)

Cordialement
Claude

[papouclo]

Bonjour,
Toutes mes excuses mais je devais somnoler quand j'ai envoyé ma proposition précédente. PLANCHER.MATH(dividende;diviseur) étant un multiple de diviseur,
le quotient PLANCHER.MATH(dividende;diviseur) / diviseur est entier et il n'est pas nécessaire de faire appel à la fonction ENT.
Une formule donnant dans tous les cas un quotient euclidien est donc simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= PLANCHER.MATH(dividende;diviseur) / diviseur

et une formule donnant dans tous les cas le reste est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= dividende - PLANCHER.MATH(dividende;diviseur)

Mais une formule plus simple et toujours valable pour calculer le reste est celle de Menhir :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= MOD ( dividende ; ABS(diviseur) )

et une formule pour le quotient euclidien est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= SIGNE(diviseur) * ENT (dividende / ABS(diviseur) )

Cordialement
Claude