Discussion :

[kdiammond]

Bonjour à tous,
Dans un même document word, je souhaite ajouter 2 cases à cocher (onglet Développeur, saisie numérique) :
- Case A
- Case B
Si l'utilisateur coche la case A, je souhaite que la case B soit automatiquement cochée.
Comment faire ? J'ai cherché sur les forums, les tutoriels, impossible de trouver la réponse.
Merci
Kim

[Invité]

Bonjour,

Si vos contrôles sont des ActiveX et que votre document admet les macros, vous pourriez utiliser ce code (module standard à créer) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Option Explicit
 
Sub MettreAJourCheckBoxB()
 
Dim CheckBoxEnCours As InlineShape
Dim MonCheckBoxA As Object, MonCheckBoxB As Object
Dim DocEncours As Document
 
    On Error GoTo Fin
 
    Set DocEncours = ActiveDocument
 
    With DocEncours
         For Each CheckBoxEnCours In .InlineShapes
             Select Case CheckBoxEnCours.OLEFormat.Object.Name
                    Case "CheckBoxA"
                         Set MonCheckBoxA = CheckBoxEnCours.OLEFormat.Object
                    Case "CheckBoxB"
                         Set MonCheckBoxB = CheckBoxEnCours.OLEFormat.Object
             End Select
        Next CheckBoxEnCours
 
        If Not MonCheckBoxA Is Nothing And Not MonCheckBoxB Is Nothing Then
           Debug.Print "Avant : " & MonCheckBoxA.Name & " : " & MonCheckBoxA.Value & ", " & MonCheckBoxB.Name & " : " & MonCheckBoxB.Value
           If MonCheckBoxA = True Then MonCheckBoxB = True
           Debug.Print "Après : " & MonCheckBoxA.Name & " : " & MonCheckBoxA.Value & ", " & MonCheckBoxB.Name & " : " & MonCheckBoxB.Value
        End If
 
    End With
 
    GoTo Fin
 
Fin:
 
    Set MonCheckBoxA = Nothing
    Set MonCheckBoxB = Nothing
    Set DocEncours = Nothing
 
End Sub

Et pour lancer la macro, utilisez l'événement Click de l'objet. Dans le module ThisDocument de votre document :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Option Explicit
 
Private Sub CheckBoxA_Click()
        MettreAJourCheckboxB
End Sub

[kdiammond]

Bonjour Eric,
Merci beaucoup, c'est exactement la solution que je cherchais.
Bonne journée.