Discussion :

[kensy]

Bonjour à tous,

J'utilise Access, pour le suivi d'opérations de transfert.

Je souhaite réaliser un export Excel, au format CSV, qui va me permettre de générer des écritures comptables (débit/crédit).

Je vais en suite injecter ce fichier dans une autre application.

Le fichier doit cependant respecter un formatage, et un séquencement bien précis pour les deux écritures.

Par exemple, les lignes doivent commencer à la ligne 4, car les précédentes contiennent des codes, nécessaires dans l'autre application.

Je mets le débit en ligne 4, puis le crédit en ligne 5.

Sur Access, j'obtiens les éléments nécessaires à l'aide d'une requête, sur une seule ligne :



Savez-vous qu'elle méthode je peux utiliser, pour générer mes deux lignes, au bon endroit ? avec les séquencement (éléments) nécessaire pour chacune d'entre elle ?



Cordialement,

Kensy

[EricDgn]

Bonjour,

De ce que j'ai compris, je commencerais par faire 2 requêtes, l'une listant les débits, l'autre listant les crédits, les deux ayant le même nom (AS ...), ensuite je ferais une requête UNION sur ces 2 listes (avec le tri qui convient).

Cordialement.

[kensy]

Bonjour EricDgn,

C'est une bonne idée.

J'ai l'impression cependant qu'il faudra de toute façon passer pas du code VBA Excel.

Car Access, ne permet pas de coller les données dans une cellule, ou une plage prédéfini.

Il exporte les informations sur une nouvelle feuille.

Je pense que je vais passer par une Macro sur Excel, qui va mettre en forme le fichier d'extraction Access.

Cordialement,

Kensy

[EricDgn]

Mais vous pourriez aussi créer dans Access une table qui contient 3 enregistrements qui correspondent à ce qui doit se trouver en tête du csv exporté et dont les champs sont identiques à ceux qui sont dans la requête UNION déjà mentionnée.

Cordialement.

[hyperion13]

Salut
Il est possible de piloter Excel depuis Access pour désigner un classeur et/ou une feuille spécifique pour "copier" des données à partir d'une cellule précise.

[kensy]

Salut hyperion13,

Tu as un exemple s'il te plait ?

Cordialement,

Kensy

[tee_grandbois]

bonsoir,
pour trouver des exemples, tape copyfromrecordset dans le lien "Recherche dans ce forum" en haut gauche du forum (ou du sous-forum):

[EricDgn]

Bonsoir,

La question est effectivement assez fréquemment posée. Un exemple de solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Option Explicit
 
'--- https://www.developpez.net/forums/d1726143/logiciels/microsoft-office/access/vba-access/optimisation-temps-traitement/
 
'--- demande référence Microsoft Excel x.xx Object Library
 
Sub Export_Xls(sRecordsource As String, sFullFileName As String)    '--- Export via Excel en .xlsx ou .csv ou .txt 
    Dim oXls As Excel.Application
    Dim oWb As Excel.Workbook
    Dim oWsh As Excel.Worksheet
    Dim rs As Recordset
    Dim sFormat As String
    Set oXls = CreateObject("Excel.Application")
    oXls.Visible = True
    Set oWb = oXls.Workbooks.Add
    Set oWsh = oWb.Worksheets(1)                   '--- première feuille
    Set rs = CurrentDb.QueryDefs(sRecordsource).OpenRecordset
    oWsh.Range("A3").CopyFromRecordset rs
    'oWsh.Range("A1") = "Ligne 1"                   '--- à adapter 
    sFormat = Mid(sFullFileName, InStrRev(sFullFileName, "."))
    Select Case sFormat
        Case ".xlsx"
            oWb.SaveAs sFullFileName
        Case ".csv"
            '--- ne conserve pas les lignes vides !
            '--- délimiteur=; --- dates FR
            'oWb.SaveAs FileName:=sFullFileName, FileFormat:=xlCSV, CreateBackup:=False
            '--- délimiteur=, --- dates US
            'oWb.SaveAs FileName:=sFullFileName, FileFormat:=xlCSVMSDOS, CreateBackup:=False
            oWb.SaveAs FileName:=sFullFileName, FileFormat:=xlCSVUTF8, CreateBackup:=False
        Case ".txt"
            '--- ne conserve pas les lignes vides !
            '--- délimiteur=tabulation --- dates US
            'oWb.SaveAs FileName:=sFullFileName, FileFormat:=xlTextWindows, CreateBackup:=False
            oWb.SaveAs FileName:=sFullFileName, FileFormat:=xlUnicodeText, CreateBackup:=False
        Case Else
            MsgBox "Extension non reconnue!", , "Annulé"
    End Select
    'oXls.Quit
    rs.Close
    Set rs = Nothing
    Set oWsh = Nothing
    Set oWb = Nothing
    Set oXls = Nothing
End Sub

A noter que les exports en .csv ou .txt ne reprend pas les lignes vides qui se trouvent au dessus des premières lignes non vides de la feuille Excel exportée. Il faut donc compléter au moins la ligne 1 pour que les lignes vides suivantes soient enregistrées (avec autant de champs laissés vides qu'il y en a dans les données normales).

Cordialement.

[kensy]

Bonjour EricDgn,

J'ai essayé la base que tu m'as envoyé,

Ça me donne ce message d'erreur :



Cordialement,

Kensy

[EricDgn]

Bonjour,

Cela dépend peut-être de la version d'Excel car cela fonctionne sur mon pc (Excel 365).

Mettre cette ligne en remarque (ajouter un ' en début de ligne, qui du coup est affichée en vert) et remettre en fonction la ligne précédente (enlever le ' qui se trouve en début de ligne, qui du coup est affichée en noir).

Énumération XlFileFormat

Cordialement.

[kensy]

EricDgn,

Merci, ça fonctionne.

Cordialement,

Kensy

[kensy]

EricDgn,

J'ai créé une requête union comme tu me l'avais conseillé.

Cependant, je n'arrive pas à la copier à la place de "sRecordsource".

Comment faire?

Ma requête se nome "R_Export_Union".

Cordialement,

Kensy

[EricDgn]

Bonjour,

Je ne vois pas vraiment où se trouve le problème. Normalement il suffit de mentionner le nom de la requête dans l'appel de la routine, par exemple quelque chose du genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Export_Xls "R_Export_Union", CurrentProject.Path & "\R_Export_Union.csv"

Il faut évidemment que la requête union elle-même fonctionne correctement pour que l'export puisse ensuite fonctionner.

Un petit exemple en attaché avec une requête union nommée NomPr_PrNom.

Cordialement.

[kensy]

Bonjour EricDgn,

J'ai trouvé d'où vient le problème.

j'ai mis un critère dynamique dans la requête, afin de la filtrer sur un enregistrement précis.



la requête union fonctionne bien, j'obtiens les lignes désirées, grâce au critère renvoyé par mon formulaire.

Cependant le code non fonctionne plus.

Cordialement,

Kensy

[tee_grandbois]

bonjour,
les requêtes contenant des paramètres sont un peu complexes à utiliser dans les recordset de VBA.
Voici ce que tu peux faire :
-déplace le paramètre formulaire (TR_Code) dans la requête UNION
- rajoute le code ci-dessous avant l'instruction CopyFromRecordset:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
' déclaration querydef (définition de requête)
Dim oQdf as QueryDef
 
Set oQdf = CurrentDb.QueryDefs("sRecordsource")
' affectation du paramètre
oQdf.Parameters("Tr_Code") = Forms![NomDuFormulaire].[NomduControle]
 
' affectation du Recordset
Set rs = oQdf.OpenRecordset

la dernière instruction remplace l'ancienne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set rs = CurrentDb.Querydefs(sRecordsource)

[EricDgn]

Bonjour,

Merci à tee_grandbois pour sa solution, qui fonctionne après avoir nommé le paramètre, par exemple en LeCode


et adapté son code en fonction du nom donné au paramètre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
' déclaration querydef (définition de requête)
Dim oQdf as QueryDef
 
Set oQdf = CurrentDb.QueryDefs("sRecordsource")
' affectation du paramètre
oQdf.Parameters("LeCode") = Forms![NomDuFormulaire].[NomduControle]
 
' affectation du Recordset
Set rs = oQdf.OpenRecordset

Cordialement.

[kensy]

Bonjour à tous,

Merci pour votre aide.

J'ai utilisé une requête action, afin de copier coller le résultat de la requête union dans une table temporaire.

J'ai en suite remplacé par le nom de cette table.

ça fonctionne.

Cordialement,

Kensy