Discussion :

[irimi54]

Bonjour,

Dans ACCESS je dispose d'une table dont je veux exporter les données dans un classeur EXCEL comprenant une feuille "Données" et une feuille "Graphique". Mais il faudrait que le transfert des données n'efface pas la feuille "Graphique" à chaque fois que je mets à jour la feuille données par un transfert depuis ACCESS

Merci

[tee_grandbois]

bonjour,
et quel est le code utilisé pour faire cela ? sachant que le paramètre Range de la commande Docmd.TransferSpreadSheet permet de spécifier le nom de la feuille ou la plage de cellules à alimenter

[irimi54]

à partir d'un formulaire j'ai crée un bouton avec sur l'evenement "sur_click"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Simulation_Excel_Click()
 
DoCmd.OutputTo acOutputQuery, "R_Simulation", "Excel97-Excel2003Workbook(*.xls)", "Simulations.xls", True, "", 0
 
End Sub

je transfert les données de la requete "R_simulation" dans un classeur excel "Simulation.xls. Mais lors du prochain "click" cela va effacer la feuille "graphique" de mon classeur

[irimi54]

J'ai modiifé le code avec la commande proposée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.TransferSpreadsheet acExport, 9, "R_Simulation", "Simulation.xls", True, "Data"

Cela fonctionne mais la feuille "Data" vient s'ajouter aux feuilles existantes et est nommée "Data1" et non pas remplacer la feuille existante.

[tee_grandbois]

en effet, dans ce cas, il faudrait plutôt utiliser CopyfromRecordset dans une procédure VBA qui permet de préciser la feuille de destination mais cela implique de coder quelques dizaines de lignes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Sub ExportVersXls()
' pour éviter les problèmes de référence, en utilise le Late Binding (liaison tardive en français):
Dim oApp As Object
Dim oWbk As Object
Dim oWSht As Object
 
Dim oRst As Recordset
Dim Qdf As DAO.QueryDef
Dim oDb As Database
Dim i As Long
 
'Définition des applications excel et access
    Set oDb = CurrentDb()
    Set oApp = CreateObject("excel.application")
 
    oApp.Visible = True  ' pour contrôler le bon fonctionnement, on rend visible l'instance Excel,
                         ' l'instruction peut être enlevée après la phase de tests
    Set oWbk = oApp.Workbooks.Open("C:\Simulations.xls")   ' modifier le chemin du fichier si besoin
    Set oWSht = oWbk.Worksheets("Data") 
 
' définition du jeu de données avec une requête enregistrée
    Set Qdf = oDb.QueryDefs("R_Simulation")
    Set oRst = Qdf.OpenRecordset
 
' suppression des anciennes données de la feuille
    oWSht.Activate
    oWSht.Cells.select
    oApp.Selection.Delete
 
' entête de colonnes sur la 1ère ligne 
    For i = 0 To oRst.Fields.Count - 1
        oWSht.Range("A1").Offset(0, i) = oRst(i).Name
    Next i
' copie des données à partir de la 2ème ligne
    oWSht.Range("A2").CopyFromRecordset oRst
 
' fermeture des instances ouvertes
oRst.Close
oWbk.Close True    ' sauvegarde du classeur
Set oRst = Nothing
Set oDb = Nothing
Set oWSht = Nothing
Set oWbk = Nothing
Set oApp = Nothing
 
End Sub

[irimi54]

OK j'essaie cela

[irimi54]

Cela fonctionne .

Merci beaucoup