Discussion :

[Westone Thunder IIA]

Bonjour,

Débutant sur LibreOffice Calc, je sollicite votre aide car je souhaite élaborer un tableau statistique à partir d'un fichier que j'alimente quotidiennement (ONGLET : "LISTE DES COMMUNES 2020").

Pour faire simple, c'est un tableau de suivi des autorisations d'urbanisme (déclaration préalable "DP", permis de construire "PC", de démolir "PD", d'aménager "PA") délivrées par commune. J'ai besoin de connaitre le nombre d'autorisations délivrées par commune, par trimestre et par type d'autorisation.

J'ai bien réussi à faire un SOMMEPROD qui me donne en global (voir formules en colonnes W et X dans l'onglet "STATISTIQUES GLOBALES") pour chaque commune le nombre d'autorisations délivrées par type mais dès que je veux ajouter des conditions supplémentaires, ça ne fonctionne plus (voir formules en colonne W dans l'onglet "STATS 1ER TRIM 2020").

Je souhaitais obtenir en plus un comptage par trimestre et que la formule sélectionne uniquement les lignes ou il est inscrit le chiffre "0" en case AE (libellé : Contrôle).

Voici le tableau en pièce jointe et voici ma ligne de code :

=SOMMEPROD(('LISTE DES COMMUNES 2020'.$B$2:$B$10000=B3)*(('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PC")+('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PD"))*(($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000>"01/01/20"));(($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000<"31/03/20"))*('LISTE DES COMMUNES 2020'.$AG$2:$AG$10000="0"))

je n'ai vraisemblablement pas encore compris la logique de programmation de CALC (Le BASIC de mon vieil ORIC ATMOS du "siècle dernier" me semblait beaucoup plus limpide !!!).

Par avance, merci pour votre aide.
Bien cordialement.

[TpF45]

Bjour,

- des parenthèses en trop
- un "*" à la place du ";"
- DATE(2020;1;1) à la place de "01/01/20" pour comparer du numérique et non du texte
- DATE(2020;3;31) à la place de "31/03/20" pour comparer du numérique et non du texte
- 0 à la place de "0" pour comparer du numérique et non du texte

=SOMMEPROD(('LISTE DES COMMUNES 2020'.$B$2:$B$10000=B3)*(('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PC")+('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PD"))*($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000>DATE(2020;1;1))*($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000<DATE(2020;3;31))*('LISTE DES COMMUNES 2020'.$AG$2:$AG$10000=0)))

A tester et nous faire un retour

[Westone Thunder IIA]

Bonjour,

un grand merci, ça marche divinement bien !!!

j'aurais une question subsidiaire : dans la dernière partie de ma formule, je demande de comptabiliser les lignes ou apparait le chiffre 0 en colonne AE, je souhaiterais qu'il intègre également dans le comptage quand le mot "OUI" apparait dans cette même colonne.

('LISTE DES COMMUNES 2020'.$AG$2:$AG$10000=0)

Existe-il une formulation commune pour rechercher les 2 variables en même temps ou doit-on les traiter une par une comme 2 conditions distinctes ?

[TpF45]

Oui, c'est une condition à ajouter dans la longue liste

=SOMMEPROD(('LISTE DES COMMUNES 2020'.$B$2:$B$10000=B3)*(('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PC")+('LISTE DES COMMUNES 2020'.$Y$2:$Y$10000="PD"))*($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000>DATE(2020;1;1))*($'LISTE DES COMMUNES 2020'.$AE$2:$AE$10000<DATE(2020;3;31))*(('LISTE DES COMMUNES 2020'.$AG$2:$AG$10000=0)+('LISTE DES COMMUNES 2020'.$AG$2:$AG$10000="OUI")))

avec un "+" qui se traduit par "ou"
ou avec un "*" qui se traduit par "et"
et en veillant aux parenthèses qui comme en arithmétique sont importantes dans l'ordre de traitement

2*(3+4)=14 ne donne pas le même résultat que (2*3)+4=10

de même
condition1 et ( condition2 ou condition3) ne donne pas la même sélection que (condition1 et condition2) ou condition3

[Westone Thunder IIA]

clair et précis.

Merci encore.
Bien cordialement.