Discussion :

[yoyoo]

Salut,
après de nombreuses galères pour comprendre la manière de sécuriser les bases, ca va mieux ... mais j'ai une autre question.
En fait MaBase est destinée à aller sur un serveur commun, chacun pourra alors la consulter depuis son pc et donc je n'ai besoin de la sécurité que sur le serveur. Donc ce que je comptais faire: mettre la base et le workgroup dans un dossier quelconque sur le serveur (par exmple Z:\SIG\data\MaBase.mdb et Z:\SIG\data\groupe.mdw) et mettre en vue, toujours sur le serveur, un raccourci de la base avec par ex

"C:\Program Files\Microsoft Office\Office\MSACCESS.exe" "Z:\SIG\data\MaBase.mdb" /Wrkgrp "Z:\SIG\data\groupe.mdw"

Mais le pb est que chaque employé n'a pas le meme chemin d'adresse sur son pc pour le MSAccess.exe (moi j'ai par exemple C:\Program Files\Microsoft Office\Office11...) je voulais alors savoir s'il y a un moyen de mettre une sorte de chemin relatif pour cette adresse?
Sinon je ne sais pas comment faire

Merci!!

[Tofalu]

Et si tu mets juste :

"Z:\SIG\data\MaBase.mdb" /Wrkgrp "Z:\SIG\data\groupe.mdw"

?

Autre chose : la partie applicative doit être installée sur chaque poste client

[Maxence HUBICHE]

ca devrait pas marcher ton truc tof, car /wrkgrp est un paramètre de la ligne de commande de msaccess.exe

par contre, tu peux peut-être essayer de mettre directement msaccess.exe (pas sûr que ca marche, mais, si msaccess est dans le PATH, ca devrait passer)

il n'y a pas, à ma connaissance, de variable d'environnement pour cela.

par contre, de mémoire, tu dois pouvoir générer ton raccourcis directement depuis l'installeur.

[yoyoo]

Salut,

En effet, ne pas mettre msacces.exe ne marche pas, la base s'ouvre avec le system.mdw par defaut.
De même, mettre uniquement MSAccess.exe ne marche pas non plus, il recherche le chemin.

Quelqu'un aurait une solution pour la sécurité sur CETTE base uniquement mais consultable sur un serveur?
Il n'y a vraiment aucun moyen d'appliquer une sécurité individuelle associée à une seule base?

Merci

[Maxence HUBICHE]

regarde du côté de la définition de profils alors...

[LedZeppII]

Bonjour,

Je te propose de contourner le problème à l'aide d'un script VBS en guise de raccourci.
N'ayant pas plusieurs versions de windows et d'Office je ne peux dire si ça fonctionne tout le temps.

Le principe est de lire le registre HKEY_CLASSES_ROOT.
1. La clé Access.Application\CurVer donne la clé de la version actuelle (Access.Application.9 pour access 2000).
2. On lit donc cette autre clé : Access.Application.9\Shell\Open\Command par exemple.

Il y a plus rapide en lisant la clé Applications\MSACCESS.EXE\Shell\Open\Command
mais je ne sais pas depuis quelle version de windows ça existe.
Tu peux tester pour voir.

Bon courage.

Ci-dessous le code à copier dans un fichier ayant l'extension .vbs (Mabase.vbs par ex.)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Const constTextCompare=1

Dim BDPATH, ACC, WKGP, oSH

BDPATH="""Z:\SIG\data\MaBase.mdb"""   ' Chemin complet BdD
WKGP = """Z:\SIG\data\groupe.mdw"""   ' Chemin complet fichier workgroup

' Crée l'objet Shell script
Set oSH = CreateObject("WScript.Shell")

' Récupère chemin MSAccess.exe dans base registre
ACC = AccessRegKeyLookUp()

If ACC<>"" Then
  ' Construit ligne de commande
  strCmd = ACC & " " & BDPATH & " /WRKGRP  " & WKGP
      ' MsgBox strCmd ' debug ligne de commande
  ' Lance Appli avec ligne de commande
   oSH.Run strCmd
Else
   msgbox "Application Access Non trouvée"
End If

Set oSH=Nothing


' -----------------------------------------------------------
' Fonction pour récupérer chemin MSAccess.exe
' -----------------------------------------------------------
Function AccessRegKeyLookUp()
Dim AccessCurVer, OpenCommand, strAccPathTo

AccessCurVer = "": OpenCommand = "": strAccPathTo = ""

On Error Resume Next

' Par Applications enregistrées
' sais pas pour quelle versions de Windows ça fonctionne - a tester -
'OpenCommand = oSH.RegRead("HKCR\Applications\MSACCESS.EXE\Shell\Open\Command\")

' Par Class
AccessCurVer = oSH.RegRead("HKCR\Access.Application\CurVer\")
If AccessCurVer <> "" Then
   OpenCommand = oSH.RegRead("HKCR\" & AccessCurVer & "\Shell\Open\Command\")
End If

If InStr(1, OpenCommand, "MSACCESS.EXE", constTextCompare) Then
   strAccPathTo = Left(OpenCommand, InStr(2, OpenCommand, """"))
End If

AccessRegKeyLookUp = strAccPathTo

End Function

[yoyoo]

Salut,
j'étais en vacances je ne vois les réponseq qu'aujourdhui.

LedZeppII merci pour ton aide (les autres aussi bien sur!) ce que tu m'as indiqué à l'air de bien fonctionner, je me suis contenté de mettre la bonne adresse dans le code sachant que je ne suis pas du tout calé en code car simple utilisateur d'access... mais ca marche.

merci