Discussion :

[Jonathan191185]

Bonjour,

J'ai cherché dans différents forums sans trouver mon bonheur.

Mon objectif est de transposer dans ACCESS en colonnes des conditions mais sans remonter leur libellés en en-tête mais une notion de "rang".
Autrement dit, ma 1ère condition remonte en colonne 1 (quelque soit la condition), ma 2ème condition en colonne 2, etc...

Cela revient à l'utilisation d'un PROC TRANSPOSE dans SAS.

Exemple :

Module	Acte	Condition
A	X	AA
A	X	AB
A	Y	AC
A	Y	AB
B	X	AD
B	X	AA
B	Z	AA

Résultat voulu :

Module	Acte	Condition 1 (ou 1)	Condition 2 (ou 2)	...
A	X	AA	AB
A	Y	AC	AB
B	X	AD	AA
B	Z	AA	Null

Je vous remercie d'avance pour votre aide,

[micniv]

Bonjour,

Une requete croisée dynamique comme celle-ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
TRANSFORM First(T1.Condition) AS PremierDeCondition
SELECT T1.Module, T1.Acte
FROM T1
GROUP BY T1.Module, T1.Acte
PIVOT T1.Condition;

Après tu retravailles la requete obtenue en VBA dans un recordset pour obtenir le tableau souhaité.

sinon si tu veux garder l'ordre d'apparition des valeurs, tu peux le faire directement en VBA, à partir de la table.

CDLT

[Jonathan191185]

Bonjour,

Merci pour votre réponse.

Cela ne correspond pas exactement au résultat attendu car il me ressort une colonne par condition alors que je veux 1ère condition, 2ème condition,etc...
Mais l'idée du VBA me parait être un bon début et je vais creuser cette option là (ce n'est pas une partie que je maîtrise très bien à ce jour).

Je vous remercie et vous tiendrais informé ;-)

[micniv]

Voici une possibilité :
Je retiens dans un champ Valeurs d'une table T2 les valeurs de Condition dans l'ordre d'affichage.
Elles sont séparée par un ; Cette chaine est exploitable par la fonction Split() :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
Private Sub transpose_data()
    ' 2018-12-26   retenir les valeurs Condition dans l'ordre d'affichage dans un champ Valeurs
    Dim rs1 As DAO.Recordset
    Dim s1 As String, s2 As String
    Set rs1 = CurrentDb.OpenRecordset("T1", dbOpenSnapshot)
 
    ' créer une table T2 (Module as TEXT(50) , Acte as TEXT(50) , Valeurs text(255))
    '                    avec clé primaire composée : Module, Acte
 
    With rs1
        If .RecordCount = 0 Then Exit Sub
 
        .MoveLast
        .MoveFirst
        While Not .EOF
            ' la ligne Module, Acte existe t'elle dejà dans T2 ?
            s1 = "Module ='" & Nz(!Module) & "' AND Acte ='" & Nz(!Acte) & "'"
            If DCount("*", "T2", s1) = 0 Then
                ' la ligne Module, Acte n'existe pas encore dans T2
                ' si Condition n'est pas nulle, on insère une nouvelle ligne dans T2
                If Len(Nz(!Condition)) > 0 Then
                    s2 = "INSERT INTO T2 ( Module, Acte, Valeurs) VALUES" _
                         & "('" & Nz(!Module) & "','" & Nz(!Acte) & "','" & Nz(!Condition) & "')"
                    Debug.Print s2
                    CurrentDb.Execute s2
                End If
            Else
                ' la ligne Module, Acte existe déjà dans T2
                ' si Condition n'est pas nulle, on ajoute Condition à Valeurs présente dans T2
                If Len(Nz(!Condition)) > 0 Then
                    s2 = "UPDATE T2" _
                         & " SET Valeurs = Valeurs & " & "';" & Nz(!Condition) & "'" _
                         & " WHERE " & s1
                    Debug.Print s2
                    CurrentDb.Execute s2
                End If
            End If
 
            .MoveNext
        Wend
    End With
    MsgBox "traitement terminé. Voir le résultat dans la table T2"
 
SET rs1 = nothing
End Sub

CDLT

[Jonathan191185]

Bonjour,

Je me suis servi de votre code, très bien fait et surtout bien expliqué ;-). J'ai pu l'adapter pour qu'il corresponde exactement à mon besoin.
J'ai un peu galéré mais j'ai réussi à utiliser le split pour obtenir le résultat exact (petite difficulté à passer : le nombre de conditions n'était pas toujours identique).

Un grand MERCI à vous