Discussion :

[morobaboumar]

Bonsoir membres du forum,
La zone de texte moteur de recherche se limite à 5 lettres et n'accepte pas l'espacement(la touche espace) entre les mots.

Je souhaiterais y entrer au moins deux mots pour la recherche.
Qu'est ce qui me coince ?




Code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub MoteurRechercheParent_Change()
MoteurRechercheParentAlphaNumerique
End Sub
 
Sub MoteurRechercheParentAlphaNumerique()
Dim strFilter As String
On Error GoTo ErrHandler
If Me.MoteurRechercheParent.Text <> "" Then
    strFilter = "NOM_PRENOMS_RECHERCHE Like '*" & Me.MoteurRechercheParent.Text & "*'"
    Me.Filter = strFilter
    Me.FilterOn = True
Else
    Me.Filter = ""
    Me.FilterOn = False
End If
With Me.MoteurRechercheParent
    .SetFocus
    .SelStart = Len(Me.MoteurRechercheParent.Text)
End With
Exit Sub
ErrHandler:
    MsgBox Err.Description, vbExclamation
End Sub

Remarque: les commandes de mise en forme et pièce jointe de mon tableau de bord sont invisibles.
Veuillez les rétablir. Merci.

Cordialement.

[EricDgn]

Bonjour,

La limite des 5 caractères ne vient pas de MoteurRechercheParent_Change() mais d'un autre événement lié à ce champ MoteurRechercheParent.
Il reste cependant possible d'utiliser le joker * dans ce champ. Exemples:
ou*go ... devrait sortir Amara (Oumar) Sanogo
go*ou ... ne devrait rien donner.

Cordialement.

[morobaboumar]

Bonsoir EricDgn,
Très heureux de vous retrouver.
J'ai testé votre proposition néammoins je souhaite encore mieux.

Je vous envoie une pièce jointe de mon application
afin si possible y a t il autre code qui pourrait qui pourrait permettre
la méthode de recherche que je souhaite.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub MoteurRechercheNomExtraireAlphaNumerique()
Dim strFilter As String
On Error GoTo ErrHandler
If Me.MoteurRechercheNomAExtraire.Text <> "" Then
    strFilter = "NOM_PRENOMS_RECHERCHE_ContrSoldee Like '*" & _
    Me.MoteurRechercheNomAExtraire.Text & "*'and ID_ContribProgram = " & _
    Me.ID_ContribProgram & "and ID_du_Contribuant = " & _
    Me.Id_du_Contribuant & ""
Me.Filter = strFilter
    Me.FilterOn = True
Else
    Me.Filter = ""
    Me.FilterOn = False
End If
With Me.MoteurRechercheNomAExtraire
    .SetFocus
    .SelStart = Len(Me.MoteurRechercheNomAExtraire.Text)
End With
Exit Sub
ErrHandler:
    MsgBox Err.Description, vbExclamation
End Sub

Cordialement.

[EricDgn]

Bonjour,

Access supprime d'office les espaces en fin de texte quand on entre dans un champ texte. Une solution est donc de remplacer les espaces par des + (plutôt que de taper sur la touche espace, on tape sur la touche +), et ensuite pour le filtrage (dans le code) ces + sont remplacés par des espaces. Cela donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Sub MoteurRechercheParentAlphaNumerique()
    Dim strFilter As String
    '--- pour le filtre, remplace les + par des espaces
    strFilter = Replace(Me.MoteurRechercheParent.Text, "+", " ") 
    strFilter = Replace(strFilter, "'", "' & chr(39) & '")  '--- gère l'apostrophe
   If strFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Me.Filter = "NOM_PRENOMS_RECHERCHE Like '*" & strFilter & "*'"
        Me.FilterOn = True
        With Me.MoteurRechercheParent
            .SetFocus
            .SelStart = Len(strFilter)
        End With
    End If
End Sub
 
Sub MoteurRechercheNomExtraireAlphaNumerique()
    Dim strFilter As String
    '--- pour le filtre, remplace les + par des espaces
    strFilter = Replace(Me.MoteurRechercheNomAExtraire.Text, "+", " ")
    strFilter = Replace(strFilter, "'", "' & chr(39) & '")  '--- gère l'apostrophe
    If strFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Me.Filter = "NOM_PRENOMS_RECHERCHE_ContrSoldee Like '*" & strFilter & "*'"
        '--- pas de filtrage sur ID_ContribProgram
        '--- pas de filtrage sur ID_du_Contribuant
        '--- pour cela il faudrait d'autres champs indiquant les ID à extraire
      Me.FilterOn = True
        With Me.MoteurRechercheNomAExtraire
            .SetFocus
            .SelStart = Len(strFilter)
        End With
    End If
End Sub

A noter que j'évite d'utiliser les On Error Goto car cela empêche de voir sur quelle ligne l'erreur se produit, ce qui rend le débogage inutilement compliqué.

A noter qu'il y a dans l'exemple donné "AERO Akaffou" et "AERO Akaffou" ainsi que "Monsieur Soumahoro Sekou" et "Monsieur Soumahoro Sekou" (tantôt avec 1 espace, tantôt avec 2 espaces).

Enfin, si la recherche ne s'occupe pas des majuscules et minuscules (A=a), elle fait la distinction entre lettre accentuées et lettres non accentuées (e <> é <> è).

Cordialement.

[morobaboumar]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub MoteurRechercheNomExtraireAlphaNumerique()
    Dim strFilter As String
    '--- pour le filtre, remplace les + par des espaces
    strFilter = Replace(Me.MoteurRechercheNomAExtraire.Text, "+", " ")
    strFilter = Replace(strFilter, "'", "' & chr(39) & '")  '--- gère l'apostrophe
    If strFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Me.Filter = "NOM_PRENOMS_RECHERCHE_ContrSoldee Like '*" & strFilter & "*'"
        '--- pas de filtrage sur ID_ContribProgram
        '--- pas de filtrage sur ID_du_Contribuant
        '--- pour cela il faudrait d'autres champs indiquant les ID à extraire
      Me.FilterOn = True
        With Me.MoteurRechercheNomAExtraire
            .SetFocus
            .SelStart = Len(strFilter)
        End With
    End If
End Sub

A noter que j'évite d'utiliser les On Error Goto car cela empêche de voir sur quelle ligne l'erreur se produit, ce qui rend le débogage inutilement compliqué.

A noter qu'il y a dans l'exemple donné "AERO Akaffou" et "AERO Akaffou" ainsi que "Monsieur Soumahoro Sekou" et "Monsieur Soumahoro Sekou" (tantôt avec 1 espace, tantôt avec 2 espaces).

Enfin, si la recherche ne s'occupe pas des majuscules et minuscules (A=a), elle fait la distinction entre lettre accentuées et lettres non accentuées (e <> é <> è).

Bonsoir ericDgn,
J'ai bien saisi vos explications limpides.
Voici la structure de la table




Je souhaite filtrer la procédure ci dessus à partir de 3champs:
- ONGAdheree
- ID_ContribProgram
- ID_du_Contribuant

au moment de la recherche dans la zone zone de texte moteur de recherche,
en tenant compte de le suggestion que vous avez faite:

Enfin, si la recherche ne s'occupe pas des majuscules et minuscules (A=a), elle fait la distinction entre lettre accentuées et lettres non accentuées (e <> é <> è).

.

Pièce jointe

Cordialement.

[morobaboumar]

Bonjour EricDgn,
Je viens d'opérer des modification dans mon application afin qu'on puisse mettre le filtre
dans le code de la procédure du post#5.
Cordialement.

[EricDgn]

Bonsoir,

Un début de solution, supposant qu'il y a aussi les champs [ONG_Selectionnee] et [tXT_ID_contributionProgrammee] dans le formulaire CONTRIBUTION_SOLDEE_TirageDeReçuVersement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub MoteurRechercheNomExtraireAlphaNumerique()
    Dim sFilter As String
    sFilter = ""
    If Nz(Me.MoteurRechercheNomAExtraire, "") <> "" Then
        '--- pour le filtre, remplace les + par des espaces
        sFilter = Replace(Me.MoteurRechercheNomAExtraire.Text, "+", " ")
        sFilter = Replace(sFilter, "'", "' & Chr(39) & '")                            '--- gère l'apostrophe
        sFilter = " AND [NOM_PRENOMS_RECHERCHE_ContrSoldee] Like '*" & sFilter & "*'"
    End If
    If Nz(Me.ONG_Selectionnee, "") <> "" Then
        sFilter = sFilter & " AND [ONGAdheree]=" & Me.ONG_Selectionnee
    End If
    If Nz(Me.tXT_ID_contributionProgrammee, "") <> "" Then
        sFilter = sFilter & " AND [ID_ContribProgram] = " & Me.tXT_ID_contributionProgrammee
    End If
 
    If sFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Debug.Print "Filtre: "; sFilter
        Me.Filter = Mid(sFilter, 6)         '--- pour retirer le 1er " AND "
        Me.FilterOn = True
        With Me.MoteurRechercheNomAExtraire
            .SetFocus
            .SelStart = Len(sFilter)
        End With
    End If
End Sub

Cordialement.

[morobaboumar]

Bonsoir ÉricDgn,
Désolé pour le retard.
Votre code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MoteurRechercheNomExtraireAlphaNumerique()

marche bien.
Merci infiniment.
Cordialement.

[morobaboumar]

Bonjour EricDgn,
J'ai essayé d'adapter le code à une autre zone de moteur MoteurRechercheParent de recherche.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
 
Sub MoteurRechercheParentAlphaNumerique()
    Dim sFilter As String
    sFilter = ""
    If Nz(Me.MoteurRechercheParent, "") <> "" Then
        '--- pour le filtre, remplace les + par des espaces
        sFilter = Replace(Me.MoteurRechercheParent.Text, "+", " ")
        sFilter = Replace(sFilter, "'", "' & Chr(39) & '")                            '--- gère l'apostrophe
        sFilter = " AND [NomPrenomsParent] Like '*" & sFilter & "*'"
    End If
    If Nz(Me.ID_ETABL_ParResp, "") <> "" Then
        sFilter = sFilter & " AND [ID_ETABL_ParResp]=" & Me.ID_ETABL_ParResp
    End If
    'If Nz(Me.mlepa_Enreg_ParResp, "") <> "" Then
        'sFilter = sFilter & " AND [mlepa_Enreg_ParResp]=" & Me.mlepa_Enreg_ParResp
    'End If
 
    If sFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Debug.Print "Filtre: "; sFilter
        Me.Filter = Mid(sFilter, 6)         '--- pour retirer le 1er " AND "
        Me.FilterOn = True
        With Me.MoteurRechercheParent
            .SetFocus
            .SelStart = Len(sFilter)
        End With
    End If
End Sub

Voici le message d'erreur affiché:



Cordialement.

[EricDgn]

Bonjour,

Je ne rencontre pas cette erreur en testant votre fichier ZONE MOTEUR RECHERCHE 3.accdb.

Par ailleurs si vous supprimiez ces On Error Goto ... vous pourriez voir sur quelle ligne exactement les erreurs se produisent.

Cordialement.

[morobaboumar]

Bonsoir EricDgn,
Message compris.
J'ai une nouvelle préoccupation se trouvant dans le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
 
Sub MoteurRechercheArticleAlphaNumerique()
    Dim sFilter As String
    sFilter = ""
    If Nz(Me.MoteurRechercheArticle, "") <> "" Then
        '--- pour le filtre, remplace les + par des espaces
        sFilter = Replace(Me.MoteurRechercheArticle.Text, "+", " ")
        sFilter = Replace(sFilter, "'", "' & Chr(39) & '")                            '--- gère l'apostrophe
        sFilter = " AND [Nom_CompletArticleScolaire] Like '*" & sFilter & "*'"
    End If
    If Nz(Me.Txt_ID_Etablissement, "") <> "" Then
        sFilter = sFilter & " AND [IdentifEtablissement]=" & Me.Txt_ID_Etablissement
    End If
    If Nz(Me.TXT_AnneeSCOLAIRE, "") <> "" Then
        sFilter = sFilter & " AND [ANNEE_SCOL]=" & Me.TXT_AnneeSCOLAIRE
    End If
 
    If sFilter = "" Then
        Me.Filter = ""
        Me.FilterOn = False
    Else
        Debug.Print "Filtre: "; sFilter
        Me.Filter = Mid(sFilter, 6)         '--- pour retirer le 1er " AND "
        Me.FilterOn = True
        With Me.MoteurRechercheArticle
            .SetFocus
            .SelStart = Len(sFilter)
        End With
    End If
End Sub

le champ "ANNEE_SCOL" est de type Texte
le champ "IdentifEtablissement" est de type Numérique

l'erreur constatée est le fait que rien ne s'affiche lors de la recherche dans le moteur de recherche MoteurRechercheArticle.





Cordialement.

[hyperion13]

Salut
Un rappel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
- " & numerik & "
- ' " & string & " '
- # & date & #

.

[morobaboumar]

Salut
Un rappel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
- " & numerik & "
- ' " & string & " '
- # & date & #

.

Bonjour hyperion13,
Très heureux de vous retrouver !
Pourriez vous me donner un plus d'explications ?
Cordialement.

[hyperion13]

... Pourriez vous me donner un plus d'explications ?

Post#11 analysez bien la L16 et faites une corrélation avec l'une des 2 remarques juste après votre code.
De plus, cette notion vous la maitrisez. Selon que la variable est numérique, alphanumérique ou date, la variable est encadrée différemment.

[morobaboumar]

Bonsoir hyperion13,
J'ai bien compris votre message et corrigé mon erreur.
Il fallait que je fasse ceci à cette ligne du code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
If Nz(Me.TXT_AnneeSCOLAIRE, "'") <> "'" Then
        sFilter = sFilter & " AND [ANNEE_SCOL]='" & Me.TXT_AnneeSCOLAIRE & "'"
    End If

Merci infiniment à vous tous.
Cordialement.

[EricDgn]

Vous y êtes presque!
Si les champs Txt_ID_Etablissement et TXT_AnneeSCOLAIRE sont tous les deux des champs de type texte, c'est ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
    If Nz(Me.Txt_ID_Etablissement, "") <> "" Then
        sFilter = sFilter & " AND [IdentifEtablissement]='" & Me.Txt_ID_Etablissement & "'"
    End If
    If Nz(Me.TXT_AnneeSCOLAIRE, "") <> "" Then
        sFilter = sFilter & " AND [ANNEE_SCOL]='" & Me.TXT_AnneeSCOLAIRE & "'"
    End If

Et s'il y avait dans votre formulaire un champ nommé LaDate du type date, il faudrait écrire ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    If Nz(Me.LaDate, 0) <> 0 Then
        sFilter = sFilter & " AND [LaDate]=#" & Format(Me.LaDate, "yyyy-mm-dd") & "#"
    End If

C'est ce que vous résumait hyperion13 au sujet des conventions de délimitation des valeurs selon qu'elles sont de type numérique, texte (string) ou date.

Cordialement.

[morobaboumar]

Bonsoir ÉricDgn,
Bonsoir hyperion13,
Message compris.
Je vous remercie infiniment.
Cordialement.