Discussion :

[Denis_67]

Bonjour,

J'ai une petite question de base.
Je boucle sur une feuille et je compare les valeurs dans une autre.
Quand je trouve des différences, je recopie les valeur et je voudrais les colorier pour que par la suite l'utilisateur décide des valeurs à conserver.

Le code fonctionne sauf en ce qui concerne la mise en couleur, en effet j'ai une erreur 1004 car je n’atteins pas les cellules.
Alors que si en je me mets en pas à pas et que j'active la feuille ça passe.
Je pourrais passer par un sheets.activate mais n'y a-t-il pas une syntaxe qui me permette directement de passer la commande ?
Ce que je ne comprends pas c'est que la séquence consistant à ajouter une ligne et à copier les valeurs d'une feuille vers l'autre passe.
J4ai essayé avec worksheets et sheets.
merci pour vos explications

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
For Each cell2 In Worksheets(WS_Call).Range("a" & NR_Ligne_Call & ":v" & NR_Ligne_Call)
If cell2.Value <> Worksheets("donnees").Cells(NR_Ligne, cell2.Column).Value Then '.Copy .Range("a1").End(xlDown).Offset(1, 0)
Worksheets("Donnees").Cells(NR_Ligne + 1, cell2.Column).EntireRow.Insert Shift:=xlDown
With Worksheets("Donnees")
    Worksheets(WS_Call).Range("a" & NR_Ligne_Call & ":v" & NR_Ligne_Call).Copy .Range("a" & NR_Ligne + 1)
End With

'   c'est là que ça passe en erreur 1004
    Sheets("Donnees").Range(Cells(NR_Ligne + 1, 1), Cells(NR_Ligne + 1, 22)).Interior.ColorIndex = 36
'    Sheets("Donnees").Range(Cells(NR_Ligne, 23), Cells(NR_Ligne + 1, 34)).FillDown
'End With

MsgBox "Ligne : " & NR_Ligne_Call
Exit For
'Else: MsgBox "OK" & NR_Ligne_Call
End If

[Jean-Philippe André]

Salut,

essaie de passer par la feuille :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Donnees").Range(Sheets("Donnees").Cells(NR_Ligne + 1, 1), Sheets("Donnees").Cells(NR_Ligne + 1, 22)).Interior.ColorIndex = 36

[patyom]

Bonsoir,
j'ai fait un truc comme çà :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
                Set Plage = Sheets("Donnees").Range(Cells(2, 1), Cells(2, 22))
                With Plage
                    .Interior.ColorIndex = 36
                End With

chez moi ça colle

[Denis_67]

Merci Jean-Philippe, ta solution fonctionne,

Ce qui m'intéresse c'est de garder cette syntaxe.
J'ai toujours des soucis pour comprendre vraiment les différentes portées de sheets, worskheets etc..

Patyom, j'ai testé aussi ta solution, mais celle ci ne sélectionne pas la feuille ciblée, donc ça ne marche pas non plus.

en tout cas merci
Denis

[patyom]

Patyom, j'ai testé aussi ta solution, mais celle ci ne sélectionne pas la feuille ciblée, donc ça ne marche pas non plus.

Tu n'as pas besoin de sélectionner la feuille, ici tu la modifies simplement sans avoir à l'afficher à l'écran.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
NR_Ligne_Call = 2  ' pour exemple
Set Plage = Sheets("Donnees").Range(Cells(NR_Ligne_Call + 1, 1), Cells(NR_Ligne_Call + 1, 22))

Si ça ne fonctionne pas c'est que tu as un PB avec ta variable "NR_Ligne_Call"

[Jean-Philippe André]

SAlut Patyom,

en principe, si la feuille active n'est pas Donnees, alors ton code ne devrait pas fonctionner

[joe.levrai]

Bonjour,

le problème est la filiation de tes Cells()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Donnees").Range(Cells(NR_Ligne + 1, 1), Cells(NR_Ligne + 1, 22)).Interior.ColorIndex = 36

si la feuille Donnees est active, alors tes Cells y font référence
si ce n'est pas le cas, tes Cells font référence à ceux de la feuille active

d'où le plantage : tu fais référence à la plage d'une feuille.... en utilisant une plage d'une autre feuille

le bloc With/End With permet de ne pas mettre Sheets("Donnees") partout sur cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("Donnees")
    .Range(.Cells(NR_Ligne+1,1), .Cells(NR_Ligne+1,22)).Interior.ColorIndex = 36
End With

Il faut prendre la sage attitute de ne JAMAIS travailler sur les objets actifs, et de renseigner à minima la feuille (et mieux encore le classeur)

[Denis_67]

Merci pour vos explications complémentaires très utiles.

En effet j'essaie de me débarasser de l'activation des feuilles (d'où ma question).
L'activation des feuilles est un héritage de l'autoformation avec l'enregistreur de macro qui lui entre autre active les feuilles au fur et à mesure de l'enregistrement.
Il faudrait écrire un petit utilitaire de conversion de l'enregistreur .
Merci et bonne année 2018 !
Denis