Discussion :

[robin des bulles]

bonjour à tous

Je n'arrive pas a fermer correctement excel malgré avoir lu beaucoup de sujets relatif ds la faq et sur le forum : excel.exe est toujour ds les processus et access ne re-execute pas ma boucle (erreur)

voici mon code simplifié (que la partie qui interagie avec excel) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Dim appexcel As Excel.Application
Dim wbexcel As Excel.Workbook

'boucle1
Set appexcel = CreateObject("Excel.Application")
appexcel.Visible = True

Set wbexcel = appexcel.Workbooks.Open(CheminCopieASPXLS)
'boucle2
Sheets("ASP").Cells(1 + j, 1) = rsASP("DateActe")
Sheets("ASP").Cells(1 + j, 2) = rsASP("CodeActe")
Sheets("ASP").Cells(1 + j, 3) = 0
Sheets("ASP").Cells(1 + j, 3) = rsASP("TauxPriseEnCharge") / 100
Sheets("ASP").Cells(1 + j, 4) = CCur(rsASP("TarifActe"))
Sheets("ASP").Cells(1 + j, 5) = CCur(rsASP("MontantDepasHono"))
Sheets("ASP").Cells(1 + j, 6) = Sheets("ASP").Cells(1 + j, 5) +
         Sheets"ASP").Cells(1 + j, 4) - (Sheets("ASP").Cells(1 + j, 3) *
         Sheets("ASP").Cells(1 + j, 4))

appexcel.CutCopyMode = False
'fin boucle2
wbexcel.Save
wbexcel.Close
appexcel.Quit

Set appexcel = Nothing
Set wbexcel = Nothing
'fin boucle1

Si quelqu'un a une idée merci d'avance

[pgz]

Bonjour,

Et quelle est l'erreur indiquée?

Sinon tu pourrais remplacer les Sheets... par wbexcel.Sheets...

ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
With wbexcel.Sheets("ASP")
    .Cells(1 + j, 1) = rsASP("DateActe")
    .Cells(1 + j, 2) = rsASP("CodeActe")
 
    ....
End With

Bon courage,

pgz

[robin des bulles]

Erreur d'execution '1004'
La méthode 'Sheet' de l'objet '_Global a échoué.

ok j'essaye merci

[robin des bulles]

AAAAAh MERCI ! c'est ça ! merci merci merci
ca fait un mois que je suis sur ce prog et que je suis obligé de tuer le processus manuellement et tu trouve en 20 min ( j'halucine ... ! )
grace a toi les 3/4 de mon prog va enfin pouvoir marcher : merchi encore
t le meilleur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Dim appexcel As Excel.Application
Dim wbexcel As Excel.Workbook
 
'boucle1
Set appexcel = CreateObject("Excel.Application")
appexcel.Visible = True
 
Set wbexcel = appexcel.Workbooks.Open(CheminCopieASPXLS)
'boucle2
With wbexcel.Sheets("ASP")
    .Cells(1 + j, 1) = rsASP("DateActe")
    .Cells(1 + j, 2) = rsASP("CodeActe")
    If IsNull(rsASP("TauxPriseEnCharge")) Then
        .Cells(1 + j, 3) = 0
    Else
        .Cells(1 + j, 3) = rsASP("TauxPriseEnCharge") / 100
    End If
    .Cells(1 + j, 4) = CCur(rsASP("TarifActe"))
    .Cells(1 + j, 5) = CCur(rsASP("MontantDepasHono"))
    .Cells(1 + j, 6) = .Cells(1 + j, 5) + .Cells(1 + j, 4) - 
                            (.Cells(1 + j, 3) * .Cells(1 + j, 4))
End With
 
 
appexcel.CutCopyMode = False
'fin boucle2
wbexcel.Save
wbexcel.Close
appexcel.Quit
 
Set appexcel = Nothing
Set wbexcel = Nothing
'fin boucle1