Etat dynamique d'une analyse croisée

**Fredo67** · 14/03/2018, 21h59

Bonjour à toutes et à tous,

je bloque sur la réalisation d'un état dynamique d'une analyse croisée.
Ma requête d'analyse croisée fonctionne bien, voici ce qu'elle m'affiche :

Choix	05/02/2018	06/02/2018	07/02/2018	08/02/2018	09/02/2018
ES			1
JB				1
JB+FR		1
M1	2
M1+FR					1
M2		1
M2+FR				1
SH		1		1	2
SH+FR	1

J'ai utilisé le super tuto de Cafeine : https://access.developpez.com/source...RequeteCroisee

Mon état s'affiche, les entêtes sont correctes mais curieusement l'état ne m'affiche que la 1ère ligne.
La ligne des Totaux me calcule bien le total affiché, donc de la 1ère ligne uniquement.

Nom : Capture.PNG
Affichages : 1042
Taille : 9,2 Ko

Nom : Capture.PNG
Affichages : 1042
Taille : 9,2 Ko

J'ai tout vérifié, tout checké et je ne comprends pas.
Je ne trouve pas mon erreur.

Quelqu'un aurait une idée ?

D'avance merci !

**titi95** · 14/03/2018, 22h20

Bonsoir

Sur l'état, les Zones de texte des champs de la requête sont placés dans quelle section : en-tête page, en-tête groupe, détail, pied de page ?
Même question pour la ligne "Total".

Titi95

**Fredo67** · 14/03/2018, 22h43

Bonsoir,
merci pour la réponse

Alors :
- les étiquettes "Entete" sont dans la section "En-tête de page"
- les étiquettes "Detail" sont dans la section "Détail"
- les étiquettes "Total" sont dans la section "Pied état"

**tee_grandbois** · 14/03/2018, 22h55

Bonsoir,
c'est bien le souci avec un tableau croisé dynamique : son utilisation comme source dans un état n'a rien de dynamique, malheureusement, car chaque champ de la requête doit être inséré (pas seulement le champ ES).
Est-ce bien le cas ?

**Fredo67** · 14/03/2018, 23h13

Ma 1ère ligne est bien affichée dynamiquement.
Le champ ES est un résultat de ma requête et nom le nom d'un champ, tout comme les chiffres (résultats de la requête)

Nom : Capture2.PNG
Affichages : 1022
Taille : 20,6 Ko

Nom : Capture2.PNG
Affichages : 1022
Taille : 20,6 Ko

Ce que je ne comprends pas, c'est pourquoi mon état n'affiche que la 1ère ligne de la requête ???

**tee_grandbois** · 15/03/2018, 00h24

~~Même si tu as utilisé le tuto, peux-tu poster le code de Détail_Format ?~~

Finalement, je pense que le souci se situe au niveau du bouton pour affichage de l'état: il faut utiliser le bouton aperçu avant impression:
Nom : ModeAperçu.JPG
Affichages : 1046
Taille : 58,1 Ko

Nom : ModeAperçu.JPG
Affichages : 1046
Taille : 58,1 Ko

et pas le bouton mode état

**Fredo67** · 15/03/2018, 10h57

Bonjour,

même résultat en mode "Aperçu avant impression"

Voici le code de mon état :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
Option Compare Database
 
' ***** déclaration des variables ***** '
Const Nombre_colonnes = 6 ' Nombre maximum d'étiquettes sur l'état (par rapport à l'exemple) & _
    on peut en afficher plus et donc modifier cette variable
Dim dbBase As DAO.Database
Dim rstEnregistrement As DAO.Recordset
Dim NbColonnes As Integer
Dim Total_colonnes(1 To Nombre_colonnes) As Long
Dim Total_etat As Long
 
 
Private Sub Initvar()
 
    Dim entX As Integer
    Total_etat = 0
 
    For entX = 1 To NbColonnes
        Total_colonnes(entX) = 0
    Next entX
 
End Sub
 
Private Sub Détail_Format(Cancel As Integer, FormatCount As Integer)
 
    Dim entX As Integer
 
    If Not rstEnregistrement.EOF Then
        If Me.FormatCount = 1 Then
            For entX = 1 To NbColonnes
                Me("Detail" + Format(entX)) = Nz(rstEnregistrement(entX - 1), 0)
            Next entX
 
            For entX = NbColonnes + 2 To Nombre_colonnes
                Me("Detail" + Format(entX)).Visible = False
            Next entX
 
            rstEnregistrement.MoveNext
        End If
    End If
 
End Sub
 
Private Sub Détail_Print(Cancel As Integer, PrintCount As Integer)
 
    Dim entX As Integer
    Dim Nblignes As Long
 
    If Me.PrintCount = 1 Then
        Nblignes = 0
 
        For entX = 2 To NbColonnes
            Nblignes = Nblignes + Me("Detail" + Format(entX))
            Total_colonnes(entX) = Total_colonnes(entX) + Me("Detail" + Format(entX))
        Next entX
 
        Me("Detail" + Format(NbColonnes + 1)) = Nblignes
        Total_état = Total_état + Nblignes
    End If
 
End Sub
 
Private Sub Détail_Retreat()
 
    rstEnregistrement.MovePrevious
 
End Sub
 
Private Sub EntêteÉtat_Format(Annuler As Integer, FormatCount As Integer)
 
    rstEnregistrement.MoveFirst
    Initvar
 
End Sub
 
Private Sub ZoneEntêtePage_Format(Annuler As Integer, FormatCount As Integer)
' Pour la version 2002 : remplacer EntêtePage_Format par Zone EntêtePage_Format. A voir pour les autres versions
 
    Dim entX As Integer
 
    ' Met les entêtes de colonnes
    ' dans des zones de texte dans la section Entête.
    For entX = 1 To NbColonnes
        Me("Entete" + Format(entX)) = rstEnregistrement(entX - 1).Name
    Next entX
 
    ' Crée l'entête Totaux de la prochaine zone de liste disponible.
    Me("Entete" + Format(NbColonnes + 1)) = "Totaux"
 
    ' Cache les zones de texte inutilisées dans la section Entête.
    For entX = (NbColonnes + 2) To Nombre_colonnes
        Me("Entete" + Format(entX)).Visible = False
    Next entX
 
End Sub
 
Private Sub PiedÉtat_Format(Annuler As Integer, NBimpression As Integer)
 
    Dim entX As Integer
 
    ' Affecte la valeur Total_Colonne(entX) des champs en colonne au champs total
    For entX = 2 To NbColonnes
        Me("Total" + Format(entX)) = Total_colonnes(entX)
    Next entX
 
    ' Place TotalEtat dans une boite de texte dans le pied d'état.
    Me("Total" + Format(NbColonnes + 1)) = Total_état
 
    ' Cache les zones de texte inutilisées dans le pied d'état.
    For entX = (NbColonnes + 2) To Nombre_colonnes
        Me("Total" + Format(entX)).Visible = False
    Next entX
 
End Sub
 
Private Sub Report_Close()
 
    rstEnregistrement.Close
 
End Sub
 
 
 
Private Sub Report_NoData(Annuler As Integer)
 
    MsgBox "Aucun enregistrement n'a été trouvé.", vbExclamation, "Information"
    rstEnregistrement.Close
    Annuler = True
 
End Sub
Private Sub Report_Open(Annuler As Integer)
 
    Dim rstRequete As DAO.QueryDef
 
    Set dbBase = CurrentDb
    Set rstRequete = dbBase.QueryDefs("Requête1")
    Set rstEnregistrement = rstRequete.OpenRecordset()
 
    'Définit le nombre de colonnes de la requête
    NbColonnes = rstRequete.Fields.Count
 
End Sub

Ma requête s'appelle "Requête1" et m'affiche bien le résultat du 1er post.

D'avance merci

**tee_grandbois** · 15/03/2018, 14h24

Bonjour,
difficile de faire un diagnostic de visu.
Peux-tu poster ta base compressée avec un jeu d'enregistrements contenant des données non confidentielles ?
Merci.

**Fredo67** · 15/03/2018, 21h36

Merci de suivre ce post

ci-joint ma BDD épurée : Cantine_demo.zip

D'avance merci !

**tee_grandbois** · 16/03/2018, 01h18

Bonsoir,
j'ai regardé ton code et relu le tuto, sans trouver la solution.
Et ce qui me semble étrange, malgré le fait qu'il est fait mention de traitement de plusieurs enregistrements, c'est que je ne vois pas comment est géré le remplissage des contrôles indépendants dans le code :

Dans le détail : les champs seront nommés Detail1, Detail2 etc...
Detail1 va contenir, pour chaque enregistrement, le nom du vendeur, Nombre2 et suivants vont recevoir les CA correspondant au mois.

il n'y a pas de boucle qui traite tous les enregistrements or, c'est un minimum si on veut tout traiter ... ou alors je n'ai pas tout compris

(ce qui est possible, aussi)
Donc désolé, pour le moment, je ne peux pas t'aider plus.

**Fredo67** · 16/03/2018, 10h30

en étudiant le code et le tuto je me suis fait exactement la même réflexion.

J'avais donc modifié le code en ajoutant une boucle "While" et en ajoutant un msgbox affichant le "Choix"
Cette fois le code balayait bien toutes les lignes, mais au final mon état affichait toujours 1 seule ligne contenant les infos de la dernière ligne de la requête.

J'avoue ne pas trop comprendre non plus.

Merci pour ton temps

**tee_grandbois** · 16/03/2018, 15h23

Bonjour,

en étudiant le code et le tuto je me suis fait exactement la même réflexion.

J'avais donc modifié le code en ajoutant une boucle "While" et en ajoutant un msgbox affichant le "Choix"
Cette fois le code balayait bien toutes les lignes, mais au final mon état affichait toujours 1 seule ligne contenant les infos de la dernière ligne de la requête.

En effet. Je pense qu'il manque la création des contrôles indépendants en amont selon le nombre de lignes de la requête, mais cela implique d'ouvrir au préalable l'état en mode création et donc une modification du code existant ...

**tee_grandbois** · 16/03/2018, 15h44

Je viens de trouver le problème,
il faut définir le RecordSource à l'ouverture :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub Report_Open(Annuler As Integer)
    Dim rstRequete As DAO.QueryDef
 
    Set dbBase = CurrentDb
    Set rstRequete = dbBase.QueryDefs("Requête1")
    Me.RecordSource = rstRequete.Name     ' <====== il manquait ceci 
    Set rstEnregistrement = rstRequete.OpenRecordset()
    NbColonnes = rstRequete.Fields.Count
End Sub

Cela fonctionne maintenant.

**Fredo67** · 16/03/2018, 17h00

Génial !!!
En effet cette ligne fait toute la différence

Un grand merci à toi tee_grandbois

Etat dynamique d'une analyse croisée [AC-2016]

VBA Access

Discussions similaires

Partager

Partager