Discussion :

[Didpa]

Bonjour

Je cherche une formule qui me permettrais de me dire combien il y a de lundi, ou mardi dans un mois, et j'ai une Matrice "Fer" qui contient les jours férié de l'année.


Exemple : En A2 j'ai 01/01/18 en B2 31/01/18 et ma Matrice "Fer" qui contient les jours fériés

=ENT(($B2-JOURSEM($B2-(1-1);2)-$A2+8)/7 cette formule me donne le nombre de lundi au mois de janvier qui est égal à 5, mais je n'arrive pas à intégrer ma Matrice afin de pouvoir soustraire le 1er janvier qui était un lundi.

Si quelqu'un à une petite idée.

Merci d'avance.

Cordialement.

[Daranc]

essayes d'intégré la formule NB.JOURS.OUVRES

[Invité]

Bonjour

A tester, remplacer F2:F8 par le nom de la matrice des J.Fériés

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((JOURSEM(LIGNE(INDIRECT(A2&":"&B2));2)=1)*(NB.SI(F2:F8;LIGNE(INDIRECT(A2&":"&B2)))=0))

[papouclo]

Bonjour,
La demande semble être le nombre de lundis ouvrés, celui de mardis ouvrés, ... dans un mois, la date de début du mois étant en A2.
Si la version d'Excel n'est pas antérieure à 2010, j'utiliserai au fait la fonction NB.JOURS.OUVRES.INTL.
Consulter l'aide en ligne pour voir que l'argument week end de cette fonction peut se donner sous la forme d'une chaîne de 7 caractères 0 ou 1, codant la semaine complète à partir du lundi avec des 1 pour les jours "fériés" de la semaine et des 0 pour les jours ouvrés.
La formule serait donc pour le nombre de lundis ouvrés :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.JOURS.OUVRES.INTL(A2;FIN.MOIS(A2;0);"0111111";Fer)

et pour le nombre de mardi ouvrés :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.JOURS.OUVRES.INTL(A2;FIN.MOIS(A2;0);"1011111";Fer)

Remarque: La fonction FIN.MOIS permet d'obtenir les dates des fin de mois sans réserver la colonne B pour les écrire.
Cordialement
Claude