Discussion :

[DrProcyon]

Bonsoir !

Je suis très très rouillé en VBA et j'aurais besoin de votre aide pour faciliter l'exploitation de données. J'ai un fichier excel avec des réponses à un questionnaire qui demande 4 mots clefs parmi 45 thématiques choisies aléatoirement.

J'ai donc un tableau avec comme en tête de colonnes. (exemple de la feuille "initiale" de mon xlsx d'exemple)

1. ID du répondant
2. Theme 1 - Mot clef 1
3. Theme 1 - Mot clef 2
4. Theme 1 - Mot clef 3
5. Theme 1 - Mot clef 4
6. Theme 2 - Mot clef 1
7. Theme 2 - Mot clef 2
8. Theme 2 - Mot clef 3
9. Theme 2 - Mot clef 4
10. ....
11. Theme 45 - Mot clef 4

J'aimerais pouvoir faire un tableau avec (exemple de la feuille "finale" de mon xlsx d'exemple)

• Colonne 1 : ID du répondant
• Colonne 2 : Thème du mot clef
• Colonne 3 : numérotation de 1 à 4 selon la position dans le thème
• Colonne 4 : mot clé

Je me disais qu'une solution était de créer dans mon tableau initial 3 colonnes avant chaque colonne "Theme # - Mot clef #" (exemple de la feuille "intermédiaire" de mon xlsx d'exemple)

• La première colonne contenant l'ID
• La 2e contenant le nom du thème
• La 3e colonne contenant le numéro de 1 à 4

Et ensuite de faire "à la main" les 45 copiés collés un brin fastidieux mais faisables
Auriez-vous une idée de quel code je peux utiliser pour faire ça ? (Si vous avez des idées plus pertinentes je suis preneur aussi)

Merci d'avance pour votre aide.

et bonne année au passage !

[EricDgn]

Bonjour,

Une façon de faire utilisant des tableaux (array).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
Option Base 1
 
Sub ConversionTableau()
    Dim DataA() As Variant, DataB() As Variant, kR As Long, kC As Long, k As Long
    DataA = Worksheets("Initial").UsedRange.Value   '--- suppose qu'il n'y a pas de données en dehors du tableau
    kR = UBound(DataA, 1)           '--- nb de lignes
    kC = UBound(DataA, 2)           '--- nb de colonnes
    k = (kR - 1) * (kC - 1) + 1     '--- nb de données (mots)
    ReDim DataB(k, 4)
    DataB(1, 1) = "Id"
    DataB(1, 2) = "Thème"
    DataB(1, 3) = "Rang"
    DataB(1, 4) = "Mot"
    k = 1
    For kR = 2 To UBound(DataA, 1)                '--- les lignes
        For kC = 2 To UBound(DataA, 2)            '--- les colonnes
            k = k + 1
            DataB(k, 1) = DataA(kR, 1)
            DataB(k, 2) = Left(DataA(1, kC), Len(DataA(1, kC)) - 4)
            DataB(k, 3) = 1 + (kC + 2) Mod 4
            DataB(k, 4) = DataA(kR, kC)
        Next kC
    Next kR
    Worksheets("Final").Select
    Worksheets("Final").Cells.ClearContents
    Worksheets("Final").Range("A1:D" & k) = DataB
End Sub

Cordialement.