Fonction de normalisation Nom de ville

**Didier77** · 19/07/2006, 10h24

Bonjour,
je suis débutant en VB et j'ai un probleme dans access
je doit normalisé un champ StandardName dans une table access 97
par exemple:
"Mans (Le)" doit etre normalisé en "Le Mans"

Je voulais faire ça avec une requete mais après plusoeurs tentative je pense que ce n'est pas possible donc il faut utiliser VB
Si quelqu'un a une idée..

**Delbeke** · 19/07/2006, 10h36

Effectivement je ne vois pas bien comment une requete Sql pourais faire çà.

Si il n'y avais que les Mans (Le) a transformer, une requete du type "Update TaBle Set Ville='Le Mans' Where Ville='Mans (Le)' serait suffisante

Donc je suggégére toutes une série de requete de normalisation, une pour chaque nom de ville à changer

**Phifi** · 19/07/2006, 10h37

Bonjour,

si tu as cette configuration dans tous tes champs ville, càd "Ville (préfixe)" et que tu veux obtenir "préfixe ville", tu peux pour chaque champ :

- utiliser la fonction Instr pour chercher ton premier caractère "("
- si tu trouves "(", utilisation de Instr également pour trouver la position de ")"
- tu extrais ton préfixe contenu entre tes deux positions (fonction Mid)
- tu concatènes (opérateur "+" ou "&") le début de ta chaine (jusqu'à "(", tu as sa position) avec ton préfixe extrait précédemment
- tu édites ton champ ville pour remplacer l'enregistrement par ton résultat
- si tu as beaucoup d'enregistrements, F1 sur "BeginTrans" ou "CommitTrans" pour optimiser le traitement

A toi de jouer

**Didier77** · 19/07/2006, 10h42

Merci pour ta réponse mais en fait il n'y a pas que Le Mans
il y a toutes les villes de France qui commence par Le, L', La, Les
je suis en train de galérer en VB, en fait j'ai penser à tester si il y a le caractere "(" dans la chaine et si oui supprimer ce qui suit et le réecrire
au début de la chaine...
mais c pas gagné
si quelqu'un la déjà fait..

**Didier77** · 19/07/2006, 10h43

Merci Phifi je vais essayé

**Delbeke** · 19/07/2006, 10h59

Tu peux Toujours ecrire une fonction qui normalise le nom de la ville
et l'appeler pour chaque enregistrement

Exemple de fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Private Function Normalise(ByVal NomVille As String)
  Dim PosDeb As Long
  Dim PosFin As Long
  Dim Longeur As Long
  Dim Prefixe As String
 
  PosDeb = InStr(NomVille, "(")
  If PosDeb = 0 Then
    Normalise = NomVille
    Exit Function
  End If
  PosFin = InStr(NomVille, ")")
  If PosFin = 0 Then
    'pas de parenthese fermante
    PosFin = Len(NomVille)
  End If
  Longeur = PosFin - PosDeb - 1
  Prefixe = Mid(NomVille, PosDeb + 1, Longeur)
  NomVille = Left(NomVille, PosDeb - 1)
  Normalise = Trim(Prefixe & " " & NomVille)
End Function

Tu lis chaque enregistrement et tu modifie l'enregistrement si le champs est different du resultat de la fonction (pas la peinne de modifier tous les enreistrements)

**Didier77** · 19/07/2006, 11h08

ok merci beaucoup
j'ai lu ton code et si j'ai bien compris
"NomVille" c'est le champ à normalisé

**Delbeke** · 19/07/2006, 11h14

Pas tout a fait, c'est une variable locale, je lui ai donné un nom plus parlant pour aider a la comprehension, j'aurais pu utiliser Text à la place
ce qui aurai donné

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Private Function Normalise(ByVal Text As String)
  Dim PosDeb As Long
  Dim PosFin As Long
  Dim Longeur As Long
  Dim Prefixe As String
 
  PosDeb = InStr(Text, "(")
  If PosDeb = 0 Then
    Normalise = Text
    Exit Function
  End If
  PosFin = InStr(Text, ")")
  If PosFin = 0 Then
    'pas de parenthese fermante
    PosFin = Len(Text)
  End If
  Longeur = PosFin - PosDeb - 1
  Prefixe = Mid(Text, PosDeb + 1, Longeur)
  Text= Left(Text, PosDeb - 1)
  Normalise = Trim(Prefixe & " " & Text)
End Function

Il faut passer a la fonction le contenu du champs
Dim NomNormalisé as string

NomNormalisé = Normalise(MonRecordset("MonChamps"))

J'epère que j'ai été plus clair*. En fait le mieux est l'ennemi du bien

**Didier77** · 19/07/2006, 11h18

apparement ta fonction à un probleme, j'ai un message d'erreur...

You entered operateur or operator...

**Didier77** · 19/07/2006, 11h32

c quoi MonRecordset?

**Delbeke** · 19/07/2006, 11h44

Sais tu te servir d'une base de données en Vb6 a l'aide de DAO ou ADO ? sinon il y a d'excellents articles traitant du sujet que tu devrais lire avant, y compris sur ce site.

**SfJ5Rpw8** · 19/07/2006, 11h45

Envoyé par Didier77

apparement ta fonction à un probleme, j'ai un message d'erreur...

You entered operateur or operator...

sur qu'elle ligne..?

**Didier77** · 19/07/2006, 11h46

ouai ta raison je vais me documenter un peu car je t'avoue que je suis un peu perdu lol
en tout cas merci beaucoup

**Delbeke** · 19/07/2006, 11h59

Bon
je te propose un petit programme d'etude alors
Crée un nouveau projet
Ajoute y un data control et un bouton de commande

dans le datacontrol renseigne les propriétés
- databasename avec le chemin complet de ta base de donnée
- recordsource avec le nom de ta table

Ajoute le code suivant dans ta feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
 
Private Sub Command1_Click()
  Dim NomNormalisé As String
  If Data1.Recordset.RecordCount = 0 Then
    MsgBox "Aucun enregistrement", vbInformation
    Exit Sub
  End If
  Do While Not Data1.Recordset.EOF
    NomNormalisé = Normalise(Data1.Recordset("Ville"))
    If NomNormalisé <> Data1.Recordset("Ville") Then
      Data1.Recordset.Edit
        Data1.Recordset("Ville") = NomNormalisé
      Data1.Recordset.Update
    End If
    Data1.Recordset.MoveNext
  Loop
  MsgBox "Normalisation terminée"
End Sub
 
Private Function Normalise(ByVal Text As String)
  Dim PosDeb As Long
  Dim PosFin As Long
  Dim Longeur As Long
  Dim Prefixe As String
 
  PosDeb = InStr(Text, "(")
  If PosDeb = 0 Then
    Normalise = Text
    Exit Function
  End If
  PosFin = InStr(Text, ")")
  If PosFin = 0 Then
    'pas de parenthese fermante
    PosFin = Len(Text)
  End If
  Longeur = PosFin - PosDeb - 1
  Prefixe = Mid(Text, PosDeb + 1, Longeur)
  Text = Left(Text, PosDeb - 1)
  Normalise = Trim(Prefixe & " " & Text)
End Function

Voila ca devrait fonctionner

PS : j'ai supposé que le champs contenant le nom des villes etait <<Ville>>

**Didier77** · 19/07/2006, 12h03

C bon sa marche en fait j'ai créer un requete:

UPDATE NomTable SET Champ = normalise(
`Champ`
);

Et sa fonctionne nikel
Merci à tous pour vos réponse et je précise que le code ne contient pas d'erreur c'était du à une mauvaise utilisation.

**Delbeke** · 19/07/2006, 13h01

Dans access alors ! je vois pas Vb faisant cela, sinon, je suis preneur pour la methode pour créer une requete avec une fonction personalisée

Fonction de normalisation Nom de ville

VB 6 et antérieur

Discussions similaires

Partager

Partager