Discussion :

[Yakov TOPRAK]

Bonjour,

Je souhaite utiliser l'instruction Retrun dans mon code mais une erreur systématique s'affiche.
Celle-ci est :

Erreur de compilation:
Attendu : fin d'instruction

Le code est pourtant des plus simple, le voici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Function AgePhrase(ByVal age As Integer) As String
    If age > 60 Then Return "Senior"
    If age > 40 Then Return "Middle-aged"
    If age > 20 Then Return "Adult"
    If age > 12 Then Return "Teen-aged"
    If age > 4 Then Return "School-aged"
    If age > 1 Then Return "Toddler"
    Return "Infant"
End Function

C'est un exemple tiré de l'aide Microsoft, donc il est bon.
Je ne comprends pas pourquoi cette erreur.
Quelqu'un aurait-il une idée ?
Bien à vous

[Philippe Tulliez]

Bonjour,
Où avez-vous trouvé cet exemple car pour moi si ma mémoire ne me fait pas défaut l'instruction Return, n'a pas d'argument. De plus, GoSub et l’instruction Return correspondante doivent se trouver dans la même procédure donc celle que vous publiez est incomplète.

[Thumb down]

bonjour,
ton exemple fait référence à VB.net pas VBA!
https://docs.microsoft.com/fr-fr/dotnet/visual-basi

[Patrice740]

Bonjour,

L'instruction Return n'est destinée à être utilisée dans une fonction VBA.
Pour coder la valeur à retourner dans une fonction VBA, c'est à la fonction qu'il faut affecter la valeur !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Function AgePhrase(ByVal age As Integer) As String
    If age > 60 Then AgePhrase = "Senior"
    If age > 40 Then AgePhrase = "Middle-aged"
    If age > 20 Then AgePhrase = "Adult"
    If age > 12 Then AgePhrase = "Teen-aged"
    If age > 4 Then AgePhrase = "School-aged"
    If age > 1 Then AgePhrase = "Toddler"
    AgePhrase = "Infant"
End Function

[joe.levrai]

Bonjour,

un bon vieux Select Case peut faire l'affaire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Function AgePhrase(ByVal age As Integer) As String
    Select Case age
        Case Is > 60
            AgePhrase = "Senior"
        Case Is > 40
            AgePhrase = "Middle-aged"
        Case Is > 20
            AgePhrase = "Adult"
        Case Is > 12
            AgePhrase = "Teen-aged"
        Case Is > 4
            AgePhrase = "School-aged"
        Case Is > 1
            AgePhrase = "Toddler"
        Case Else
            AgePhrase = "Infant"
    End Select
End Function

[anasecu]

Bonjour,

Je souhaite utiliser l'instruction Retrun dans mon code

Pourquoi un "Retrun" alors qu'avec une formule tu as le résultat ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=CHOISIR(EQUIV(A1;{0;1;4;12;20;40;60};1);"Infant";"Toddler";"School-aged";"Teen-aged";"Adult";"Middle-aged";"Senior")

[Philippe Tulliez]

Bonjour,
Personnellement pour ce genre de problème, j'utilise RECHERCHEV avec valeur proche.

Comment remplacer des SI imbriqués par la fonction RECHERCHEV

[Yakov TOPRAK]

Merci à tous.
Je comprends pourquoi cela ne fonctionne pas alors, car l'instruction n'est pas valide pour ce que je veux faire.
Bonne journée

[Pierre Fauconnier]

Salut.

Excel 365 => RECHERCHEX, histoire de ne pas réinventer la roue en VBA et d'éviter le hard-coding... Comme le signale Philippe, pour les autres versions, on peut utiliser RECHERCHEV ou INDEX-EQUIV en s'appuyant sur un tableau structuré, histoire d'éviter aussi le hard-coding dans la formule . En VBA, on préférera le Select Case au IF lorsque les conditions portent sur la même valeur. Tnat qu'à faire, autant exploiter correctement ce qui a été créé (voir mon billet à ce sujet)

Si vraiment besoin du VBA pour inclure la réponse dans un traitement VBA, j'utiliserais quand même RECHERCHEX sur un tableau structuré, au sein d'une fonction utilisant Evaluate:


On pourrait aussi utiliser directement RECHERCHEX dans la fonction:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Function AgePhrase(Age As Integer) As String
  AgePhrase = Application.XLookup(Age, Range("t_Ages[Age]"), Range("t_Ages[Phrase]"), , -1)
End Function

Attention que telles que tu as écrit tes conditions, elles excluent les valeurs bornes (> au lieu de >=), d'où les bornes de mon tableau structuré qui ont été majorées de 1. A toi de voir si 60 doit renvoyer Middled-Aged ou Senior

[...]

Ta fonction va toujours renvoyer "infant"... et si tu supprimes la dernière ligne de ta fonction, elle renverra "Toddler" dès que l'âge passé sera supérieur à 1 puisque le dernier If "emportera la mise"... Quelle misère


(Hors sujet) Il faut noter au passage qu'en VB.NET, Return fait sortir de la fonction à la manière d'un Exit Function, donc perso, je ne trouve pas chouette d'avoir plusieurs Return dans la même fonction. Par contre, on peut comme en VBA affecter la valeur de retour à la fonction.

[Thumb down]

Bonjour Pierre,

(Hors sujet) Il faut noter au passage qu'en VB.NET, Return fait sortir de la fonction à la manière d'un Exit Function, donc perso, je ne trouve pas chouette d'avoir plusieurs Return dans la même fonction. Par contre, on peut comme en VBA affecter la valeur de retour à la fonction.

Contrairement au VBA en VB.net c'est monaie courante !

Deplus affecter la valeur à la fonction c'est du VBA ça n'existe pas en VB.net c'est le return valeur qui le fait !

Microsoft entretient la confusion en activant par défaut la librairie visual Basic!

[Pierre Fauconnier]

Bonjour Pierre,

Contrairement au VBA en VB.net c'est monaie courante !

Dans le cas d'une fonction telle que présentée, ça ne pose pas de problème, même si je trouve plus lisible d'utiliser Select Case (c'est peut-être ma déformation VBA). Mais d'une façon générale, je ne trouve pas clair qu'il y ait plusieurs sorties de fonction, mais je t'avoue que je ne suis pas un fan de vb.net, préférant C# (qui permet les mêmes choses, ceci dit), et j'aime toujours mieux retrouver l'intention du programmeur dans ce qu'il écrit.

Je trouve que ce n'est pas clair pour vb.net d'avoir permis le Return et l'affectation à la fonction (comme en VBA) qui, elle, imposera le If Else IF ou le Select Case... Mais je suppose que ce sont des habitudes de langage et n'étant pas un spécialiste du vb.net, je n'irai pas plus loin dans le débat

[Pierre Fauconnier]

[...]
Deplus affecter la valeur à la fonction c'est du VBA ça n'existe pas en VB.net c'est le return valeur qui le fait ![...]

Ben si, ça existe, justement. Tu peux faire l'un ou l'autre, et c'est là que je pense qu'il y problème. Les deux syntaxes suivantes sont valides en VB.NET

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
    Function AgePhrase(ByVal age As Integer) As String
        If age > 60 Then Return "Senior"
        If age > 40 Then Return "Middle-aged"
        If age > 20 Then Return "Adult"
        If age > 12 Then Return "Teen-aged"
        If age > 4 Then Return "School-aged"
        If age > 1 Then Return "Toddler"
        Return "Infant"
    End Function
 
    Function AgePhrase1(ByVal age As Integer) As String
        Select Case age
            Case > 60
                AgePhrase1 = "Senior"
            Case > 40
                AgePhrase1 = "Middle-Aged"
            Case Else
                AgePhrase1 = "Infant"
        End Select
    End Function

La fonction présentée dans le message initial s'écrirait ainsi en VBA, et perso, je n'aime pas du tout, mais vraiment pas du tout

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Function AgePhrase(Age As Integer) As String
  If Age > 60 Then AgePhrase = "Senior": Exit Function
  If Age > 40 Then AgePhrase = "Middle-Aged": Exit Function
  If Age > 20 Then AgePhrase = "Adult": Exit Function
  If Age > 12 Then AgePhrase = "Teen-Aged": Exit Function
  If Age > 4 Then AgePhrase = "School-Aged": Exit Function
  AgePhrase = "Infant"
End Function

[Thumb down]

je confirme ça fonctionne! j'ai toujours utiliser Return!

notes que je ne suis pas un autodidacte j'ai tous appris dans le cadre de la formation continue!