Discussion :

[bougalix]

Bonjour le Forum,

mon problème est simple en apparence mais je n'y arrive pas. je vais essayer de vous l'exposer aussi clairement que possible. Merci par avance de votre précieuse aide.

Dans mon projet VBA, j'ai plusieurs userforms (usf) dont le fonctionnement commence par la saisie dans un TextBox (tbClient) quelques caractères pour rechercher le client selon le contexte de l'usf, par exemple UFSource.
Après avoir saisi quelques lettres dans tbClient, un bouton Seek (dans UFSource) permet de lancer un usf UFSeek contenant un textbox tbSeek et une ListView LV alimentée selon le contexte de UFSource.
Au fur et à mesure que le tbSeek change les items de LV sont filtrés. Après un événement LV_Click je souhaite récupérer l'item sélectionné par un moyen que j'ignore, fermer UFSeek et continuer mon traitement dans UFSource avec tBClient = l'item

Mon problème est que je n'arrive pas à passer la valeur de l'item sélectionné dans le LV par une instruction du type Forms("UFSource").Controls("tbClient")=Item avant de fermer UFSeek

Bien entendu je souhaite que UFSeek soit un outil commun à tous mes usf.

Dans un module (indépendant de UFSeek), j'ai donc créé une sub UFSeek_Show(UFSource As UserForm, tbSource As String) qui est appelée par le bouton Seek qui affiche UFSeek en ayant au préalable chargé LV et dupliqué le contenu de tbSource dans tbSeek. ce même module contient également les sub tbSeek_Change et LV_Click.

Après plusieurs recherches j'ai pensé qu'un module de classe pouvait m'aider, mais je n'en ai jamais utilisé et je n'arrive pas à structurer la démarche.

Merci de votre aide.

[BENNASR]

bonjour
j'ai eu le même besoin et j'ai trouvé mon bonheur ... donc ce n'est pas mon code
donc j'ai un userform pour rechercher et puis double clic sur le code souhaité à ce moment s'ouvre une nouvelle userform avec un textbox qui prend comme valeur le code déjà choisi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean) 'au double-Click dans la ListBox1
Dim LI As String
LI = Me.ListBox1 'récupère la ligne de la ListBox1
With UserForm1 'prend en compte l'UserForm1
    With .ComboBox1 'prend en compte la TextBox2
        'sélectionne le texte
        .SetFocus 'place le curseur
        .SelStart = 0 'début de la sélection
        .SelLength = .TextLength 'longueur de la sélection
        .Value = LI
    End With
    Unload Me 'vide et ferme l'UserForm2
    .Show 'affiche l'UserForm1
 
End With 'fin de la prise en compte de l'UserForm1
 
End Sub

j'espère que ça t'aide à avancer
Bonne Continuation

[bougalix]

Bonjour BENNASR,

Merci pour ta réponse aussi rapide.
En réalité même le nom du UFSource est un argument (l'idée est de paramétrer en une ligne de code l'appel de UFSeek et de récupérer le contenu du tbSeek depuis n'importe quel userfom appelant UFSource) .
Donc il faut le passer en argument. Désolé si ce n'était pas clair dans mon énoncé .
Depuis ce matin j'ai pensé à utiliser la collection Userform pour boucler dessus jusqu'à trouver celui que je veux remplir (plus exactement remplir le controle tbSource dans UFSource).

Ce n'est certainement pas la méthode la plus orthodoxe ou la plus directe mais ça me permet d'avancer (très certainement qu'un module de classe pour instancier le contrôle du userform devrait fonctionner et ça serait plus "classe")

Voici mon code pour ceux que ça peut aider.
(à insérer dans le userform UFSource)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub UFSeek_Show(UFSource As String, tbSource As String, LeftPos, TopPos) 'passage des paramètres à l'UFSeek
 
If UFSeek.tbSeek = "" Then Importer_Client (UFSource) 'sub qui rempli la LV selon le contexte de UFSource
 
UFSeek.LView.ColumnHeaders.Clear
UFSeek.LView.ColumnHeaders.Add , , "Client" 
UFSeek.LView.ColumnHeaders(1).Width = 265
UFSeek.tbSeek.SetFocus
UFSeek.LView.Tag = tbSource
 
UFSeek.Show
 
'pendant l'affichage de UFSeek, le textbox tbSeek est renseigné (depuis l'item selectionné dans LView)
'après une instruction UFSeek.Hide il faut récupérer la valeur de tbSeek
 
For i = 0 To VBA.UserForms.Count - 1
    If VBA.UserForms.Item(i).Name = UFSource Then
        With VBA.UserForms.Item(i).Controls(tbSource)
            .Value = UFSeek.tbSeek
            If .Value <> "" Then 'mise en forme du controle tbSource lorsqu'il est rempli avec l'item recherché
                .Tag = UFSeek.tbSeek
                .BackColor = &H80FFFF
                .Font.Bold = True
            End If
        End With
    End If
Next i
 
End Sub

Merci encore

[Pierre Fauconnier]

Salut

[...]
l'idée est de paramétrer en une ligne de code l'appel de UFSeek et de récupérer le contenu du tbSeek depuis n'importe quel userfom appelant UFSource
[...]

C'est une EXCELLENTE idée . C'est une architecture très professionnelle (la seule qui vaille, en fait).

Voici la mise en place de ce que tu souhaites obtenir, pour ce que je j'ai cité de ton message. Je ne dis donc pas ici comment tu dois filtrer et arriver à la bonne valeur dans usf2 (apparemment, tu as cette solution), mais comment architecturer ton code pour découpler tes userforms, qui devraient être totalement indépendants l'un de l'autre.

Je te donne ici un userform tout simple avec un seul textbox et un bouton de commande. Lorsque l'on clique sur le bouton, une propriété publique du usf appelée Result est valorisée puis le formulaire est masqué. La fonction qui l'a appelé récupère alors la valeur de Result et la met à disposition du reste du code en retour de fonction. Tu as ainsi UNE LIGNE DE CODE à utiliser dans le reste de ton application.

Code du userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
 
Public Result As String
 
Private Sub btnValidate_Click()
  Result = "Validate"
  Me.Hide
End Sub

La fonction qui l'appelle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function getSeek() As String
  With UserForm1
    .Show
    If .Result = "Validate" Then getSeek = .txtSeek.Value
  End With
  Unload UserForm1
End Function

Tu peux utiliser cette fonction n'importe où dans ton code (dans d'autres userforms, mais aussi dans d'autres procédures de ton application), dès que tu as besoin de récupérer la valeur sur base de ta recherche: SeekValue = getSeek(), car le code du usf2 n'est plus lié au usf1. il y a une séparation claire des responsabilités de chaque userform (Le USF2 a la responsabilité de te permettre de chercher ta donnée par saisie intuitive et le premier peut utiliser la valeur du second sur simple appel d'une fonction dont la responsabilité est de restituer cette valeur) et les deux ne sont en fait pas liés. De plus, en ne liant pas les usf1 au usf2, tu capitalises sur le code de USF2.

[bougalix]

Bonsoir,
je suis très honoré cher Pierre de ta citation et merci pour ta réponse.
En effet alimenter une variable publique est une piste que j'avais envisagée. Mais je dois dire que l'appel par une Function est encore une des finesses dont tu as le secret et grâce auxquelles tu nous as éclairé à d'innombrables reprises sur ce merveilleux site.
ça me donne même une autre idée: passer comme argument de ta fonction getSeek le nom du USF appelant . ===> Function getSeek(USFSource)
Ce qui me permettrait de l'utiliser dans le code de l'usf pour y déclencher des traitements au moyen de sub toutes logées dans un module indépendant.
Gain en maintenance et en lisibilité du code.

Merci encore, d'autres idées me viennent...

Bonne soirée

[Pierre Fauconnier]

[...]
Merci encore, d'autres idées me viennent...

Bonne soirée

Super. Content que ces idées d'architecture te permettent d'avancer dans ton projet.

Enjoy