Discussion :

[Boukleudor]

Bonjour à tous,

Je suis débutant dans Access.
J'ai commencé à créer un petit programme pour gérer le prêt de matériel dans la structure où je travaille. Après plusieurs recherches je reste bloqué sur un point..
J'aimerai que le bouton s'affiche lorsque dans la zone de texte il est affiché "Disponible" sinon s'il est affiché "Prêté(e)" je voudrais que le bouton se désactive.

Alors mon début de code est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private Sub txtStock_BeforeUpdate(Cancel As Integer)
If (Me.txtStock) Then
    Me.btnEnregistrerPret.Enabled = True
    Cancel = False
Else
    Me.btnEnregistrerPret.Enabled = False
    Cancel = True
End If
End Sub

Je pense qu'il faudrait que je rajoute quelque chose au niveau des ???, mais je ne sais pas quoi.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub txtStock_BeforeUpdate(Cancel As Integer)
If (Me.txtStock ???) Then
    Me.btnEnregistrerPret.Enabled = True
    Cancel = False
Else
    Me.btnEnregistrerPret.Enabled = False
    Cancel = True
End If
End Sub

Si vous pouviez m'éclairer je serai ravi, car je tourne en rond et ce coup si je n'arrive pas à trouver de solution..
Merci d'avance, bonne soirée à vous

[tee_grandbois]

bonsoir,
attention, à l'instruction Cancel = True car elle empêche de sortir du champ tant qu'il ne correspond pas à la valeur correcte (c'est à dire Me.txtStock ="Disponible") je pense plutôt qu'il faut le faire après mise à jour:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub txtStock_AfterUpdate()
If Me.txtStock ="Disponible" Then
    Me.btnEnregistrerPret.Enabled = True  
Else
    Me.btnEnregistrerPret.Enabled = False
End If
End Sub

et sur l'évènement "Sur activation" du formulaire pour remettre la valeur par défaut:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Form_Current()
Me.btnEnregistrerPret.Enabled = False
End Sub

[Boukleudor]

Bonjour, merci beaucoup de votre réponse.
C'est vrai que c'est plus pertinent du faire comme vous me conseillez.

Je viens d'essayer mais le bouton reste désactivé que ce soit indiqué "Prêté(e)" ou "Disponible".


Alors voilà je vais essayer de mieux exposer mon problème.

J'ai une liste si rien n'est sélectionné j'aimerai bien que mon bouton soit désactivé.


Ensuite lorsque je sélectionne un fauteuil roulant qui est déjà prêté, je voudrais que le bouton reste désactivé.


Et pour finir lorsque le fauteuil sélectionné est disponible, je voudrais que le bouton soit actif.


Si besoin voici mon code entier :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
'-----------------------------------------------------------------------------------------------------------------------------
'------------------------------------------------Partie pour l'Aide Technique-------------------------------------------------
'-----------------------------------------------------------------------------------------------------------------------------
 
Private Sub txtCritereAT_AfterUpdate()
Dim req As String
req = "SELECT  Aides_Techniques.idAideTechnique, '[' & [RefAideTechnique] & ']' & ' ' & [Designation] & ' (' & [LibTaille] & ')' AS [AT], * FROM Stock INNER JOIN (Taille INNER JOIN Aides_Techniques ON Taille.Taille = Aides_Techniques.Taille) ON Stock.idStock = Aides_Techniques.idStock WHERE [RefAideTechnique] & ' ' & [Designation] & ' ' & [LibTaille] like '*" & Me.txtCritereAT & "*'"
    Me.txtListeAT.RowSource = req
    Me.txtListeAT.Requery
End Sub
 
Private Sub btnChercherAT_Click()
txtCritereAT_AfterUpdate
End Sub
 
Private Sub txtListeAT_AfterUpdate()
Dim db As Database
Dim rs As Recordset
Set db = CurrentDb
 
Set rs = db.OpenRecordset("SELECT Aides_Techniques.idAideTechnique, [LibCategorie] & ' ' & [Designation] & ' ' & [LibTaille] & ' ' & [LibEtat] & ' ' & [LibStock] AS [AT2], * FROM Etat INNER JOIN (Categories INNER JOIN (Taille INNER JOIN (Stock INNER JOIN Aides_Techniques ON Stock.idStock = Aides_Techniques.idStock) ON Taille.Taille = Aides_Techniques.Taille) ON Categories.idCategorie = Aides_Techniques.idCategorie) ON Etat.idEtat = Aides_Techniques.idEtat WHERE idAideTechnique = " & Me.txtListeAT.Value, dbOpenDynaset)
If Not rs.EOF Then rs.MoveFirst
    Me.txtCategorie = rs("LibCategorie")
    Me.txtDesignation = rs("Designation")
    Me.txtTaille = rs("LibTaille")
    Me.txtEtat = rs("LibEtat")
    Me.txtStock = rs("LibStock")
rs.Close
Set rs = Nothing
db.Close
Set db = Nothing
End Sub
 
Private Sub btnEnregistrerPret_Click()
Me.txtListeATDemandesPret.AddItem Me.txtListeAT.Value & ";" & _
Me.txtDesignation & ";" & _
Me.txtTaille
End Sub
 
Private Sub Form_Current()
Me.btnEnregistrerPret.Enabled = False
End Sub
 
Private Sub txtStock_AfterUpdate()
If (Me.txtStock = "Disponible") Then
    Me.btnEnregistrerPret.Enabled = True
Else
    Me.btnEnregistrerPret.Enabled = False
End If
End Sub

Voilà une explication un peu plus claire.

[nico84]

Bonjour,

Avec un évènement update, l'état du bouton ne change que si le texte est changé. Il faut donc aussi modifier l'état chaque fois qu'on change de ligne, donc par exemple dans form_current

[tee_grandbois]

bonjour,
je comprend mieux: les zones de texte situées à droite sont des contrôles indépendants et c'est à partir de la zone de liste qu'elles sont chargées.
Dans ce cas, il faut faire le test après mise à jour de la zone de liste:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub txtListeAT_AfterUpdate()
Dim db As Database
Dim rs As Recordset
Set db = CurrentDb
 
Set rs = db.OpenRecordset("SELECT Aides_Techniques.idAideTechnique, [LibCategorie] & ' ' & [Designation] & ' ' & [LibTaille] & ' ' & [LibEtat] & ' ' & [LibStock] AS [AT2], * FROM Etat INNER JOIN (Categories INNER JOIN (Taille INNER JOIN (Stock INNER JOIN Aides_Techniques ON Stock.idStock = Aides_Techniques.idStock) ON Taille.Taille = Aides_Techniques.Taille) ON Categories.idCategorie = Aides_Techniques.idCategorie) ON Etat.idEtat = Aides_Techniques.idEtat WHERE idAideTechnique = " & Me.txtListeAT.Value, dbOpenDynaset)
If Not rs.EOF Then rs.MoveFirst
    Me.txtCategorie = rs("LibCategorie")
    Me.txtDesignation = rs("Designation")
    Me.txtTaille = rs("LibTaille")
    Me.txtEtat = rs("LibEtat")
    Me.txtStock = rs("LibStock")
 
If (Me.txtStock = "Disponible") Then
    Me.btnEnregistrerPret.Enabled = True
Else
    Me.btnEnregistrerPret.Enabled = False
End If
 
	rs.Close
Set rs = Nothing
db.Close
Set db = Nothing
End Sub

PS: l'option dbOpenDynaset est réservée pour les requêtes de mise à jour, ici dbOpenSnapshot suffit car le Recordset est une requête de sélection: = " & Me.txtListeAT.Value, dbOpenSnapshot)

[Boukleudor]

Super, merci beaucoup.

J'ai apporté vos corrections et ça fonctionne encore merci !