Discussion :

[P_LHOS]

Bonjour à toutes et à tous,

Je publie ce message car je cherche à réaliser un graphique que j'ai pu faire sous excel grâce à un tableau croisé dynamique et qui se présente comme ça :



Pour ce faire, j'ai utilisé ce tableau dynamique :



Je voulais savoir si ce graphique est réalisable sur sas en conservant d'un côté les fréquences et de l'autre les pourcentages? Faut-il passer par une proc freq pour le tracer ou quelles sont les options?
Je vous remercie d'avance pour votre temps et vos réponse!

Bonne journée!

[olivier.decourt]

Bonjour.
Oui c'est faisable sous SAS. Ce n'est pas forcément nécessaire de passer par la proc Freq au préalable, mais ça peut simplifier le code.
Regarde du côté de la proc SGPLOT, les instructions VBAR ou VBARPARM (si tu as déjà tout calculé avec Freq), VLINE ou SERIES pour la courbe, l'option Y2AXIS pour l'axe secondaire.

[olivier.decourt]

Re-bonjour.
J'ai été un peu optimiste hier soir. Ce qui rend le graphique un poil plus compliqué à produire c'est le mélange entre des données détaillées par sous-groupes (les barres groupées) et la courbe qui n'est pas détaillée.
La solution la plus simple, si tu as un SAS 9.4 assez récent, est de tout calculer à l'avance (proc Freq et un peu d'étape Data) et d'utiliser une instruction VBARBASIC pour les bâtons et SERIES pour la courbe.
Ci-dessous un exemple avec les données SASHELP.CLASS qui devrait ressembler à ce que tu veux faire.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
PROC FREQ DATA=sashelp.class ;
  TABLE age * sex / LIST NOPERCENT NOCUM ;
  TABLE age / NOCUM ;
  ODS OUTPUT list = work.freq_detail 
             oneWayFreqs = work.freq_agg ;
RUN ;
DATA work.freq_graph ;
  MERGE work.freq_detail (RENAME=(frequency=f))
      work.freq_agg (RENAME=(percent=p)) ;
  BY age ;
  KEEP age sex f p ;
  IF FIRST.age THEN p = p / 100 ;
  ELSE p = . ;
  FORMAT p NLPCT12.2 ;
RUN ;
PROC SGPLOT DATA=work.freq_graph ;
  VBARBASIC age / GROUP=sex GROUPDISPLAY=CLUSTER
                  RESPONSE=f STAT=SUM 
                  ;
  SERIES X=age Y=p / Y2AXIS LEGENDLABEL="TOTAL %"
                     LINEATTRS=(THICKNESS=3) ;
  XAXIS DISPLAY=(NOLABEL) ;
  YAXIS DISPLAY=(NOLABEL) INTEGER GRID ;
  Y2AXIS DISPLAY=(NOLABEL) ;
  KEYLEGEND / POSITION=RIGHT NOBORDER ;
RUN ;

[P_LHOS]

Bonjour,

Merci du conseil Olivier, je suis sur la bonne voix! Je viens de voir ton message à 9h30, je vais tester ça. Je poste quand même celui-ci.
Cependant, j'ai un problème avec la vline qui pour l'instant se démultiplie pour chaque tranche de score, alors que je voudrais une seule ligne pour le total. Je ne suis pas encore passer par la sortie de ma proc freq et du coup le code donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PROC SGPLOT DATA = WORK.STAT_TEST ;
VLINE NOTET/ response=freq group=scoring Y2AXIS;
 VBAR NOTET / GROUP = SCORING GROUPDISPLAY = CLUSTER;
 TITLE 'SCORE SELON LA NOTE DU CLIENT';
RUN;

J'obtiens le graphique suivant :



En revanche, quand je passe par la sortie de ma proc freq, j'utilise le code suivant pour récupérer le VBAR de chaque modalité :

PROC SGPLOT DATA = WORK.DATA_GRAPH_ALL ;
VLINE NOTET/ response=pourcentage Y2AXIS;
VBAR NOTET / response=S_0_30;
VBAR NOTET / response=S_30_50;
VBAR NOTET / response=S_50_75;
VBAR NOTET / response=S_75_100;
TITLE 'SCORE SELON LA NOTE DU CLIENT';
RUN;

Et j'obtiens le graphique suivant qui n'est pas loin de ce que je souhaite :



Dans les deux cas j'y suis presque mais il faudrait que je regroupe mes vline dans le premier code alors que j'utilise la fonction GROUP pour obtenir mon histogramme comme je le souhaite et qui me rend plusieurs courbes. Dans le second code, il faudrait que j'arrive à les désempiler pour obtenir 4 barres pour chaque note.

[P_LHOS]

Merci Olivier, c'est de la bombe!! J'ai plus qu'à retoucher les couleurs et c'est tout bon! Il me manquait une table au final pour pouvoir réaliser mon graphique!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
PROC FREQ DATA=work.stat_test ;
  TABLE notet * scoring / LIST NOPERCENT NOCUM ;
  TABLE notet / NOCUM ;
  ODS OUTPUT list = work.freq_detail 
             oneWayFreqs = work.freq_not ;
RUN ;
DATA work.freq_graph ;
  MERGE work.freq_detail (RENAME=(frequency=f))
      work.freq_not (RENAME=(percent=p)) ;
  BY notet ;
  KEEP notet scoring f p ;
  IF FIRST.notet THEN p = p / 100 ;
  ELSE p = . ;
  FORMAT p NLPCT12.2 ;
RUN ;
PROC SGPLOT DATA=work.freq_graph ;
  VBARBASIC notet / GROUP=scoring GROUPDISPLAY=CLUSTER
                  RESPONSE=f STAT=SUM 
                  ;
  SERIES X=notet Y=p / Y2AXIS LEGENDLABEL="TOTAL %"
                     LINEATTRS=(THICKNESS=3) ;
  XAXIS DISPLAY=(NOLABEL) ;
  YAXIS DISPLAY=(NOLABEL) INTEGER GRID ;
  Y2AXIS DISPLAY=(NOLABEL) ;
  KEYLEGEND / POSITION=RIGHT NOBORDER ;
RUN ;

Voici le rendu final du graphique sur mes données :




Encore merci olivier, et bon codage à tous!

[P_LHOS]

Bonjour à toutes et à tous, maintenant que j'ai réussi à sortir mon graphique, je cherche à ranger de façon décroissante mes modalités en fonction de l'effectif total. Je sais que sas le fait si l'on utilise un proc sort avant la proc sgplot mais existe-t-il un autre moyen de le réaliser avec la proc sgplot?
Merci d'avance!

[P_LHOS]

Bonjour,

J'ai trouver l'option de la proc sgplot qui permet de ranger les modalités de façon décroissante. Ca peut toujours intéresser quelqu'un :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
PROC SGPLOT DATA = WORK.STAT_TEST ;
TITLE 'Répartition des individus par filière et selon leur statut en effectif';
  VBAR FILIERE_APE/ GROUP = STATUT GROUPDISPLAY = CLUSTER dataskin=pressed CATEGORYORDER=RESPDESC;
  VLINE FILIERE_APE/ response=freq group=STATUT Y2AXIS;
  XAXIS DISPLAY=(NOLABEL noticks) ;
  YAXIS DISPLAY=(NOLABEL) INTEGER GRID ;
  Y2AXIS DISPLAY=(NOLABEL) ;
  KEYLEGEND / POSITION=RIGHT NOBORDER ;
RUN;

Tout se joue sur l'option CATEGORYORDER=RESPDESC qui classe automatiquement selon l'effectif ou la variable renseignée dans l'option RESPONSE= de VBAR.

Bonne journée et bon codage à tout le monde!