Discussion :

[Krimo1973]

Bonjour je suis nouveau sur le forum et je débute sur VBA . je veux créer un code qui ouvre un fichier normé chaque mois
Le fichier avec son format normé est : Balance 122019v20200107.xlsx ( MOIS-ANNEE V DATE DU JOUR DU FICHIER).
Une fois le fichier ouvert je cherche à convertir en nombre les valeurs contenues dans la colonne A et cela à chaque qu'il ya une valeur qui existe dans la colonne A.
Voici mon code actuellement , c'est incomplet et ma fonction conversion en nombre n'est pas concluante.
Je vous remercie de votre aide par avance . l'objectif étant de m'appuyer sur vos connaissances

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Maj_GL()
'
' Maj_GL Macro
'
 
    Workbooks.Open Filename:= _
        "T:\Administratif & Financier\reportings mensuels\2019\12 Decembre 2019\J+5\Balance 122019v20200107.xlsx"
    Sheets("GL Général").Select
    Range("A:A").NumberFormat = "0.00"
 
End Sub

[zoltar_x]

Il faut d'abord connaitre le type de la donnée que tu as dans la colonne A avec la fonction Type() côté tableur. La fonction renvoie 1 si c'est un nombre et 2 si c'est du texte. Coté développeur, tu peux utiliser la fonction Cdbl pour forcer la conversion en Double (type décimal) cellule par cellule c'est-à-dire avec une boucle.

[Krimo1973]

Merci pour votre réponse . le contenu est de la colonne (A) est du texte. Par contre je ne saurais pas coder avec une boucle . Pouvez vous m'aider ?

Merci

[zoltar_x]

Essaye ça. La conversion en Double s'affiche dans la colonne 2.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub conversion()
 
    Dim i As Long, derniere_ligne As Long
 
    Worksheets(1).Select
 
    derniere_ligne = ActiveSheet.UsedRange.Rows.Count
 
    For i = 1 To derniere_ligne
 
        Cells(i, 2) = CDbl(Cells(i, 1))
 
    Next i
 
End Sub

[Krimo1973]

Merci encore . Est il possible me documenter le code à chaque étape car je ne cherche pas à prendre des solutions toutes faites . L'objectif est de me former également

Merci par avance

[zoltar_x]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub conversion()
 
    Dim i As Long, derniere_ligne As Long 'Déclaration de 2 variables de type Long (grand entier)
 
    Worksheets(1).Select 'Sélection de la première feuille du classeur
 
    derniere_ligne = ActiveSheet.UsedRange.Rows.Count 'Stockage dans la variable dernier_ligne du nombre de lignes de la plage de cellules utilisée (UsedRange)
 
    For i = 1 To derniere_ligne ' Boucle
 
        Cells(i, 2) = CDbl(Cells(i, 1)) 'Conversion en Double (décimal) des cellules de la colonne 1 vers les cellules de la colonne 2. Cells(ligne, colonne)
 
    Next i
 
End Sub

[Philippe Tulliez]

Bonjour,

Merci pour votre réponse . le contenu est de la colonne (A) est du texte. Par contre je ne saurais pas coder avec une boucle . Pouvez vous m'aider

Il n'y a aucune raison d'utiliser une boucle pour formater dans une colonne précise l'ensemble des lignes de cette colonne et il n'y aucune raison d'utiliser la méthode Select en VBA (Sauf cas exceptionnel)

La propriété permettant de formater un nombre est NumberFormat

Exemple pour une cellule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 With ThisWorkbook.Worksheets("Feuil1")
 .Range("a2").NumberFormat = "#,##0.0#"
 End With

Exemple pour une colonne entière

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 With ThisWorkbook.Worksheets("Feuil1")
 .Range("a2:A20").NumberFormat = "#,##0.0#"
 End With

mais évidemment ce n'est pas intéressant car ceci est "hardcodé"

Pour connaître la plage complète d'une liste de données commençant en A1 et à condition bien entendu que la première ligne et la première colonne soient remplies on utilise la propriété CurrentRegion (pour une plage classique mais il est plus intéressant d'utiliser les tableaux structurés (objet ListObjects).)
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(A1").CurrentRegion

Petit exemple pour le formatage de la colonne 2 (nombre avec séparateur de millier et deux décimales dont une obligatoire) et colonne 4 (date) d'une plage de données commençant en A1 de la feuille nommée Feuil1 du classeur où se trouve le code VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub t()
 ' Déclaration
 Dim rng As Range     ' Plage complète
 Dim rngData As Range ' Place uniquement des données
 ' Assignation
 Set rng = ThisWorkbook.Worksheets("Feuil1").Range("A1").CurrentRegion
 With rng
  Set rngData = .Offset(1).Resize(.Rows.Count - 1)
 End With
 ' Formatage des cellules des colonnes 2 et 4
 With rngData
 .Columns(2).NumberFormat = "#,##0.0#"
 .Columns(4).NumberFormat = "ddd* dd-mm-yyyy" ' Date
 End With
 ' Fin du process
 Set rng = Nothing: Set rngData = Nothing
End Sub

[EDIT]
Attention : Ce que je viens d'expliquer n'a rien à voir avec le titre de ta discussion Macro convertir nombre mais bien un formatage. Ce n'est pas la même chose

• S'il s'agit de faire de la conversion, il y a lieu d'utiliser les fonctions prévues à cet effet
• S'il s'agit de remplacer des . par des , (possible avec des ouvertures de fichier csv ou txt il faudra utiliser la méthode Replace
• S'il s'agit de reformater des dates qui proviennent également de fichier csv ou txt il y a deux types de formules à utiliser (cas de date en texte, cas de date nombre mais sous format mm-dd-aa

[Krimo1973]

Bonjour Mr Tulliez
Merci pour votre réponse . Pour répondre à votre question sur select , en fait lorsque mon fichier s'ouvre je selectionne l'onglet GL Général et une fois selectionné je demande à ma plage de donnée ( A:A) de se convertir en nombre car les données sont en texte . j'ai rajouté la valeur "#,##0.0#" , mais j'ai toujours des données en format texte . Je ne comprends pas la raison

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Workbooks.Open Filename:= _
        "T:\Administratif & Financier\reportings mensuels\2019\12 Decembre 2019\J+5\Balance 122019v20200107.xlsx"  
    Sheets("GL Général").Select
    Range("A:A").NumberFormat = "#,##0.0#"

End Sub

[Philippe Tulliez]

Bonjour,

Pour répondre à votre question sur select , en fait lorsque mon fichier s'ouvre je selectionne l'onglet GL Général et une fois selectionné je demande à ma plage de donnée ( A:A) de se convertir en nombre car les données sont en texte

Oui, merci, j'avais compris.
En VBA on peut avoir n'importe quelle feuille active et écrire dans n'importe quelle cellule de n'importe quelle feuille présente dans un classeur quelconque ouvert à condition de préciser la parentalité complète de l'objet. A savoir pour une cellule : sa feuille et son classeur
Donc je persiste et signe, pas besoin de Select ni d'Activate c'est inutile et cela ralenti l'exécution du programme

j'ai rajouté la valeur "#,##0.0#" , mais j'ai toujours des données en format texte . Je ne comprends pas la raison

Puis-je voir le code complet ?

Si les nombres sont cadrés à gauche à l'affichage, il s'agit vraissemblablement de texte et pas de nombre, il faut passer par une étape intermédiaire

[EDIT]
Essayez ceci (voir le code que j'ai proposé précédemment)
Avant de formater les nombres insérer la ligne qui remet l'ensemble des cellules de la feuille au format Standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 With rngData
 .Worksheet.Cells.NumberFormat = "General"
 .Columns(2).NumberFormat = "#,##0.0#"
 .Columns(4).NumberFormat = "ddd* dd-mm-yyyy" ' Date
 End With

[zoltar_x]

Voici la sélection de cellules avec UsedRange



Et voici la sélection avec Currentregion



Personnelement, je choisis UsedRange au cas où il y aurait une discontinuité des données (données non adjacentes).

[Patrice740]

Bonjour le Fil,

@Philippe : si comme tu le suggère les cellules contiennent du texte, le fait de changer le format ne suffit pas quand les cellules contiennent des valeurs (i.e. pas le résultat de formules).

Il faudrait que le demandeur précise ça, en mettant l'alignement horizontal au format standard pour savoir comment sont cadrées les données.

[Krimo1973]

Merci Mr Tulliez . Mon code est dans le premier message avec la modification apporté dans un second temps sur NumberFormat = "#,##0.0#".
Pour ce qui est du format des cellules . Le format est standard.

Merci encore

[Krimo1973]

Voici mon fichier sur le lequel je veux faire les traitements . Cela sera peut être plus parlant

Bien Cordialement

[zoltar_x]

Re,

D'abord un copier > coller valeurs seulement parce que tes cellules contiennent des formules.
Voila ton fichier collé en A1


Et les types de chaque cellule



Apparemment c'est bon : dans tes colonnes C à G, à part les intitulés de la première ligne qui sont du texte (String), tu as un format décimal (Double) après. C'est bien des nombres.

[Patrice740]

Bonjour,

Simplement :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub test()
   With Worksheets("GL Général").UsedRange.Columns(1)
      .NumberFormat = "General"
      .Value = .Value
   End With
End Sub

[Philippe Tulliez]

Bonjour Patrice,

@Philippe : si comme tu le suggère les cellules contiennent du texte, le fait de changer le format ne suffit pas quand les cellules contiennent des valeurs (i.e. pas le résultat de formules).

D'où ma proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 With rngData
 .Worksheet.Cells.NumberFormat = "General"
 .Columns(2).NumberFormat = "#,##0.0#"
 .Columns(4).NumberFormat = "ddd* dd-mm-yyyy" ' Date
 End With

du fil #9

[Krimo1973]

merci bien

Merci Messieurs pour la qualité juste de ces échanges , juste un complément avant de clôturer cette discussion .
Je comprends pas les synthaxe ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
.NumberFormat = "General"
.Value = .Value   ( porquoi on répéte 2 fois la propriété value ?)

Et enfin si j'ai bien compris l'instruction usedRange va sélectionner automatiquement la plage de donnée en colonne 1 sans spécifier le nombre de lignes , car potentiellement mon fichier n'a jamais le même nombre de lignes .

Bien cordialement

[zoltar_x]

Et enfin si j'ai bien compris l'instruction usedRange va selectionner automatiquement la plage de donnée en colonne 1 sans spécifier le nombre de lignes , car potentiellement mon fichier n'a jamais le même nombre de lignes .

Bien cordialement

UsedRange va sélectionner la plage utilisée, jusqu'à la dernière ligne et jusqu'à la dernière colonne et cela même (et c'est la différence avec CurrentRegion) s'il y a des lignes vides ou des colonnes vides, comme dans l'exemple ci-dessus.

[Krimo1973]

Il manque ce point :
Je ne comprends pas les syntaxes ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 .NumberFormat = "General"
 .Value = .Value ( porquoi on répète 2 fois la propriété value ?)

Merci par avance

[Philippe Tulliez]

Bonjour,

Je ne comprends pas les syntaxes ci-dessous
.NumberFormat = "General"
.Value = .Value ( porquoi on répète 2 fois la propriété value ?)

La première ligne met au format standard, les cellules concernées
La deuxième ligne est un peu l'équivalent d'un Copier/Collage spécial-Valeur

Dans un objet Range la propriété Value contient la valeur (ou le résultat de la formule), la propriété Formula contient la formule donc
si en cellule F2, nous avons la formule (ici une simple fonction)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(B2:E2)

Dans Objet.Propriété, (où objet est par exemple Range("E2")), la propriété

• Formula renverra =SUM(B2:E2)
• Value renverra la valeur dans la cellule par exemple 15030 (cad ici le résultat renvoyé par la formule)
• Text renverra la valeur telle qu'elle est formatée, par exemple 15 030 €

En écrivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("E2").Value = Range("E2").Value

on force la cellule à ne conserver que la valeur renvoyée par la formule (propriété Formula)