Trier un tableau qui a des filtres

**mijean94** · 28/08/2022, 03h30

Bonjour à tous,

J’ai un tableau avec des colonnes utilisées de A à V .

Dans toutes les colonnes j’ai des filtres sur la ligne 2.

Mon tableau est aujourd’hui renseigné jusqu’à la ligne 800, mais ça va continuer.

Ce que j’aimerai faire :

Un trie sur trois critères avec mes données ont des têtes (la ligne 2)

Les critères sont les colonnes G, H et F

Ca je sais faire en manuel, mais pas en VBA, car je n’arrive pas à définir les lignes à prendre en comptes pour le tri, puisqu’elle change en fonction des filtres utilisées dans les autres colonnes.

voici le code fait en automatique pour une configuration de filtre, mais la première ligne et dernière change si le tri est différent ou même les lignes ne ce suivent pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Clas_N_P_NU()
'
 
    Rows("2:1399").Select
    ActiveWorkbook.Worksheets("Gestion des données ").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Gestion des données ").Sort.SortFields.Add _
        Key:=Range("G3:G1399"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    ActiveWorkbook.Worksheets("Gestion des données ").Sort.SortFields.Add _
        Key:=Range("H3:H1399"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    ActiveWorkbook.Worksheets("Gestion des données ").Sort.SortFields.Add _
        Key:=Range("F3:F1399"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("Gestion des données ").Sort
        .SetRange Range("A587:W1399")
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
 
    Range("B588").Select
 
End Sub

Merci pour votre aide.

Cordialement

**Philippe Tulliez** · 28/08/2022, 07h44

Bonjour,
Je n'ai jamais dû utiliser en VBA le tri de colonnes filtrées mais d'après moi, la seule chose à indiquer c'est le numéro des colonnes à trier ou la plage des colonnes.

[EDIT]
Je confirme.
Je viens d'utiliser ma procédure générique de tri sur une table (ListObject) filtrée et cela fonctionne parfaitement, les lignes filtrées sont bien triées dans l'ordre souhaité et pas les autres.

**hyperion13** · 28/08/2022, 09h23

Bonjour
Si vous voulez ~~filtrer~~ trier une plage dynamique, une méthode parmi tant d'autres

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Option Explicit
Sub Trier3Colonnes()
Dim xlWbk As Workbook
Dim xlWsh As Worksheet
Dim rngSort As Range
Dim iRows As Long, iCols As Long
 
Set xlWbk = ThisWorkbook
Set xlWsh = xlWbk.Worksheets("Gestion des données") ' Attention il y a un espace avant le dernier guillemet dans votre syntaxe !!!
 
iRows = xlWsh.Range("A2").CurrentRegion.Rows.Count ' nombre de lignes
iCols = xlWsh.Range("A2").CurrentRegion.Columns.Count ' nombre de colonnes
 
Set rngSort = xlWsh.Range(xlWsh.Cells(2, 1), xlWsh.Cells(iRows, iCols)) ' range plage dynamique
 
Application.ScreenUpdating = False
 
With xlWsh.Sort
     .SortFields.Clear
     .SortFields.Add Key:=xlWsh.Range("G2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     .SortFields.Add Key:=xlWsh.Range("H2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     .SortFields.Add Key:=xlWsh.Range("F2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     .SetRange rngSort
     .Header = xlYes
     .MatchCase = False
     .Orientation = xlTopToBottom
     .SortMethod = xlPinYin ' ne sert à rien sauf si caractères chinois dans le tableau
     .Apply
End With
 
End Sub

**mijean94** · 28/08/2022, 14h20

Bonjour #hyperion13, à tous,

Un grand merci à #hyperion13, ça fonctionne nickel. Merci aussi à Philippe

Je vais essayé de l'adapter à d'autres types de trie, par exemple lorsqu'on lance la macro on a le choix des trois colonnes à filtrer.
Un imputbox je pense et 3 choix possibles, après validation du choix le filtrage sera réalisé.

Si je n'y arrive pas je reviendrais vers vous.
j'ai un décalage horaire de -6 h, donc mes réponses est questions sont décalées par rapport à la France.

Cordialement

**hyperion13** · 28/08/2022, 15h13

re,
Et pour compéter si jamais vous travaillez avec un tableau structuré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
Sub Trier3Colonnes1()
Dim xlWbk As Workbook
Dim xlWsh As Worksheet
Dim lstObj As ListObject
 
Set xlWbk = ThisWorkbook
Set xlWsh = xlWbk.Worksheets("Gestion des données")
Set lstObj = Range("Tableau1").ListObject ' vérifier nom effectif du tableau strcuturé
 
Application.ScreenUpdating = False
 
With lstObj.Sort
     .SortFields.Clear
     .SortFields.Add Key:=lstObj.ListColumns(7).Range, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal ' colonne G
     .SortFields.Add Key:=lstObj.ListColumns(8).Range, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal ' colonne H
     .SortFields.Add Key:=lstObj.ListColumns(6).Range, SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal ' colonne F
     .Header = xlYes
     .MatchCase = False
     .Orientation = xlTopToBottom
     .Apply
End With
 
End Sub

**mijean94** · 28/08/2022, 16h06

Bonjour #hyperion13, à tous,

j'ai ajouté en début de votre macro,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Dim choix_tri, A, B, C As String
 
debut:
 
MsgBox "Voici les choix de tri possible : " & Chr(13) & Chr(10) & Chr(13) & Chr(10) & _
"1 - tri sur NOM (G), Prénom (H) et Numéro de clim (F)" & Chr(13) & Chr(10) & _
"2 - tri sur N° série clims (R et S) et N° clims (F)" & Chr(13) & Chr(10) & _
"3 - tri sur N° OP (D) nom (G) et Prénom (H)"
 
choix_tri = InputBox("Entrer votre choix 1, 2 ou 3 :", " Définition du tri choisi")
 
If choix_tri = 1 Then A = "G2": B = "H2": C = "F2": GoTo suite
If choix_tri = 2 Then A = "R2": B = "S2": C = "F2": GoTo suite
If choix_tri = 3 Then A = "D2": B = "G2": C = "H2": GoTo suite
 
MsgBox "Votre choix n'est pas conforme aux possibilités": GoTo debut
 
suite:

et modifier les lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
'.SortFields.Add Key:=xlWsh.Range("G2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     '.SortFields.Add Key:=xlWsh.Range("H2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     '.SortFields.Add Key:=xlWsh.Range("F2"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
 
     .SortFields.Add Key:=xlWsh.Range(A), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     .SortFields.Add Key:=xlWsh.Range(B), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
     .SortFields.Add Key:=xlWsh.Range(C), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal

mais ça ne fonctionne pas,

RECTIF, ça fonctionne, je lancé une mauvaise macro. ce n'est peut-être pas très bien au niveau programmation mais ça fonctionne.

merci de l'aide.

Cordialement