Discussion :

[badibad]

Bonjour à tous

j’essaye de mettre une vérification sur le numéro de tva belge avec cette fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
 
 
Function Testlc(NOMDUCHAMP) As Long
Testlc = 97 - ((100000000 + Int(NOMDUCHAMP / 100)) * 100) Mod 97
If Testlc = NOMDUCHAMP Mod (100) Then
Testlc = True
Else
MsgBox "LE NUMERO EST FAUX, REVERIFIEZ VOTRE SAISIE"
 
End If

le problème c'est que j'ai un dépassement de valeur. avez vous des solutions ? merci

[marot_r]

Bonjour.

Type tes variables, cela va aider le compilateur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

dim Testlc as double

Devait résoudre le problème.

A+

[PipoWIL]

Bonjour Badibad,

Ton code est intéressant pour verifier le format du numéro de TVA mais sais-tu qu'il est aussi possible de vérifier si le numéro est valide, s'il correspond à une société réellement enrégistrée auprès de l'administration ?
Jette un coup d'oeil sur cette discussion Developpez

[Invité]

Ca semble fonctionner via le webservice:

Les fonctions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Public Function checkVAT(ByVal CountryCode As String, ByVal vatNumber As String, Optional ByRef isErr As Boolean) As Boolean
'Validation du numéro de TVA via VIES : http://ec.europa.eu/taxation_customs/vies/vatRequest.html
    On Error GoTo fin
    Const cURL As String = "http://ec.europa.eu/taxation_customs/vies/services/checkVatService"
    Const cEnv As String = "<env:Envelope xmlns:env='http://schemas.xmlsoap.org/soap/envelope/'>" & _
          "<env:Body><cv:checkVat xmlns:cv='urn:ec.europa.eu:taxud:vies:services:checkVat:types'>" & _
          "<cv:countryCode>CC</cv:countryCode><cv:vatNumber>VN</cv:vatNumber>" & _
          "</cv:checkVat></env:Body></env:Envelope>"
    Dim sEnv As String, sResult As String, oHttp As Object
 
 
    isErr = True
    sEnv = Replace(Replace(cEnv, "CC", CountryCode, , , vbBinaryCompare), "VN", vatNumber, , , vbBinaryCompare)
    Set oHttp = CreateObject("MSXML2.XMLHTTP")
    oHttp.Open "POST", cURL, False: oHttp.send sEnv
    If oHttp.Status = 200 Then
        sResult = getTextBetween(oHttp.responseText, "<valid>", "</valid>")
        checkVAT = (sResult = "true")
        isErr = False
    End If
fin:
    Set oHttp = Nothing
End Function
 
 
'retourne un texte entre deux limites
Private Function getTextBetween(ByVal text As String, ByVal Before As String, Optional ByVal After As String = " ") As String
    On Error Resume Next
    getTextBetween = Split(Split(text, Before)(1), After)(0)
End Function

Le test :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Public Function testCheckVAT()
    Dim CountryCode As String, vatNumber As String
    Dim estErreur As Boolean, estOk As Boolean, i As Long
 
    For i = 1 To 2
        If i = 1 Then
            CountryCode = "BE"
            vatNumber = "0123456789"
        Else
            CountryCode = "RO"
            vatNumber = "4594917"
        End If
 
        estOk = checkVAT(CountryCode, vatNumber, estErreur)
        Debug.Print "Résultat pour:'" & CountryCode; "' - '" & vatNumber & "'"
        Debug.Print vbTab & "-> CheckVAT: " & estOk & " (Erreur: " & IIf(estErreur, "Oui", "Non") & ")"
    Next i
End Function

[electrosat03]

Bonsoir Galoir,

J'essaie depuis pas mal de temps à faire ça, j'ai donc essayé ton code mais après avoir ouvert la page web du site Vies, il ne se passe rien.

Pourrais-tu m'aider un peu sur ton code.

Merci