Discussion :

[cavano59]

bonjour

j'aimerais faire appel à votre expérience pour solutionner mon problème.

j'ai un tableau comportant des dates et où j'aimerais automatiser la mise à jour des dates des dernières maintenance.

1er col dernière MP / 2ème col Fréquence en mois / 3ème col date prévisionnelle MP (selon fréquence de la col 2) / 4ème col date réelle effective

j'aimerais que la date réelle vienne automatiquement se mettre à la colonne dernière MP. est-ce possible sans macro. (voir mon tableau en pièce jointe.

Merci d'avance de votre aide.

modèle date préventive.xlsx

[papouclo]

Bonjour,
Ecrire en C2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(A2="";"";SI(D2="";A2+(B2*30);D2))

et la recopier vers le bas en colonne C.
Cordialement
Claude

[cavano59]

Merci Claude pour votre aide, votre formule m'intéresse pour la date prévisionnelle mais pour ma demande, je souhaitais que la date de la colonne A se met à jour avec la date réelle effective colonne D, pour avoir une liaison et que je reparte toujours de la dernière date "effectuée" de ma "Dernière MP".

j'espère être assez claire dans mes propos.

Merci encore.

[Menhir]

j'aimerais que la date réelle vienne automatiquement se mettre à la colonne dernière MP.

C'est quoi la "date réelle" ?
Comment Excel peut-il savoir quand a lieu l'intervention ?

est-ce possible sans macro.

Peu probable.
Il ne peut pas y avoir dans une cellule à la fois une valeur et une formule.

voir mon tableau en pièce jointe.

Voir les règles du forum : https://www.developpez.net/forums/d8...s-discussions/

[cavano59]

Merci Menhir pour ce retour


C'est quoi la "date réelle" ? c'est la date où l'intervention a réellement était faite et est renseignée manuellement.

Comment Excel peut-il savoir quand a lieu l'intervention ? c'est renseigné manuellement

Il ne peut pas y avoir dans une cellule à la fois une valeur et une formule. ==> donc je vais garder la colonne A tel que (dernière MP) et insérer en colonne B, avec une formule de calcul . je vais refaire mon tableau et reviendrai si nécessaire

voir mon tableau en pièce jointe. (j'ai pas eu votre tableau ??)

Merci encore

[cavano59]

RE Bonjour,

je re-poste un nouveau au tableau (avec mes dates mises à jour automatiquement selon formules) mais dans certains résultats le texte suivant apparait "#VALEUR!" comment le faire disparaitre, et laisser plutôt une cellule à blanc. voir fichier "planning MP TEST".

merci d'avance de votre retour.

bonne soirée.

[papouclo]

Re,
Au temps pour moi ! La demande était parfaitement claire dans le premier message mais j'avais mal lu.
Il faudra passer par une procédure évènementielle et plus précisément la procédure Worksheet_Change.
Lire le tutoriel Les évènements dans la feuille de calcul Excel.

Dans l'éditeur de macros, écrire dans le module attaché à la feuille le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    
    If Target.Column <> 4 Then Exit Sub        'permet de sortir de la procédure si la cellule sélectionnée n'est pas une cellule de la colonne D
    If Target.Value = "" Then Exit Sub             'permet d'interrompre la procédure lorsque la cellule de la colonne D est effacée
    
    Target.Offset(0, -3).Value = Target.Value   'remplace la cellule de la dernière MP par la date réelle effective
    
    Target.ClearContents                                'efface la cellule de la date réelle effective
    
End Sub

Revenir à la feuille et tester.
Remarque : Dans la colonne C des dates prévisionnelles, je remplacerais votre formule de calcul qui compte tous les mois à 30 jours par une formule employant la fonction MOIS.DECALER et j'écrirais dans C2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(A2="";"";MOIS.DECALER(A2;B2))

Cordialement
Claude

[Menhir]

j'aimerais que la date réelle vienne automatiquement

c'est la date où l'intervention a réellement était faite et est renseignée manuellement.

Là, j'ai beaucoup de mal à suivre ta logique...

voir mon tableau en pièce jointe. (j'ai pas eu votre tableau ??)

C'est toi qui a mis un tableau en pièce jointe.
Moi je t'ai juste signalé une des règles du forum (que tu aurais dû lire avant de poster ta demande) qui explique pourquoi beaucoup de participants (moi compris) n'ouvrent pas les fichiers joints.

[Menhir]

est-ce possible sans macro.

La demande était parfaitement claire dans le premier message mais j'avais mal lu.
Il faudra passer par une procédure évènementielle et plus précisément la procédure Worksheet_Change.

Es-tu sûr d'avoir si bien lu ? Il est écrit "sans macro".

[cavano59]

encore merci de votre aide

Es-tu sûr d'avoir si bien lu ? Il est écrit "sans macro".

si réellement je dois passer par macro pour y arriver, je le ferai, enfin j essayerai.

merci pour votre temps

[papouclo]

Bonjour,
Ma proposition de procédure évènementielle correspondait au premier exemple de fichier proposé : modèle date préventive.xlsx. Dans le deuxième fichier la distinction Contrôle Initial - Dernier Contrôle Automatique permet de s'en tirer avec des formules.
Dans le tableau ci-dessous, vos formules ont été modifiées pour éviter les messages d'erreur #VALEUR! et aussi les raccourcir.


Les formules sont respectivement :
en B2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(CNUM(GAUCHE([@FREQUENCE];CHERCHE(" ";[@FREQUENCE])-1))*(1+11*ESTNUM(CHERCHE("an";[@FREQUENCE])));"")

en C2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(30*[@[FREQUENCE en mois]];"")

en E2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(MAX([@[CONTRÔLE INITIAL]];[@[DATE RELLE DE CONTRÖLE]])>0;MAX([@[CONTRÔLE INITIAL]];[@[DATE RELLE DE CONTRÖLE]]);"")

en F2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR([@[DERNIER CONTRÔLE AUTOMATIQUE]]+[@[FREQUENCE en jour]];"")

en H2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(([@[CONTRÔLE PREVU]]>=AUJOURDHUI()+10)*([@[CONTRÔLE PREVU]]<=AUJOURDHUI()+30);"PREVOIR MP";"")

Au cas où l'utilisation de mois de 30 jours pour le décompte des fréquences d'intervention n'est pas obligatoire et si l'on peut utiliser la fonction MOIS.DECALER, voici une présentation simplifiée du tableau avec deux colonnes en moins (Fréquence en mois et Fréquence en jours).


Les formules pour le dernier contrôle automatique en C2 et l'alerte en F2 sont les mêmes qu'en E2 et H2 dans le tableau précédent.Seule la formule pour le contrôle prévu en D2 est plus complexe car elle utilise le calcul du nombre de mois en B2 dans l'ancien tableau. La formule en D2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(MOIS.DECALER([@[DERNIER CONTRÔLE AUTOMATIQUE]];CNUM(GAUCHE([@FREQUENCE];CHERCHE(" ";[@FREQUENCE])-1))*(1+11*ESTNUM(CHERCHE("an";[@FREQUENCE]))));"")

En comparant les deux tableaux, on peut voir qu'en ligne 17 l'alerte est déclenchée dans le premier tableau alors qu'elle ne l'est pas dans le deuxième.
Cordialement
Claude