Discussion :

[TchiotPols]

Bonjour,
Je suis tout nouveau sur ce forum et si je suis là c'est que j'ai un petit problème
Dans un UserForm, en dehors de Labels et d'images autres que pour mon problème, j'ai un ComboBox1 avec une liste de noms de site. J'ai une Image4 qui affiche la photo du site et une Image5 qui affiche le plan d'accès à ce site. Les images qui doivent s'afficher sont enregistrées dans un même répertoire. Tant que les images existent tout se passe bien. Mais comme je n'ai pas fini de tout créer ces images, des sites ne peuvent être traités. Néanmoins je traite ces manques par un traitement d'erreur. L'erreur qui s'affiche lorsque l'image n'est pas trouvée dans le répertoire est la "53". Tout à fait normal. Je traite donc cette erreur "53" en disant : si cette erreur se produit, tu mets à la place de l'image du site une image représentant un "?" enregistrée dans le même répertoire. Le traitement de l'image4 se passe très bien quand l'image n'existe pas mais le traitement ne fonctionne pas pour l'image5. vérification des écritures, du chemin tout est ok. Voici comment je traite ces deux images :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Private Sub ComboBox1_Change()
'ce code permet d'afficher les Images et les Labels cachées à l'ouverture correspondantes au site demandé
 
'rend visible l'image 1
Me.Image1.Visible = True
'rend visible le Label2
Me.Label2.Visible = True
'rend visible l'image 2
Me.Image2.Visible = True
'rend visible le Label3
Me.Label3.Visible = True
'rend visible l'image 3
Me.Image3.Visible = True
'rend visible le Label4
Me.Label4.Visible = True
 
'recherche de la ligne correspondante à la valeur de la ComboBox1
For lig = 1 To 110
    If Sheets("Region").Cells(lig, 12).Value = Me.ComboBox1.Value Then
        Me.Label2.Caption = Sheets("Region").Cells(lig, 13).Value   'téléphone
        Me.Label4.Caption = Sheets("Region").Cells(lig, 14).Value   'adresse postale
        Me.Label3.Caption = Sheets("Region").Cells(lig, 15).Value   'adresse mail
        Exit For
    End If
Next lig
    'rend visible le Label5 - légende de l'image 4 correspondant à la photo du site
    Me.Label5.Visible = True
    'rend visible l'image 4 - si elle existe - image de la photo du site
    Me.Image4.Visible = True
    'blocage du dimensionnement automatique de l'image 4
    Me.Image4.AutoSize = False
    'type d'affichage de la photo du site dans l'image 4
    Me.Image4.PictureSizeMode = fmPictureSizeModeStretch
    'affichage de l'image (si elle exite) émanant du répertoire d'enregistrement des images
    On Error GoTo TraiteError1                    ' - ici le traitement se fait bien - aucun problème -
    Me.Image4.Picture = LoadPicture("C:\Users\moi\Documents\Cartes des régions\SITE_" & Me.ComboBox1.Value & ".jpg")
    GoTo ligne
TraiteError1:
    'si erreur affichage image site inconnu
    Me.Image4.Picture = LoadPicture("C:\Users\moi\Documents\Cartes des régions\SITE non connu.jpg")
ligne:
    'description identique que précédemment pour l'image 5 (plan d'accès au SITE),sa légende le Label6 et l'information pour le zoom le Label7
    Me.Label6.Visible = True
    Me.Label7.Visible = True
    Me.Image5.Visible = True
    Me.Image5.AutoSize = False
    Me.Image5.PictureSizeMode = fmPictureSizeModeStretch
    On Error GoTo TraiteError2              ' - c'est ici mon problème - ne veut pas travailler comme pour l'image4 - affiche erreur 53 - 
    Me.Image5.Picture = LoadPicture("C:\Users\moi\Documents\Cartes des régions\SITE_" & Me.ComboBox1.Value & "_plan_acces.jpg")
    Exit Sub
TraiteError2:
     'si erreur affichage image site inconnu
    Me.Image5.Picture = LoadPicture("C:\Users\moi\Documents\Cartes des régions\SITE non connu.jpg")
End Sub

[Patrice740]

Bonjour,

Voir ici :
https://silkyroad.developpez.com/VBA...nErreurs/#LIII
et notamment : https://silkyroad.developpez.com/VBA...eurs/#LIII-A-2

[mercatog]

Bonjour

je préfère que tu évites les on error. Elles sont gérables en amont

Exemple non testé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Me.Image4.Visible = True
'blocage du dimensionnement automatique de l'image 4
Me.Image4.AutoSize = False
'type d'affichage de la photo du site dans l'image 4
Me.Image4.PictureSizeMode = fmPictureSizeModeStretch
'affichage de l'image (si elle exite) émanant du répertoire d'enregistrement des images
InsertPicture Me.Image4, "C:\Users\moi\Documents\Cartes des régions\SITE_" & Me.ComboBox1.Value & ".jpg"
 
 
'description identique que précédemment pour l'image 5 (plan d'accès au SITE),sa légende le Label6 et l'information pour le zoom le Label7
Me.Label6.Visible = True
Me.Label7.Visible = True
Me.Image5.Visible = True
Me.Image5.AutoSize = False
Me.Image5.PictureSizeMode = fmPictureSizeModeStretch
InsertPicture Me.Image5, "C:\Users\moi\Documents\Cartes des régions\SITE_" & Me.ComboBox1.Value & "_plan_acces.jpg"
End Sub
 
Private Sub InsertPicture(Img As Object, Chemin As String)
 
If Dir(Chemin) = "" Then Chemin = "C:\Users\moi\Documents\Cartes des régions\SITE non connu.jpg"
 
Img.Picture = LoadPicture(Chemin)
End Sub

[TchiotPols]

Je vous remercie pour ces réponses rapides. J'étais sûr d'avoir les bonnes infos.
Merci à Patrice 740 pour cette lecture intéressante.
Merci à mercatog pour ces lignes de macro qui fonctionnent à merveille. En effet c'est nettement mieux que la gestion des erreurs. Je retiens et prends note ...