Discussion :

[florent149]

Bonjour le forum

Quelqu'un pourrait il m'aider a debugger ce petit bout de code rebelle svp?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
For SheetTest = 1 To ThisWorkbook.Worksheets.Count
    If ThisWorkbook.Worksheets(SheetTest).Name = "Stage " & StageNumber & " Summary" Then
        Application.DisplayAlerts = False
        Sheets("Stage " & StageNumber & " Summary").Delete
    End If
Next SheetTest
 
...
 
 
ActiveWorkbook.Sheets.Add after:=ActiveSheet
ActiveSheet.Name = "Stage " & StageNumber & " Summary"

Donc je cherche la feuille que je veux effacer, je l'efface et ensuite j'insere une nouvelle feuille et je lui donne le nom de la precedente feuille. Sauf qu'en fait l'effacement de la feuille ne marche pas donc ca bugge quand je renomme car 2 feuilles ne peuvent pas avoir le meme nom.
Et quand je regarde la valeur de SheetTest en mode break a la fin de la boucle, je vois qu'il ne va pas jusqu'a la valeur de la derniere sheet. J'ai l'impression que ca vient du fait qu'il y a une discontinuite dans la numerotation des pages: je passe de 27 a 35, car j'ai efface quelques feuilles. Ca pourrait etre ca? et dans ce cas que puis je faire?

Merci de votre aide et n'hesitez pas a demander des precisions si je n'ai pas ete clair (ce qui ne m'etonnerait pas... )

PS: je precise juste que StageNumber est un entier parfaitement defini

[SfJ5Rpw8]

...Et quand je regarde la valeur de SheetTest en mode break a la fin de la boucle, je vois qu'il ne va pas jusqu'a la valeur de la derniere sheet. J'ai l'impression que ca vient du fait qu'il y a une discontinuite dans la numerotation des pages: je passe de 27 a 35, car j'ai efface quelques feuilles. Ca pourrait etre ca? et dans ce cas que puis je faire?...

tu peu utiliser la gestion d'erreur...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
  Dim st As String
  Dim iMemo As Integer 'Memo numero de feuille
  st = "Stage " & StageNumber & " Summary"
  bMemoAlert = Application.DisplayAlerts
  Application.DisplayAlerts = False
  On Error Resume Next
  iMemo = Sheets(st).Index 'Memorise index
  Sheets(st).Delete
  Application.DisplayAlerts = bMemoAlert
  On Error GoTo 0
 Debug.Print iMemo
 If iMemo < 1 Then iMemo = 1
 If iMemo <= Sheets.Count Then
   Worksheets.Add(before:=Sheets(iMemo)).Name = st
   Else
   Worksheets.Add(after:=Sheets(Sheets.Count)).Name = st
 End If

[conconbrr]

Question : Pourquoi tu n'utiliserais pas une boucle for each?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub testforum()
    Dim Feuille As Worksheet
    Dim iStageNumber As Integer
 
    iStageNumber = 1
 
    For Each Feuille In ActiveWorkbook.Worksheets
        If Feuille.Name = "Stage " & iStageNumber & " Summary" Then
            Application.DisplayAlerts = False
            Feuille.Delete
            Application.DisplayAlerts = True
            Exit For
        End If
    Next Feuille
 
    ActiveWorkbook.Sheets.Add after:=ActiveSheet
    ActiveSheet.Name = "Stage " & iStageNumber & " Summary"
 
End Sub

[florent149]

Reponse: parce que je n'y avais pas pense!

Ben voila c'est impec ca roule. Merci beaucoup!