Discussion :

[Louax]

Bonjour,
J'aimerai savoir comment récupérer la valeur d'un item d'un dictionnaire.
Voici mon code, il doit y avoir une petite erreur mais je ne trouve rien qui m'aide sur Internet.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Sub UserForm_Initialize()
  Set MonDico = CreateObject("Scripting.Dictionary")
 
  For Each c In Range([T5], [T25])
     If Not MonDico.Exists(c.Value) Then MonDico.Add c.Value, c.Value
  Next c
 
  a = MonDico.Item(1)
  b = MonDico.Item("1")
  d = MonDico(1)
  e = MonDico("1")
End Sub

J'ai bien une solution en écrivant : a=MonDico.Items
J'ai alors la possibilité de saisir z=a(1) pour avoir la première valeur de mon dictionnaire

Mais s'il existe une meilleure façon d'obtenir cette valeur, je suis preneur.

Merci

[Trystan441]

Bonjour,

Si tu veux récupérer la valeur d'un item en particulier dans ton dictionnaire, sans passer par une variable tableau, il te faut forcément la clé associée.

Je pense que tu le connais déjà mais au cas où je t'invite à suivre le lien ci-dessous :
Objet Dictionary

Une autre solution si jamais tu n'as pas de valeur associée à une clé :
Tu incrémentes une variable compteur. La clé prendrait alors ce chiffre puis la valeur correspondrait à tes anciennes clés (j'espère que je suis clair)

[Thumb down]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
k=MonDico.Keys
 a = MonDico(k(1))

[MarcelG]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
a = MonDico.Item(1)
  b = MonDico.Item("1")
  d = MonDico(1)
  e = MonDico("1")

Ces lignes constituent chacune une ineptie.
Plutôt que de coder au hasard, tu peux te documenter sur la notion de dictionnaire au préalable pour pouvoir mettre ces informations en application.

Les Items d'un dictionnaire constituent une "collection" dont on interroge la valeur d'un indice.
Autrement dit:
- Cette "collection" se désigne au pluriel
- L'indice est numérique

Autrement dit, pour obtenir la valeur du 1er Item

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Mondico.Items(0)

A noter: les items sont indicés à partir de 0

D'autre part, je ne peux que te conseiller de déclarer obligatoirement l'intégralité de tes variables.
Pour ce faire, dans l'éditeur VBE, Outils\Options\Editeur ==> Déclaration obligatoire des variables (Option à cocher)

Plus précisément ici, en activant la Référence Scripting RunTime (Menu Outils\Références)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim mondico As Scripting.Dictionary

La saisie étant généralement semi-automatique, la gestion des propriétés et méthodes du dictionnaire en sera favorisée.

Ainsi.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Option Explicit
 
Sub test_dico()
 
Dim mondico As Scripting.Dictionary
Dim c As Range
Dim i As Byte
Dim lesitems As Variant
 
Set mondico = CreateObject("Scripting.Dictionary")
 
For Each c In Feuil1.Range("A1:A3")
          With c
                  If Not mondico.Exists(.Value) Then mondico.Add .Value, .Value
          End With
Next c
 
lesitems = mondico.Items
 
For i = LBound(lesitems) To UBound(lesitems)
      Debug.Print lesitems(i)
Next i
 
Set mondico = Nothing
 
End Sub

[boisgontierjacques]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub essai()
  Set d = CreateObject("scripting.dictionary")
  d.Item("Dupont") = 35 ' ou If Not d.Exists("aa") Then d.Add "Dupont", 35
  d.Item("Durand") = 40
  d.Item("Martin") = 27 ' ou d("Durand")=40
  d.Item("Espinasse") = 32
  MsgBox d("Martin")
  'MsgBox d.Keys(2)   ' ne fonctionne pas
  'MsgBox d.Items(2)  ' ne fonctionne pas
End Sub

pour obtenir ce que vous voulez,il faut :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub essai2()
  Dim d As New Dictionary  '  Dans Outils/Références Microsoft Scripting Runtime
  d.Item("Dupont") = 35 ' ou If Not d.Exists("aa") Then d.Add "Dupont", 35
  d.Item("Durand") = 40
  d.Item("Martin") = 27 ' ou d("Durand")=40
  d.Item("Espinasse") = 32
  MsgBox d.Keys(2)
  MsgBox d.Items(2)
End Sub

Boisgontier

[Louax]

Merci
Grace à vous mon code fonctionne parfaitement et devient

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub testdico()
Dim mondico As New Dictionary
 
  For Each c In Range([T5], [T25])
     If Not mondico.Exists(c.Value) Then mondico.Add c.Value, c.Value
  Next c
 
  a = mondico.Items(1)
 
End Sub

Maintenant je ne sais pas pourquoi cela ne fonctionnait avec Set mondico = CreateObject("Scripting.Dictionary"), mais bon ce n'est pas très important...
Je clôture résolu

[MarcelG]

Bonjour,

Maintenant je ne sais pas pourquoi cela ne fonctionnait avec " Set mondico = CreateObject("Scripting.Dictionary") "

Quel est le message d'erreur?

mais bon ce n'est pas très important...

Si!
Ne serait-ce que pour ton information et, partant, tes développements futurs.