Discussion :

[zoumzoum59]

Bonjour a tous,

Je cherche le moyen de récupérer les différentes valeurs d'une plage de cellule est de colorer le fond des cellules de cet plage en fonction des différentes valeurs trouvé.
Déjà faut il passer par une plage de cellule ou un tableau ou autre ?
Ensuite comment récupérer les différentes valeurs ?
Et enfin comment affecter une couleur de fond a la cellule contenant la valeur ?

Voici en gros ma problématique.

Je sais cela fait beaucoup de questions mais pas beaucoup de codes, mais je ne voudrais pas démarrer soit a l'envers ou en ne sélectionnant pas la bonne méthode.

Je ne cherche pas non plus un code tout fait, mais un peu d'aide pour le construire me sera nécessaire, car je ne suis pas un pro en vba. d'ailleurs cela doit ce voir dans mes questions.

Merci d'avance pour toute l'aide que vous pourrez me donner.

[parmi]

Bonjour,

Tu pourrais utiliser la mise en forme conditionnelle

[zoumzoum59]

Bonjour parmi,

Je me suis posé la question, mais je ne vois pas comment gérer mes valeurs car elles ne sont pas défini a l'avance, je sais juste qu'il y a dans une plage de 4 colonnes et entre 1 et 400 lignes une dizaine maximum de valeurs différentes qui se retrouve plusieurs fois dans cette plage de cellule.

[Menhir]

Je ne vois pas comment gérer mes valeurs car elles ne sont pas défini a l'avance

C'est pour cela que Parmi ( ) a parlé de mise en forme CONDITIONNELLE.

Il s'agit d'une mise en forme pouvant s'adapter instantanément à une condition comme par exemple la valeur contenue dans la cellule.
Et cela, sans écrire de code VBA.

Regarde l'icone "Mise en forme conditionnelle" dans le ruban Accueil.
Et si tu veux apprendre comment ça marche, voir http://silkyroad.developpez.com/Exce...onditionnelle/

[zoumzoum59]

Merci Menhir pour ta précision,

Mais je ne vois toujours pas comment je peux faire une mise en forme conditionnelle sur une plage de cellule avec une dizaine de valeurs différentes dont je ne connais rien.
Je sais juste quelles sont différentes et qu'il y a des doublons de ces valeurs dans la plage.
je n'ai pas de référence de base pour faire une comparaison.

[zoumzoum59]

Voici un exemple de ma plage de cellule, la position des données sont aléatoire et les valeurs aussi.

Sur quoi pourrais je me baser pour faire une MFC ?

[parmi]

Effectivement, ce n'est pas évident...

Si tu connais la plage que tu vises, tu peux boucler chaque cellule et emmagasiner les valeurs uniques dans un tableau (ou chaîne de caractères, ou collection, ou dictionnaire...)

Par la suite (ou en même temps), il te faut déterminer une couleur pour chacune des valeurs.

Tu pourrais avoir une feuille avec les différentes couleurs que tu veux utiliser de la ligne 1 à X
À la 1ere occurrence d'une valeur, tu lui attribues la couleur en ligne 1. À la 2e valeur, la couleur de la ligne 2,...

[zoumzoum59]

Merci parmi de revenir sur mon cas,

Oui je connais la plage, a part la profondeur en ligne et oui j'avais éventuellement pensé au dictionnaire même si je ne sais pas si je serais capable de le coder.
Ensuite ne peut on pas mettre des couleur dans un tableau pour les juxtaposer avec les valeurs, parce que je ne voudrais pas spécialement créer une feuille avec des couleur, mais s'il le faut pourquoi pas.
Ou alors je délire un max un dictionnaire avec des valeur et comme clé des couleurs.
Peux tu me dire si il y a quelque choses dans ce que je viens de citer qui est plausible.

[patricktoulon]

si tu ne veux pas recommencer dictionnaire (valeur/couleu) a chaque demarrage de ton fichier tu peux enregistrer des names comme ca tu garde tout meme en fermant le fichier

pour 2002 ca fait une sorte de MFC

que tu gere dans l'evenement change
voir meme charger un dico avec les names histoire d'accelerer la cadence
a mediter

[parmi]

Oui, tu pourrais créer un tableau avec la valeur des couleurs que tu veux utiliser.

Ça dépend aussi combien de valeurs différentes tu peux avoir.
ColorIndex te donne un certain nombre de choix.
Color t'en donne plus, mais ça complique si tu veux passer par des valeurs RGB de couleurs...

À chaque fois que tu rencontres une valeur, mets-la dans une String avec un séparateur quelconque si elle n'est pas déjà là en vérifiant avec Instr().

Donc, au début de ta macro, tu crées ton tableau de couleur.
Et tu initialises une variable compteur qui s'incrémente à chaque fois que tu rencontres une nouvelle valeur.
Tu mets donc la couleur avec l'index de ce compteur à la valeur rencontrée.

Sans avoir testé, je pense que ça pourrait fonctionner assez facilement...

[patricktoulon]

allons parmi pense aux names
noublie pas qu'une variable tableau dico et collection compris se decharge a la fermeture du fichier ou de l'application

les memoriser dans un name te permet de garder ta pseudo MFC

je dis MFC car on peut memoriser plusieurs propriétés comme ca pas que le interior
ca permet de sepasser d'un sheets pour memoire

regarde
j'ajoute un name "toto"au quel je donne le contenu "3"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub ajout_regle()
    With ActiveWorkbook.Names("toto"): .Name = "toto": .RefersToR1C1 = "=3": End With
End Sub

maintenant dans l'evenemement change du sheet je fait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    For Each n In ActiveWorkbook.Names
        If n.Name = Target.Value Then 
Target.Interior.ColorIndex = Split(n, "=")(1)
 
else
'tu peux meme l'ajouter dynamiquement ici si tu veux 
end if 
 Next
End Sub

voila tes pseudo MFC ne sont pas perdues meme apres fermeture du fichier

[parmi]

Le problème, à ce que je sache, c'est qu'il ne connait pas les noms des valeurs à priori...
Il faut donc qu'il les emmagasine "live" à chaque exécution, non ?

[patricktoulon]

re
bonjour parmi

oui a la place du commentaire dans mon code

a chaque changement si le name existe application de sa valeur pour le interior

si il existe pas un rnd sur x pour determiner une couleur ,applicationde la couleur, memorisation

[zoumzoum59]

Bonjour parmi et patricktoulon,

Désole de mon absence mais me revoilà, et merci pour vos suggestions.

Ton principe patricktoulon me parait intéressant, mais ou place tu ta procédure "ajout_regle", car je ne vois pas ou la mettre, j'ai voulu faire des essais et je n'y suis pas arrivé.
Ensuite je suis un peu perdu avec la retranscription que je doit faire sur mes 4 colonnes, et les names, comment les créer dynamiquement en fonction des référence trouvé dans mes colonnes.

mon niveau reste assez modeste, donc je pense qu'il va me falloir un peu plus de renseignement, si c'est pas trop demandé

[zoumzoum59]

Bonjour a tous,

J'ai fait des recherche sur les "Names" qui si je comprend a quoi cela correspond, correspond a une collection qui reste enregistré dans le fichier et chaque "Name" peut contenir une valeur.
Mais mes recherches ne m'ont pas permis de comprendre leurs fonctionnements, en plus je tombe généralement sur "ActiveWorkbook.Name" qui correspond uniquement au nom du classeur.

Donc si quelqu'un peut m'indiquer ou je pourrais m'informer, merci d'avance.

[zoumzoum59]

Bonjour à tous,

Tant bien que mal j’essaie d'avancer dans mon projet, j'ai laisser tomber les "Names" par manque d'info et me suis dirigé vers la piste que m'avais soulevé parmi, donc créer des tableaux.
je suis arrivé a ceci qui est loin d’être parfait, j'ai d’ailleurs certains soucis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub toto()
  Dim Tableau1()
  Dim NumColIndex As Variant
 
  Set MonDico = CreateObject("Scripting.Dictionary")
  Ligne = Range("E65536").End(xlUp).Row
  Ligne = "Q" & Ligne
  'MsgBox (Ligne)
 
 
  For Each C In Range([N5], [Ligne])
 
If C <> "" Then
     If Not MonDico.Exists(C.Value) Then
 
        MonDico.Add C.Value, C.Value
 
        ReDim Tableau1(1 To MonDico.Count)
        Tableau1(MonDico.Count) = C.Value
 
      End If
End If
  Next C
 
  NumColIndex = Array(35, 36, 37, 38, 39, 40, 41, 42, 43, 45, 46, 47, 48)
 
 
 
End Sub

Donc pour mon premier tableau (Tableau1) qui dans mes essais comportaient deux valeurs a la première boucle j'ai bien ma première valeur qui apparait, mais quand la deuxième valeur est intégré au tableau la première valeur devient vide et je ne comprend pas pourquoi.
Dans mon Tableau1, quelque soit le nombre de valeur il n'y a que la dernière ligne qui est renseigné les autres sont vides

Ensuite j'ai créer mon tableau avec les numéros des colorindex a utiliser, mais je ne vois pas comment lier mes deux tableaux pour affecter la valeur du premier tableau au numéro du colorindex du deuxième.

Merci d'avance en espérant avoir été a peu prés clair.

[zoumzoum59]

Re

Comme mon code évolue je me permet de reposter un nouveaux message, j'ai donc recréer mondico en associant la valeur de ma cellule et le numéro du colorindex a utiliser, j'arrive a reboucler sur ma plage pour rechercher les valeur contenu dans mondico, mais je n'arrive pas a cible toutes les valeurs contenu dans ma plage, je n'arrive qu'a cibler la première valeur contenu dans la plage, et pas les suivante.

Comment pourrais je récupérer l'adresse de la cellule qui correspond à la variable d contenu dans ma deuxième boucle For Each ?

Quelqu'un aurait il une idée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Sub toto()
  Dim Tableau1()
  Dim NumColIndex As Variant
 
  Set MonDico = CreateObject("Scripting.Dictionary")
  Ligne = Range("E65536").End(xlUp).Row
  Ligne = "Q" & Ligne
  'MsgBox (Ligne)
 
i = 35
  For Each C In Range([N5], [Ligne])
 
If C <> "" Then
     If Not MonDico.Exists(C.Value) Then
 
        MonDico.Add C.Value, i
        i = i + 1
        ReDim Tableau1(1 To MonDico.Count)
        Tableau1(MonDico.Count) = C.Value
 
      End If
End If
  Next C
 
 For Each d In Range([N5], [Ligne])
 
If d <> "" Then
     k = MonDico.keys
l = MonDico.items
 
For n = 0 To MonDico.Count - 1
 
 
If d = k(n) Then
az = Cells.Find(d, , xlValues).Address
MsgBox (az)
End If
Next n
End If
  Next d
 
End Sub

[parmi]

Essaie ceci pour voir

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub Couleur()
    Dim nbLignes As Long, Cnt As Long
    Dim C As Range, Plage As Range
    Dim strValeurs As String
 
    nbLignes = Cells(Rows.Count, "N").End(xlUp).Row
    Set Plage = Range("N5:Q" & nbLignes)
 
    For Each C In Plage
        If C.Value <> "" Then
            'Si la valeur n'est pas trouvée, on la met dans une String
            'en plus d'un index qui s'incrémente à chaque fois
            'le tout séparés par un point-virgule qui va nous servir lors du Split
            If Not strValeurs Like "*" & C.Value & "*" Then
                strValeurs = strValeurs & C.Value & ";" & Cnt & ";"
                Cnt = Cnt + 1
            End If
        End If
    Next C
 
    For Each C In Plage
        If C.Value <> "" Then
            C.Interior.ColorIndex = GetCouleur(C, strValeurs)
        End If
    Next C
End Sub
 
Function GetCouleur(C As Range, strValeurs As String) As Long
    Dim I As Long
    Dim arrCouleurs
    Dim Tablo
 
    'Tableau de couleur prédéfinies (ColorIndex)
    arrCouleurs = Array(3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15)
 
    Tablo = Split(strValeurs, ";")
    For I = 0 To UBound(Tablo) Step 2   'le 1e item est la valeur, le 2e est l'index de couleurs
        If Tablo(I) = C.Value Then
            GetCouleur = arrCouleurs(Tablo(I + 1))
            Exit Function
        End If
    Next
End Function

[zoumzoum59]

Bonsoir à tous,

Je viens d'arriver au résultat que je recherchait, donc même si un peu d'aide supplémentaire m'aurait fait avancer plus vite je pense, je remercie parmi ainsi que patricktoulon pour m'avoir mis sur la voie.

je met le code pour finaliser et si toute fois on peu l'optimiser, je suis preneur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub toto()
  Dim Tableau1()
  Dim NumColIndex As Variant
 
  Set MonDico = CreateObject("Scripting.Dictionary")
  Ligne = Range("E65536").End(xlUp).Row
  Ligne = "Q" & Ligne
 
 
i = 35
  For Each C In Range([N5], [Ligne])
 
 
If C <> "" Then
     If Not MonDico.Exists(C.Value) Then
 
        MonDico.Add C.Value, i
        i = i + 1
        ReDim Tableau1(1 To MonDico.Count)
        Tableau1(MonDico.Count) = C.Value
 
      End If
End If
  Next C
 
 For Each d In Range([N5], [Ligne])
 
If d <> "" Then
 
     k = MonDico.keys
l = MonDico.items
 
For n = 0 To MonDico.Count - 1
 
 
If d = k(n) Then
 
    d.Interior.ColorIndex = l(n)
 
End If
Next n
End If
  Next d
 
End Sub

[zoumzoum59]

Désolé parmi je n'avais pas vu que tu avais posté avant moi, je vais analyser ton code pour voir comment tu l'as exploité.
Peux tu me faire un retour sur celui que j'ai fait car je n'ai aucune idée s'il est correct malgré qu'il fonctionne.

Encore merci