Discussion :

[harpyopsis]

Bonjour à tous !

J'utilise CopyObject pour créer des Backups d'une Table de tarification.

Cette Table ("Actes") est liée soit à un fichier accdb, soit à un mdf SQL Server. Ces copies "Actes_backup_..." restent locales, elles ne doivent pas être répliquées/synchronisées.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.CopyObject , NewTableName, acTable, "Actes"

CopyObject fonctionne bien, sauf que les copies apparaissent dans le Panneau de Navigation en temps que Tables liées, au lieu de Tables locales (voir image). Après vérification, les copies n'apparaissent effectivement pas dans les fichiers back-end d'origine.



Un "Copy" - "Paste Table as" avec choix "Structure and Data (local table)" ne produit pas cette incohérence. Pourquoi ?

J'ai essayé de mettre le chemin d'accès en "destination", mais sans succès.

Un Compact and Repair est sans effet.

J'évite de faire une "Make Table Query" à la place de CopyObject pour des questions de clefs uniques et de tables filles.

Où se situe le bug ?

Merci !

[marot_r]

Bonjour.

Je ne pense pas que tu puisses copier une table liée, tu peux juste copier le lien vers cette table.

A+

[Zekraoui_Jakani]

Vous pouvez vous inspirer de ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub unlinkTables()
    Const myTableName As String = "NomDeMaTable"   ' à adapter
    Const SourceDBPath As String = "C:\Users\..etc\NomDeLaDatabase.accdb"  ' à adapter
    Dim tbl As TableDef, B As Boolean: B = False
 
    For Each tbl In CurrentDb.TableDefs
        If tbl.Name Like myTableName Then
            If Len(CurrentDb.TableDefs(myTableName).Connect) > 0 Then
                ' Supprimer la table liée.
                DoCmd.DeleteObject acTable, myTableName
                MsgBox "'" & myTableName & "' vient d'être supprimée !"
                'Puis l'importer en tant que table locale
                DoCmd.TransferDatabase acImport, "Microsoft Access", (SourceDBPath), acTable, (myTableName), (myTableName) & "_Copy"
                MsgBox "'" & myTableName & "' vient d'être importée en LOCAL !"
            Else
                MsgBox "Attention !  '" & myTableName & "' n'est pas une table liée ! " & _
                        "Elle ne sera pas supprimée.", vbExclamation, "Table NON liée"
            End If
            B = True
            Exit For
        End If
    Next tbl
    If B = False Then MsgBox "la table '" & myTableName & "' n'existe pas !"
 
End Sub

[harpyopsis]

Effectivement, un très grand merci à tous les deux !

Docmd.CopyObject ne crée bel et bien qu'une copie du lien, soit une coquille vide ! Dangereuse en plus, car si on y effectue des suppressions de nettoyage (Delete Query), les enregistrements en question seront impitoyablement supprimés dans la Table d'origine, ce qu'on ne souhaite évidemment pas !

Rien de tout ceci ne se trouve clairement expliqué dans la doc de Microsoft, ou alors il faut bien chercher !

Docmd.TransferDatabase de Zekraoui crée de véritables copies locales (structure + données), c'est parfait !

Il faut peut-être adapter l'argument DatabaseType en fonction de l'environnement...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
DoCmd.TransferDatabase acImport, "Microsoft Access",
'ou bien
DoCmd.TransferDatabase acImport, "ODBC Database",    ' et bien d'autres aussi...

Voilà le résultat !



Merci encore pour votre éclairage inestimable !

[harpyopsis]

Voilà le code complet avec TransferDatabase, qui numérote et nettoie les sauvegardes. Cela peut faire gagner du temps à quelqu'un !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Private Sub CmdMakeBackUp_Click()
 
    '1. Generate unique incremented name for new Backup (= Name + User + Date + Increment in brackets if needed)
            Dim ObjectRootName As String, ObjectFullName As String
                ObjectRootName = "Actes_BackUp_" & _
                                FctGetUserInitial(CrtUserID) & "_" & _
                                DatePart("d", Now) & "_" & DatePart("m", Now) & "_" & DatePart("yyyy", Now)
            ObjectFullName = ObjectRootName
 
    '2. Iterate Table collection to detect existing backups
            Dim db As DAO.Database, tdf As DAO.TableDef, TableAlreadyExists As Boolean, i As Long, ii As Long
                Set db = CurrentDb
            TableAlreadyExists = False
            i = 1
            ii = 0
 
            For Each tdf In db.TableDefs
                If (tdf.Attributes And dbSystemObject) = 0 Then
                    If tdf.Name = ObjectFullName Then
                        TableAlreadyExists = True
                        ObjectFullName = ObjectRootName & " (1)"
                    End If
                    If Right(tdf.Name, 1) = ")" Then
                        i = (Left((Right(tdf.Name, 2)), 1)) + 1
                        ObjectFullName = ObjectRootName & " (" & i & ")"
                    End If
                End If
                ii = ii + 1
            Next tdf
 
            Set db = Nothing
 
    '3. Create a local copy of linked Table "ActesTempCopy" (avoid using brackets)
            Dim SourceDBPath As String
                SourceDBPath = GetDBPath & "Data\VetoDBaseActes.accdb"
            DoCmd.TransferDatabase acImport, "Microsoft Access", (SourceDBPath), acTable, "Actes", "ActesTempCopy"
 
    '4. Cull records belonging to sibling company
            DoCmd.RunSQL "DELETE ActesTempCopy.*, ActesTempCopy.VetStructureID " & _
                        "FROM ActesTempCopy " & _
                        "WHERE (((ActesTempCopy.VetStructureID)<>" & CrtVetStructureID & "));"
 
    '5. Rename Table with full name including brackets if any
            DoCmd.Rename ObjectFullName, acTable, "ActesTempCopy"
 
    '6. Update display
            UpdateMyBackUpList
            EnableMyButtons
 
End Sub