Discussion :

[jpg75014]

Bonjour,

Je voudrais pouvoir trouver le texte PCE ou BT ou KG dans une cellule.

J'utilise la fonction CHERCHE :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

=CHERCHE("PCE";A1)

mais en existe-t-il une autre qui permet plus d'arguments (si possible sans passer par une macro).

Merci beaucoup pour votre aide.

JPG

[Invité]

Peut-être avec une condition :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

SIERREUR(RECHERCHE("PCE";A:A);RECHERCHE("BT";A:A))

[Raccourcix]

Bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=OU(ESTNUM(CHERCHE({"PCE";"BT";"KG"};A1)))

renverra VRAI s'il trouve un des trois termes PCE, BT ou KG dans la cellule et FAUX si aucun n'est présent

Stéphane

[jpg75014]

Merci pour cette réponse, c'est possible d'obtenir la position de PCE ou BT ou KG ?

[Raccourcix]

Oui, bien sûr

par exemple avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=JOINDRE.TEXTE(CAR(10);;{"PCE";"BT";"KG"}&": "&SIERREUR(CHERCHE({"PCE";"BT";"KG"};A1);"NA"))

le JOINDRE.TEXTE(CAR(10) permet d'aller à la ligne
le SIERREUR permet d'afficher NA si le texte n'est pas trouvé



Stéphane

[Raccourcix]

Un autre exemple pour identifier la première des trois chaines dans le texte et sa position
l'usage de LET permet d'éviter l'usage à trois reprises de la même fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=LET(
liste;{"PCE";"BT";"KG"};
position;CHERCHE(liste;A1);
SIERREUR(INDEX(liste&": "&position;EQUIV(MIN(SIERREUR(position;""));position));"Aucun"))

ou avec RECHERCHEX pour éviter le SIERREUR(INDEX...;EQUIV...) et une définition de la liste des textes cherchés

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=LET(
liste;{"PCE";"BT";"KG"};
position;CHERCHE(liste;A1);
RECHERCHEX(MIN(SIERREUR(position;""));position;liste&": "&position;"Aucun"))

Stéphane