Discussion :

[STEF_1]

Voilà mon pb,

Je voudrais changer le paramètre régionale : Date Courte, en le passant d'un format jj/mm/aa en jj/MM/aaaa

J'ai bien trouver comment récupérer le format via l'API :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Private Declare Function GetDateFormat Lib "kernel32" Alias "GetDateFormatA" (ByVal Locale As Long, ByVal dwFlags As Long, lpDate As SYSTEMTIME, ByVal lpFormat As String, ByVal lpDateStr As String, ByVal cchDate As Long) As Long

mais comment le changer ( si cela est possible ...) ?????????

merci de votre coopération

[shwin]

salut, il faut justement que je post un code-source que ce sujet

voici un code que j'ai fait hier soir, jsutement il fait ce que tu demande

dans un module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
'---------------------------------------------------
Public Declare Function GetUserDefaultLCID Lib "kernel32" () As Long
Public Declare Function SetLocaleInfo Lib "kernel32" Alias "SetLocaleInfoA" (ByVal Locale As Long, _
                     ByVal LCType As Long, ByVal lpLCData As String) As Boolean
Public Declare Function GetLocaleInfo Lib "kernel32" Alias "GetLocaleInfoA" (ByVal Locale As Long, _
                     ByVal LCType As Long, ByVal lpLCData As String, ByVal cchData As Long) As Long
 
Public Const LOCALE_SSHORTDATE = &H1F
 
Public Function GetFormatDate() As String
    Dim sBuffer As String
    Dim nRet    As Long
 
    sBuffer = String(256, 0)
    nRet = GetLocaleInfo(GetUserDefaultLCID(), LOCALE_SSHORTDATE, sBuffer, Len(sBuffer))
 
    If nRet > 0 Then
        GetFormatDate = Left(sBuffer, nRet - 1)
        Else
            GetFormatDate = ""
    End If
End Function
 
Public Function SetFormatDate() As Boolean
Dim ret As Boolean
ret = SetLocaleInfo(GetUserDefaultLCID(), LOCALE_SSHORTDATE, "yyyy-MM-dd")
SetFormatDate = ret
End Function

je l'appel de cette manière

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub VerifFormatDate()
If (StrComp(GetFormatDate, "yyyy-MM-dd") <> 0) Then
        If (SetFormatDate = False) Then
            MsgBox "Une erreur système s'est produite, veuillez redémarrer l'application." & vbNewLine & _
                   "Si l'erreur persiste, aller dans les paramètre régionaux sous l'onglet 'DATE'. " & _
                   "Changez le 'style de date courte' pour 'aaaa-MM-dd'.", vbCritical, "Erreur critique"
        End If
End If
End Sub

A toi de changer le format de date pour celui qui te convient

[STEF_1]

C'est "Au poil"

J'avais trouvé l'API SetLocalInfo mais je pataugais au niveau des variables.

Encore merci

A++