Discussion :

[Invité]

bonjour,

je viens de parcourir beaucoup de forum et j'ai trouvé énormément de post, en revanche personne ne souhaite faire du diag par du ping.

je m'explique :

je souhaiterais pinger 8 adresses et avoir le résultat dans le terminal et non dans un fichier texte.

exemple :

ping 1 => 192.168.1.1 = résultat1
.....
ping 8 => 192.168.1.274 = résultat8

Resultat1 est joinable
...
résultat8 est injoignable

Merci de votre aide

je suis sur Windows 7 je ne sais pas si c'est important à préciser

[ericlm128]

Un truc comme cela si j'ai bien compris

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
@echo off
cls
 
call :f_ping www.voila.fr
call :f_ping www.voilaaa.fr
call :f_ping 192.168.1.1
call :f_ping 192.168.1.254
call :f_ping 192.168.1.274
 
 
echo.
echo fin
pause>nul
exit
 
:f_ping
ping %~1 -n 1 |find "TTL=" 1>nul 2>nul&&echo %~1 est joinable||echo %~1 est injoignable
goto :eof

[Invité]

c'est excatement ca !!

Merci beaucoup

[hackoofr]

Posté ici en reddit : Script that pings and displays the status of multiple network devices.
Vous pouvez aussi faire les deux càd afficher sur la console et sauvegarder aussi les résultats en fichier texte.
Si vous voulez ajouter de la couleur comme bonus aussi

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 @echo off
 Title Scan Network and Multi Ping With Colors
 REM ----------------------------------------------
 REM You can change this variable LastByte to yours
 Set LastByte=20
 REM ----------------------------------------------
 set "LogFile=%~dp0PingResults.txt"
 If exist "%LogFile%" Del "%LogFile%"
 SetLocal EnableDelayedExpansion
 @for /f "tokens=2 delims=:" %%a in ('ipconfig ^| find /I "Ipv4"') do (
     Set "LocalIP=%%a"
     Set "LocalIP=!LocalIP:~1!"
 )
 If not defined LocalIP (
 echo(
 Call :PsColor "Your Local IP address is Empty, So Please Check your Network" RED \n
     Timeout /T 10 /NoBreak>nul & Exit
 )
 echo( & Call :PsColor "Your Local IP Address : !LocalIP!" Yellow \n
 echo Your Local IP Address : !LocalIP!>"%LogFile%"
 @for /f "tokens=1,2,3,4 delims=." %%a in ('echo !LocalIP!') do (
     Set "A=%%a" & Set "B=%%b" & Set "C=%%c" & Set "D=%%d"
 )
 @for /L %%i in (1,1,%LastByte%) do (
         Ping -n 1 !A!.!B!.!C!.%%i |find "TTL=">nul) && (
         set "msg=!A!.!B!.!C!.%%i Ping SUCCESS" && Call :PSColor "!msg!" Green \n
         echo !msg!>>"%LogFile%"
      ) || ( 
         set "msg=!A!.!B!.!C!.%%i Ping FAILURE" && Call :PSColor "!msg!" Red \n
         echo !msg!>>"%LogFile%"
     )
 )
 EndLocal
 Start "Log" /MAX "%LogFile%" & Exit /B
 ::---------------------------------------------------------------
  :PSColor <String> <Color> <NewLine>
  If /I [%3] EQU [\n] (
      Powershell Write-Host "`0%~1" -ForegroundColor %2
  ) Else (
      Powershell Write-Host "`0%~1" -ForegroundColor %2 -NoNewLine
  )
  Exit /B
  ::--------------------------------------------------------------