Discussion :

[re]

Bonjour,
Je dois faire une grosse erreur de débutant, pouvez-vous m'aider svp
Ca ouvre bien la boite de dialogue et le fichier puis erreur...
Précision c'est une ouverture d'un fichier CSV

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
   Application.Dialogs(xlDialogOpen).Show , _
   Origin:=65001, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
   xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=True, _
   Comma:=False, Space:=False, Other:=True, OtherChar:=";", FieldInfo:= _
   Array(Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array(5, 1), Array(6, 1), Array(7 _
   , 1), Array(8, 1), Array(9, 1), Array(10, 1), Array(11, 1)), TrailingMinusNumbers:= _
       True
End Sub

Merci

[EricDgn]

Bonjour,

Il me semble que vous avez coupé un morceau entre la première et la deuxième ligne. Un début de solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub testCsv()
   With Application.FileDialog(msoFileDialogFilePicker)
        .Title = "S"
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "Fichiers texte", "*.txt; *.csv"
        .InitialView = msoFileDialogViewProperties
        If .Show Then
            MsgBox .SelectedItems(1)
            ChargerCsv .SelectedItems(1)
        End If
   End With
End Sub
 
Sub ChargerCsv(sFichierTxt As String)
    Workbooks.OpenText Filename:=sFichierTxt, _
        Origin:=xlWindows, StartRow:=1, DataType:=xlDelimited, _
        TextQualifier:=xlTextQualifierNone, ConsecutiveDelimiter:=False, _
        Tab:=False, Semicolon:=True, Comma:=False, Space:=False, _
        Other:=False, DecimalSeparator:=",", TrailingMinusNumbers:=True, _
        Local:=True
End Sub

Cordialement.

[re]

Bonjour,
Merci ça fonctionne mieux :-)
Bonne journée