Discussion :

[matlabation]

Bonjour à tous,

Je viens vous sollicité dans l'espoir de trouver une solution à mon problème qui traîne déjà depuis 2 jours.

Je souhaite distinguer le nombre d'heures de jour de celles de nuit sur une durée de travail, je m'explique:

1- Sont considérées comme heures de nuit, toutes les heures comprises entre 21h-6h

2- Exemple: un salarié travaille de 4h du matin à 12h ( midi), donc la durée totale de sa vacation est de 8h, je veux une formule qui me dis que sur ces 8h j'ai 2h ( entre 04h et 6h) de nuit et 6h de jour;

3- le format du tableau que je souhaite obtenir est comme suit:

Heure début vacation	Heure fin vacation	Durée vacation	Heures nuit	Heures jour
04:00	12:00	08:00	02:00	06:00
15:00	21:45	06:45	00:45	06:00

Je vous remercie tous d'avance,


Ce forum est juste Top!!

[Menhir]

En supposant que les heures de début commencent en A2 et les heures de fin en B2, mettre en D2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(0;6/24-A2)+MAX(0;B2-21/24)

[papouclo]

Bonjour,
Est-ce que la durée d'une vacation est obligatoirement contenue dans une seule et même journée comme c'est le cas pour les deux exemples proposés ?
Dans ce cas, Menhir a donné une formule pour calculer les heures de nuit.

La durée d'une vacation peut-elle "à cheval" sur deux journées consécutives comme pour les deux dernières lignes de l'image ci-dessous. Alors, la formule pour calculer les heures de nuit sera plus complexe.

On peut écrire en D2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= MAX(0;MIN(B2;6/24)-A2) + MAX(0;MIN(6/24+1;B2+(B2<A2))- MAX(21/24;A2))

Pour calculer les heures de jour, la formule pourrait être en E2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(0;MIN(B2+(B2<A2);21/24)- MAX(6/24;A2))+ MAX(0;MIN(21/24+1;B2+(B2<A2))- MAX(6/24+1;A2))

Cordialement
Claude

[matlabation]

Nikel, ça marche à merveille! Merci a vous deux!
Merci à ce forum qui est une mine d'or