Discussion :

[BtjpsspgrW]

Bonjour,

Prenons cet exemple :
Sur la cellule A1, il a été saisi le texte « le lait équitable »
Sur cette cellule active, je souhaiterais exécuter une tâche, si l'on y trouve le mot clé.
En l’occurrence, ce mot clé est « lait », et s’il a bien ce mot clé, décale de 2 cellules vers la droite

Comment rédiger cette syntaxe ? dans la macro ci-dessous, ça fonctionne seulement si le texte est lait, pas si la cellule contient la donnée « le lait équitable ». Je ne parviens pas modifier ce qui ne va pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub decal()
If ActiveCell.Value2 = "lait" Then ActiveCell.Offset(0, 2).Select
End Sub

Merci pour votre aide.

[eriiic]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= "*lait*"

Tu sais que tu as des événements feuille qui te le lancerait automatiquement dès la validation ?
eric

[clementmarcotte]

Bonjour,

Je n'ai jamais essayé, mais, tu as peut-être une porte de sortie avec Like

Ou bien avec quelque chose qui ressemblerait à cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
sub portion()
   dim texte1 as string
   dim texte2 as string
   texte1 = "le lait équitable"
   texte2 = "lait"
   if instr (texte2, texte1) >0 then
      msgbox("Trouvé")
   else
      msgbox("Non rouvé")
   end if
end sub

[eriiic]

Oula oui, j'ai répondu un peu vite...

[unparia]

Bonjour
BtjpsspgrW ne veut pas déceler la présence d'une sous-chaîne de caractères, mais celle d'un MOT (ce n'est pas pareil du tout).
Je ne veux pas apporter dans cette "affaire", dont l'utilité dans un tableur me parait plutôt ludique, une aide au-delà de la description du mécanisme à mettre en place -->>
- encadrement de la chaîne à traiter par des espaces
- remplacement par un espace de tout caractère présent dans cette liste : ".,:-()!?"
- forçage de la casse en majuscule
- recherche (comme montré plus haut) de la valeur de instr(la-chaîne, " " & ucase(le_mot) & " ")

Mon aide s'arrêtera là.

PS : je n'ai pas voulu parler en plus d'autres aspects (pluriels, accords, etc...), puisque le message d'origine n'en parle pas non plus.

Amusez-vous bien

[BtjpsspgrW]

Bonjour,
Je ne comprends pas bien les réponses apportées par les membres.
Ce que je souhaite :
Dans une base de données, sur la même colonne en décalant d’une cellule à chaque fois (boucle), je souhaiterais que VISUAL BASIC détecte si le mot clé est contenu dans cette cellule ou pas du tout. On peux trouver ce mot dans la barre de formule après peu de caractères, ou après un grande nombre de caractères.

EXEMPLE :
Cellule B2 = le lait équitable
Cellule B3 = j’aime danser
Cellule B4 = J’aime boire du lait
Pour la cellule B2, le mot clé se trouve à partir du 4ème caractère. Pour la cellule B3, le mot clé ne se trouve pas. Pour la cellule B5, le mot clé se trouve à partir du 17ème caractère.

J’ai essayé avec la syntaxe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveCell.Find

, mais ça ne fonctionne pas.

[parmi]

Bonjour,

Et qu'en serait-il d'une phrase du genre
Il s'appelait Raymond

Faut-il considérer ou non?
Et qu'en est-il si lait est au pluriel, en majuscule,...?

Prend le temps de lire le message de unparia (que je salue)

[Pierre Fauconnier]

Salut,

Pour continuer sur les remarques de Jacques et Parmi...

On parle du mot "lait"... Donc à encadrer par des espaces, sauf si en début de cellule (pas trop de sens en français mais il serait sage de préciser les cas possibles de façon exhaustive) ou en fin de cellule (suivi d'un des signes prévus par Jacques, ... ou pas!)

Vu la complexité, j'envisagerais une expression régulière. Sur base d'exemples courants qu'il conviendrait que tu complètes quant aux cas autorisés et rejetés, voici une fonction (dont le pattern serait à adapter si tous les cas que tu prévois ne sont pas dedans), tu pourrais utiliser la fonction suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Function TestWord(Content As String, Word As String) As Boolean
  Dim regexp As Object
  Dim Pattern As String
 
  Set regexp = CreateObject("VBScript.RegExp")
  regexp.IgnoreCase = True
  Pattern = "(^\(*[word][ ,;\?\.\)]+)|([ |\(][word][ ,;\?\.\)]+)|([ |\(][word][ \.,;?\)]*$)"
  Pattern = Replace(expression:=Pattern, Find:="[word]", Replace:=Word)
  regexp.Pattern = Pattern
  TestWord = regexp.Test(Content)
  Set regexp = Nothing
End Function

Soyons clairs: je ne suis pas certain d'avoir envisagé tous les cas. Sur base d'une règle de gestion , on devrait probablement affiner/ajuster le pattern, qui semble peut-être ésotérique, mais qui en fait assez simple à disséquer...

[patricktoulon]

Re
bonsoir a tous
oui le regex peut etre interéssant
@pierre on peut simplifier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub test()
    MsgBox TestWord("huile:lait?carton; poire", "lait")
    MsgBox TestWord("il s'appelait trinita", "lait")
    MsgBox TestWord("il faut boire du lait pour grandir", "lait")
    MsgBox TestWord("j'aime la laitiere", "lait")
    MsgBox TestWord("lait et sucre sont necessaires pour la pate a crepe ", "lait")
    MsgBox TestWord("ce qui est bon dans le dejeuner c'est le lait", "lait")
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Function TestWord(ByVal txt As String, ByVal Word As String) As Boolean
    Dim Txt2$
    With CreateObject("VBScript.RegExp")
        .Global = True: .IgnoreCase = True
        .Pattern = "[^\w]"    'pattern pour chopper tout les caracteres speciaux y compris les espaces (voir result dans debug )
        Txt2 = .Replace(" " & txt & " ", "|") 'remplacement de ces dit caracteres
        .Pattern = "\|" & Word & "\|" 'new pattern englobant le mot cherché entre caracteres distincts(choisir le caracteres que l'on veut pourvu qu'il soit distinguable de ceux de la chaine)
        TestWord = .test(Txt2) 'test retournant un booleen
        Debug.Print Txt2 & "    :" & TestWord 'verif dand debug(facultatif)
    End With
End Function

[unparia]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox TestWord("huile:étourdi?carton; poire", "étourdi")

[unparia]

J'appelle en outre l'attention sur l'existence de certains pièges.
Le mot "grand-père", par exemple, est un mot à part entière et non deux mots.
La recherche du mot "père" dans la phrase "j'ai rencontré mon grand-père au marché" ne doit en aucun cas retourner "vrai"
"Vrai" doit par contre être retourné avec la phrase "Jean le grand - père de trois enfants - est connu des services administratifs"
D'autres pièges existent.
Amusez-vous bien (il pleut, ce week-end).

[patricktoulon]

J'appelle en outre l'attention sur l'existence de certains pièges.
Le mot "grand-père", par exemple, est un mot à part entière et non deux mots.
La recherche du mot "père" dans la phrase "j'ai rencontré mon grand-père au marché" ne doit en aucun cas retourner "vrai"
"Vrai" doit par contre être retourné avec la phrase "Jean le grand - père de trois enfants - est connu des services administratifs"
D'autres pièges existent.
Amusez-vous bien (il pleut, ce week-end).

ca me parait impossible de demander au regex de dicerner cet exemple vba et regexpand ne possedent pas de dictionnaire
on peut jouer avec l'espace en plus dans la separation mais ca c'est toi qui le code dans le pattern
que se soit avec un regex ou like faire les deux test

pour ma proposition de toute a l'heure j'ai trouver une parade mais c'est pa joli

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
    MsgBox TestWord("huile:étourdi?carton; poire", "étourdi")
    MsgBox TestWord("huile:lait?carton; poire", "lait")
    MsgBox TestWord("il s'appelait trinita", "lait")
    MsgBox TestWord("il faut boire du lait pour grandir", "lait")
    MsgBox TestWord("j'aime la laitiere", "lait")
    MsgBox TestWord("lait et sucre sont necessaires pour la pate a crepe ", "lait")
    MsgBox TestWord("ce qui est bon dans le dejeuner c'est le lait", "lait")
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Function TestWord(ByVal txt As String, ByVal Word As String) As Boolean
    Dim Txt2$, word2$
    With CreateObject("VBScript.RegExp")
        .Global = True: .IgnoreCase = True
        .Pattern = Word
        Txt2 = .Replace(txt, String(10, "C"))
        .Pattern = "[^\w]"
        Txt2 = .Replace(" " & Txt2 & " ", "|")
        .Pattern = "\|" & String(10, "C") & "\|"
        TestWord = .test(Txt2)    '
        Debug.Print Txt2 & "    :" & TestWord
    End With
End Function

[unparia]

pour ma proposition de toute a l'heure j'ai trouver une parade mais c'est pa joli

Ce qui, tant dans le code bancale que dans celui de "correction", n'est pas "joli", c'est sans aucun doute le fait d'utiliser un camion de 20 tonnes (Regex) pour transporter une boîte d'allumettes.
Je n'irai plus loin (et avec vraiment très peu de code) que si BtjpsspgrW nous exposait une raison vraiment sérieuse de sa démarche.

[Pierre Fauconnier]

@Jacques,

Je crois que tout le monde a bien compris les limites. La question n'est pas de réaliser la fonction qui envisage tous les cas possibles et imaginables, même les plus improbables, mais de répondre à la demande initiale dans les limites précises de sa formulation et en ayant en tête la finalité de l'opération.

Il me semble donc qu'il revient au demandeur de préciser "son cahier des charges" et la finalité de la chose, que j'entrevois plus comme toi comme quelque chose de ludique), et notamment ce qui est considéré comme un mot.

[...]
Le mot "grand-père", par exemple, est un mot à part entière et non deux mots.
La recherche du mot "père" dans la phrase "j'ai rencontré mon grand-père au marché" ne doit en aucun cas retourner "vrai" [...]

Il me semble assez évident que certaines règles doivent être respectées. Si on peut trouver "grand-père", ça devrait vouloir dire, au niveau des règles, qu'un mot ne peut pas être encadré par des tirets qui le collent, sinon, il serait impossible de déterminer si on doit considérer "grand-père" ou "grand" et "père" dans "bonjour-grand-père-merci" => retour aux règles qui doivent être énoncées clairement.

@Patrick. J'étais parti au départ sur un découpage début|milieu|fin, mais en matière de regexp, je n'ai pas beaucoup de pratique, donc je fais sûrement un peu trop compliqué

[eriiic]

Bonjour à tous,

Si on revenait au basique ? ;-)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Option Compare Text
Function motOk(phr As String, mot As String) As Boolean
    motOk = mot = phr Or InStr(phr, mot & " ") > 0 Or InStr(phr, " " & mot & " ") > 0 Or InStr(phr, " " & mot) > 0
End Function

Ou avec Like
eric

Edit : ajout de mot=phr

[Invité]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub portion()
   Dim texte1 As String
   Dim texte2 As String
   texte1 = "le lait équitable"
   texte2 = "lait"
   MsgBox IsMidText(texte1, texte2)
 End Sub
Function IsMidText(Txt As String, Cherche As String) As Boolean
IsMidText = InStr("©" & Replace(Txt, " ", "©") & "©", "©" & Cherche & "©")
End Function

[eriiic]

Et tant qu'on y est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Option Compare Text
Function motOk(phr As String, mot As String) As Boolean
    motOk = InStr(" " & phr & " "," " &  mot & " ")
End Function

eric

[Invité]

Bonjour eriiic,
Je n'avais pas vue ta réponse.

[eriiic]

Pas de mal, c'était une avancée avec plus qu'une seule comparaison.
Et puis ça m'a inspiré la suivante ;-)

[patricktoulon]

re
bonjour a tous

@Patrick. J'étais parti au départ sur un découpage début|milieu|fin, mais en matière de regexp, je n'ai pas beaucoup de pratique, donc je fais sûrement un peu trop compliqué

@Pierre
moi non plus je metrise pas les subtilités d'un pattern aussi complexe que le tiens

c'est ce pattern qui m'a rendu fou je serais incapable de savoir quel segment fait quoi

pour pouvoir envisager toutes les possibilités

1. replacer le mot reccherché avec une chaine distincte sans caracteres speciaux
2. replacer tout les caracteres speciaux y compris les espaces par un caracteres special
3. test de la chaine de replacement précédée et suivi du caracteres special de remplacement

toutes les possibilités seront prises en compte
@unparia
pour le grand-pere et grand - pere
le regex n'a pas de dictionnaire il ne sera jamais distinger si c'est un nom commun ou autre,le regex cherche une expression c'est tout

il faut faire les deux tests

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
pattern="(\s)" & word &"(\s)"
.test(chaine)
pattern="[^\w][^\w]" & word &"(\s)"
.test(chaine)=true