Discussion :

[scoobydoos]

Bonjour,
Est-il possible de faire une RechercheX avec plusieurs conditions ?
Si oui, avez-vous des exemples ?

Je voudrais faire une recherche d'une référence et d'une marque.

Merci par avance
@+

[Raccourcix]

Bonjour

avec l'argument 4 de RECHERCHEX vous pouvez empiler les fonctions.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

RECHERCHEX(mavaleur;liste_référence;liste_référence_renvoyée;RECHERCHEX(mavaleur;liste_marque;liste_marque_renvoyée))

Stéphane

[Raccourcix]

Je viens d'avoir une mise à jour d'Excel avec les nouvelles fonctions TEXTE.AVANT, TEXTE.APRES... et les fonctions pour gérer les matrices EXCLURE, ETENDRE, DANSCOLS, DANSLIGNES...

on peut donc utiliser ASSEMB.V pour coller deux plages l'une sous l'autre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@Recherche];ASSEMB.V(Marque[Marque];Référence[Référence]);ASSEMB.V(Marque[Valeur];Référence[Valeur]))

Vraiment très pratique

Stéphane

[Pierre Dumas]

Bonsoir

Sinon, si je ne dis pas de bêtises (je n'ai pas la 365 pour tester) :
RECHERCHEX(1;(Colonne1 de recherche=Valeur1 cherchée)*(Colonne2 de recherche=Valeur2 cherchée);Colonne affichée)

On utilise un * pour signifier le ET
On utilise un + pour signifier le OU

En espérant que cela aide

Bonne soirée

Pierre Dumas

[scoobydoos]

Salut,

Merci à tous. Je vais tester tout ça et je vous dis lequel fonctionne le mieux

@+

[Raccourcix]

J'avoue ne pas avoir bien compris la question
Si c'est pour rechercher un couple marque+références il est possible de concaténer les termes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
RECHERCHEX(marque_cherchee&"/"&reference_cherchee;lste_marque&"/"&liste_reference;colonne renvoyée)

Stéphane

[scoobydoos]

En fait oui c'est ça.

J'ai un tableau comprenant plein de marque avec les références associées et je veux chercher le prix mais dans différents tableaux de chaque marque.

J'ai fait un exemple si ça peut aider.

Merci par avance
@+

[scoobydoos]

Salut,

Peut-on dire dans une formule comme "RechercheX", d'aller chercher tel ou tel tableaux depuis la marque que l'on veut ?

Je m'expliques toujours pour fichier :
J'ai 2 tableaux notés :
-TSchneider
-TLegrand

Le 3ième où je veux les prix des tableaux ci-dessous suivant les marques et réf.

J'ai fait ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@Marque]&[@Réf];"T"&[@Marque]&[Marque]&"T"&[@Marque]&[Réf];"T"&[@Marque]&[Prix];"non")

En fait, je voudrais qu'automatiquement, il aille chercher les tableaux correspondant.

Si je fait ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="T"&[@Marque]

Cela me sort bien le nom du tableau.

Merci par avance
@+

[Philippe Tulliez]

Bonjour,
La fonction INDIRECT est une solution mais il est important de savoir que son usage peut être chronophage car c'est une fonction volatile

Dans l'illustration ci-dessous, nous avons

• trois tables nommées de gauche à droite t_Legrand, t_Schneider et t_Mapping.
• la cellule B2 contenant la référence à chercher dans l'une des tables (en bleu) et ce en fonction du premier caractère de cette valeur
• la cellule C2 qui contient la formule de recherche ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX(B2;INDIRECT(RECHERCHEX(GAUCHE(B2;1);t_Maping[Prefix];t_Maping[LookupTable]));INDIRECT(RECHERCHEX(GAUCHE(B2;1);t_Maping[Prefix];t_Maping[TableReturn])))

[Raccourcix]

Le 3ième où je veux les prix des tableaux ci-dessous suivant les marques et réf.

J'ai fait ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@Marque]&[@Réf];"T"&[@Marque]&[Marque]&"T"&[@Marque]&[Réf];"T"&[@Marque]&[Prix];"non")

En fait, je voudrais qu'automatiquement, il aille chercher les tableaux correspondant.

Bonjour

Essayez

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@Réf];INDIRECT("T"&[@Marque]&"[Réf]");INDIRECT("T"&[@Marque]&"[Prix]");"non")

Stéphane

[scoobydoos]

Bonjour

Essayez

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEX([@Réf];INDIRECT("T"&[@Marque]&"[Réf]");INDIRECT("T"&[@Marque]&"[Prix]");"non")

Stéphane

Bonjour,

Merci.
Pourquoi [Réf] et [Prix] sont entre guillemets ?

Sinon, cela ne fonctionne pas, cela me renvoi "non".

Merci par avance
@+

[scoobydoos]

Si excusez-moi, cela fonctionne, j'avais oublié d'enlever la Marque dans le critère de recherche.

Merci par avance
@+

[WF14HR]

Salut,

Clair et efficace

Merci à tou.te.s

@+