Discussion :

[Fanolito]

Bonjour,

J'utilise LibreOffice 7.1.6.2 sous Windows 10 Pro 21H1.

Dans une feuille de calcul, je dispose d'une plage de cellules allant de A1 à A24.
Chaque cellule contient soit une chaine de caractère vide, soit l'adresse d'une plage de cellules comme par exemple $E$201:$J$248.
Je souhaiterais parcourir la plage A1:A24 de façon à récupérer chacune des adresses.
Si la cellule est vide, on passe à la cellule suivante sans rien faire.
Dans le cas contraire, on récupère le contenu de la cellule et on l'ajoute au contenu de la cellule précédente séparé par un point virgule.
Au final, je récupère une zone comme par exemple $E$201:$J$248;$E$250:$J$299;$E$500:$J$549 que je souhaite définir comme étant ma nouvelle zone d'impression.

J'ai écrit ce bout de code mais ça ne me donne pas résultat attendu !
La macro plante sur la ligne : For Each item In ThisComponent.Sheets.GetByName("Feuille1").GetCellRangeByName("$A$1:$A$24")

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Sub definitionZoneImpression
	Dim item As Object
        ziEncours = ""
        ziTotal = ""
	For Each item In ThisComponent.Sheets.GetByName("Feuille1").GetCellRangeByName("$A$1:$A$24")
		If item <> "" Then
                   ziEncours = item
                   ziTotal = ziTotal + ";" + item
		End If
	Next item 
End Sub

Si quelqu'un peut me mettre sur la voie.
Je l'en remercie d'avance.

Fanolito

[Mobydick_62]

Bonjour,

Le document que tu as joint ne contient pas ta macro.
J'en ai donc écrit une autre d'une manière différente.
On récupère correctement dans la variable ziTotal la liste complète des cellules non vides séparées par un point-virgule.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 Sub definitionZoneImpression()
  Dim oFeuille As Object, oCell As Object 
  Dim oZone As Object, oListeCell As Object, oSelectionCell As Object
  Dim oEnumCellules As Object
  Dim ziEncours As String, ziTotal As String 
 
  oFeuille = ThisComponent.Sheets.GetByName("Feuille1")
  oZone = oFeuille.getCellRangeByName("A1:A24")
  oSelectionCell = oZone.queryContentCells(com.sun.star.sheet.CellFlags.STRING)
  oEnumCellules = oSelectionCell.Cells
  oListeCell = oEnumCellules.createEnumeration
  Do While oListeCell.hasMoreElements
   oCell = oListeCell.nextElement
   ziEncours = oCell.String 
   If ziTotal = "" Then 'Pour éviter d'avoir un point virgule en début de variable
    ziTotal = ziEncours
   Else  
    ziTotal = ziTotal & ";" + ziEncours
   End If 
  Loop
   Print ziTotal
 End Sub

Cordialement

[Fanolito]

Bonjour Mobydick_62,

Merci pour ce retour plus que rapide.
J'ai testé ton code, ça fonctionne parfaitement.

As-tu une idée pour faire en sorte que le résultat de ziTotal soit défini en tant que zone d'impression ?

Bien sincèrement.
Fanolito

[Mobydick_62]

Re,

Oui mais là, le code est différent. On ne peut pas d'un coup envoyer la variable ziTotal même séparée par des virgules. Il faut définir les zones d'impression une a une. Donc il faut passer par un tableau de zone et boucler dessus.
Ci dessous le nouveau code.

Cordialement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 Sub definitionZoneImpression()
  Dim oFeuille As Object, oCell As Object 
  Dim oZone As Object, oListeCell As Object, oSelectionCell As Object
  Dim oEnumCellules As Object, oZoneImp As Object 
  Dim ziEncours As String
  Dim nbreZone As Integer 
 
  Dim f As Integer, x As Integer 
  Dim tabZone() As String
 
  oFeuille = ThisComponent.Sheets.GetByName("Feuille1")
  oZone = oFeuille.getCellRangeByName("A1:A24")
  oSelectionCell = oZone.queryContentCells(com.sun.star.sheet.CellFlags.STRING)
  oEnumCellules = oSelectionCell.Cells
  oListeCell = oEnumCellules.createEnumeration
  Do While oListeCell.hasMoreElements
   oCell = oListeCell.nextElement
   ziEncours = oCell.String 
   'Création d'un tableau contenant toutes les zones
   Redim preserve tabZone(f)
    tabZone(f) = ziEncours
    f=f+1
  Loop
  'Je définie la taille du tableau d'impression (f-1 car on commence par le chiffre 0)
  nbreZone = f-1
 
  Dim Props() As New com.sun.star.beans.PropertyValue
  Dim adrZones(nbreZone) As New com.sun.star.table.CellRangeAddress 
 
  'Je parcours le tableau des zones et définie les zones d'impression une a une 
  For x = LBound(tabZone()) to Ubound(tabZone())
   oZoneImp = oFeuille.getCellRangeByName(tabZone(x))
   adrZones(x) = oZoneImp.RangeAddress
  Next x
  'Définition de toutes les zones dans Calc
  oFeuille.PrintAreas = adrZones()
 End Sub

[Fanolito]

Merci beaucoup Mobydick_62, ça fonctionne super bien.
Je vais étudier ton code pour en comprendre toutes les subtilités.

Bien sincèrement,
Fanolito.