Discussion :

[isscool]

Bonjour à tous,

j'ai un petit soucis avec la fonction SI(HEURE).
Voilà ma formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTVIDE(E3);"";SI(HEURE(F3)<=8;2,65;SI(HEURE(F3)<=9;3,01;3,34)))

La formule marche bien sauf qu'elle ne me prend pas en compte les minutes. Si j'ai un résultat de 8:15, elle reste dans la tranche des 8 est ne m'affiche donc pas le bon résultat.
Avez-vous une idée pour lui faire prendre en compte les minutes ?

merci d'avance à tous.

[njhub]

Bonjour isscool,

Je n'ai pas compris pourquoi après avoir cherché à savoir si E3 est vide vous faites vos calculs sur F3
j'ai donc utilisé une référence unique : F3
à vous de tester si la formule vous convient

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=8;2,65;SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=9;3,01;3,34);"")

[Philippe Tulliez]

Bonjour,

La formule marche bien sauf qu'elle ne me prend pas en compte les minutes. Si j'ai un résultat de 8:15, elle reste dans la tranche des 8

D'après toi que renvoie la fonction HEURE ?
Quand tu auras répondu à la question tu comprendras que la fonction SI réagit parfaitement à ta condition.
Qu'il y ait dans la cellule testée 08:01 ou 08:59 le résultat renvoyé par la fonction HEURE sera identique

[isscool]

Bonjour,

D'après toi que renvoie la fonction HEURE ?
Quand tu auras répondu à la question tu comprendras que la fonction SI réagit parfaitement à ta condition.
Qu'il y ait dans la cellule testée 08:01 ou 08:59 le résultat renvoyé par la fonction HEURE sera identique

Je comprend que la fonction HEURE gère que les heures, mais il y a t'il une fonction qui gère les deux ?
Merci

[isscool]

Bonjour isscool,

Je n'ai pas compris pourquoi après avoir cherché à savoir si E3 est vide vous faites vos calculs sur F3
j'ai donc utilisé une référence unique : F3
à vous de tester si la formule vous convient

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=8;2,65;SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=9;3,01;3,34);"")

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=8;2,65;SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60>8;3,01;SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60>9;3,34))))

J'ai essayé ta solution "njhub" ça marche bien. Je l'ai juste modifié un peu sur la fin sauf que cette partie SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60>9;3,34)))) ne marche pas. Pourtant je ne pense pas avoir fais d'erreur. As tu une idée ?

Merci

[njhub]

Bonjour isscool,

Oui, l'idée est : ce qui est supérieur à 9 est également supérieur à 8...
Il faut encadrer 3.01 si >8 et <9.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
=SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60<=8;2,65;
SI(et(SOMME(HEURE(F3)*60;MINUTE(F3))/60>8;SOMME(HEURE(F3)*60;MINUTE(F3))/60<9);3,01;
SI(SOMME(HEURE(F3)*60;MINUTE(F3))/60>=9;3,34))))

[AurelienG_]

Bonjour.

Si ton heure est au format hh:mm:ss alors tu peux utiliser la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(F3*24<=8;2,65;SI(ET(F3*24>8;F3*24<9);3,01;SI(F3*24>=9;3,34))))

Par souci d'optimisation j'ai pour habitude d'utiliser l'intervalle le plus élevé en premier puis de "descendre" par palier, on peut donc écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(F3*24>=9;3,34;SI(F3*24>=8;3,01;2,65))

Cela se lit de la manière suivante : "Est-ce supérieur ou égal a 9 ? Oui on prend la valeur, non, est-ce supérieur ou égal a 8 ? oui on prend la valeur, non on prend la valeur évaluée la plus basse (inférieur a 8)"

Info : une heure au format hh:mm:ss est une fraction de journée. Ainsi 08:15:00 font 8.25 heure decimales ou 0.34375 fraction d'une journée. En multipliant cette fraction par 24 on obtient le resultat en décimal

En espérant avoir été clair

[Philippe Tulliez]

Bonjour,
Au lieu d'utiliser une suite de SI imbriqués, je préfère passer par la fonction RECHERCHEV. Plus simple à mettre en place et surtout plus facile à maintenir.
Un petit exemple

Dans une feuille nommée [Parameter], la liste des heures ainsi que leurs valeurs associées



La formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEV(F2;Parameter!$A$2:$B$5;2)

A lire éventuellement Comment remplacer des SI imbriqués par la fonction RECHERCHEV

[isscool]

Merci à tous les deux pour votre aide, tout marche parfaitement.

[isscool]

Bonjour à tous,

je reviens vers vous pour avoir un petit coup de pouce. Je ne sais pas si c'est possible de le faire mais je pose quand même la question. Je suis toujours avec mon tableau pour le calcul d'heure.
J'ai utilisé la formule de Philippe Tulliez =RECHERCHEV(F2;Parameter!$A$2:$B$5;2) qui marche parfaitement.
Toujours en gardant cette formule qui me permet d'afficher le tarif en fonction de l'heure. Est-il possible d'y ajouter une formule quand l'heure dépasse 9h00 pour que ça me calcul le montant en faisant cette formule (3,03/9*nbrs d'heures G6).
Je ne sais pas si je suis bien clair dans mes explications. J'ai ajouter en pièce jointe une ligne de mon tableau.

Merci pour votre aide.