Discussion :

[Keuf95]

Bonjour à tous.

J'ai un formulaire avec un sous-formulaire en mode "continu".
Est-il possible dans le sous-formulaire en mode continu de ne faire apparaître que les lignes contenant des enregistrements et pas la ligne supplémentaire qui s'affiche automatiquement et qui permet la saisie d'un nouvel enregistrement (La ligne avec *).
Par contre je voudrai afficher cette ligne lorque je quitte l'enregistrement précédent avec la touche tabulation afin de pouvoir tout de même créer de nouveaux enregistrements.

[LedZeppII]

Bonsoir,

voici la méthode que j'utilise.
Dans le formulaire utilisé en tant que sous-formulaire :
Ajout Autorisé : Non
Dans le pied de Formulaire, un bouton 'Nouvel enregistrement'
(image intégrée : Atteindre Nouveau 2)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
' Bouton Nouvel enregistrement : Sur Click
Private Sub b_NewRec_Click()
 Me.AllowAdditions = True
  DoCmd.GoToRecord acActiveDataObject, , acNewRec
 ' ou
 ' DoCmd.RunCommand acCmdRecordsGoToNew

  ' Donner le focus au premier contrôle (ici F1)
 Me.F1.SetFocus
End Sub

' Formulaire : Sur Activation
Private Sub Form_Current()
  If Me.NewRecord = False Then Me.AllowAdditions = False
End Sub

Par déplacement ça doit être faisable, mais moins simple.
Il faut détecter quand on quitte le dernier contrôle et si on a appuyé sur TAB (et peut-être Enter aussi)

Bon courage

[Ajout]:
Finalement ça se fait .
Si le dernier contôle de la ligne s'appelle DernierChp :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Dim ToucheDernierChp As Integer ' Variable au niveau Général

Private Sub DernierChp_Exit(Cancel As Integer)
Cancel = False
If Me.CurrentRecord = Me.RecordsetClone.RecordCount Then
   If ToucheDernierChp = 13 Or ToucheDernierChp = 9 Then
      Me.AllowAdditions = True
      DoCmd.RunCommand acCmdRecordsGoToNew
   End If
End If
End Sub

Private Sub DernierChp_KeyDown(KeyCode As Integer, Shift As Integer)
If Shift = 0 Then
   ToucheDernierChp = KeyCode
Else
   ToucheDernierChp = 0
End If
End Sub

Private Sub Form_Current()
  If Me.NewRecord = False Then Me.AllowAdditions = False
End Sub

A+