Discussion :

[bernard38]

Bjr,

Comment remplacer le filtre personnalisé d'excel (filtre "qui contient") par une boucle qui serait capable de trouver toutes les cellules d'une colonne qui contiennent certaines données (mises dans un fichier) ex:
le fichier contient:
AEC
AEW
LCT
NJR ...
Il faut garder que les cellules qui ont au moins un de ces termes.
Le filtre excel n'accepte que deux possibilités.
ex du contenu d'une cellule (toujours la même structure)
XEROX DOCUMENT SAS
Cde: 0042676805-Message BAP facture 6339801 date éch
13-juin-06 EDG AEC - -

[SfJ5Rpw8]

La solution est peu-être du coté des "filtres élaborés"..(menu données/Filtres/Filtres élaborés)

[bernard38]

Je n'arrive pas à me servir du filtre élaborer pour trouver toutes les cellules qui contiennent ou x ou y ou z.
est-ce possible en une recherche en indiquant des critères particuliers ?

[ouskel'n'or]

est-ce possible en une recherche en indiquant des critères particuliers

Avec Find ? Tu n'as que trois critères
Une question : une fois trouvées les données, que veux-tu faire ?
Tu as la possibilité, soit de créer un tableau() soit de recopier les lignes trouvées dans une autre feuille...

Tu dis

[bernard38]

J'ai une quarantaine de sigles à rechercher (ex: aec,aew,clp,clr...)
Si la cellule ne contient pas un de ces sigles je peux supprimer la lignes de la cellules.Le but est de garder les lignes dont les cellules contiennent au moins un de ces sigles.
Je galère avec les filtres je pense qu'avec une boucle on devrait pouvoir faire ça ?

[Pierre Fauconnier]

Bonjour

Voici un code qui masque les lignes ne correspondant pas aux critères

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub Filtre()
    Dim PlageCriteres As Range
    Dim PlageDonnees As Range
    Dim CelDonnee As Range
    Dim CelCritere As Range
    Dim Trouve As Boolean
 
    Set PlageCriteres = Range("critères")
    Set PlageDonnees = Range("Données")
 
    For Each CelDonnee In PlageDonnees
        Trouve = False
        For Each CelCritere In PlageCriteres
            If InStr(1, CelDonnee.Value, CelCritere.Value) <> 0 Then
                Trouve = True
                Exit For
            End If
        Next CelCritere
        If Not Trouve Then CelDonnee.EntireRow.Hidden = True
    Next CelDonnee
 
    Set PlageCriteres = Nothing
    Set PlageDonnees = Nothing
    Set CelCritere = Nothing
    Set CelDonnee = Nothing
End Sub

Nomme la plage de recherche "Données" et la plage de critères "Critères".

Veux-tu supprimer ou masquer les lignes?

N.B.: Il y a peut-être plus court comme code...

[bernard38]

Ce code fonctionne parfaitement.Pour la suppression je verrai en fonction.
Il faudra que je l'adapte car la plage données est variable.
Merci à tous.