Discussion :

[phal2ip]

Bonjour à tous
cela fait maintenant une semaine que je me triture les méninges à essayer de déconcaténer une liste qui peut-être courte ou longue voir très longue.
La liste est tjs formé de la même façon (NOM Prénom - Numéro à 7chiffres suivi d'une lettre; et ainsi de suite).
Je souhaiterais récupérer uniquement les 7 chiffres et la lettre qui suit pour copie dans la case de la ligne suivante.
En fait je n'arrive pas à récupérer ces données, je m'y prends peut-être mal mais comme la longueur des NOM Prénom est différente à chaque fois....
Je souhaiterais chercher le - puis décaler d'une case vers la droite et récupérer les 8 caractères suivants.
Mon souci est que je n'arrive pas à faire la recherche de ce - puisqu'il fait partie de la case et que ce n'est pas le seul...
Une fois les premiers caractères récupérés et copier dans la ligne suivante, il faut chercher le tiret suivant et ainsi de suite....
Je ne sais pas si je me suis bien fait comprendre ?
Si quelqu'un voit un bout de solution, je lui en serais très reconnaissant.
Merci

[jurassic pork]

hello,
peux tu nous montrer un exemple de ce qu'il y a en entrée? est-ce du genre TAIRIEUR Alain - 1234567 G ? . Il me semble que les expressions régulières pourraient être une solution pour ton problème.
[EDIT] deedolith a répondu presqu'en même temps que moi et te montre alors comment faire.
Ami calmant, J.P

[deedolith]

Salut,

Rechercher le tiret est une fausse bonne idée, pour la simple raison qu'il existe des noms ou prénoms composés qui comportent un tiret.
Une solution plus fiable est de passer par les expressions régulières.
Par exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Public Function ExtractRegexValues(ByVal Pattern As String, ByVal Target As String) As Collection
    Dim Results As Collection
    Set Results = New Collection
 
    Dim Rx As VBScript_RegExp_55.RegExp
    Set Rx = CreateObject("VBScript.RegExp")
    Rx.Pattern = Pattern
    Rx.Global = True
    Rx.MultiLine = True
 
    Dim Matchs As VBScript_RegExp_55.MatchCollection
    Set Matchs = Rx.Execute(Target)
 
    Dim Match As VBScript_RegExp_55.Match
    For Each Match In Matchs
        Results.Add Match.Value
    Next
    Set ExtractRegexValues = Results
End Function
 
Public Sub test()
    Const data As String = "Luc Mont-Motma - 1234567" & vbCrLf & "Lea - Mal a droite - 4598761"
    Dim Results As Collection
    Set Results = ExtractRegexValues("\d{7}", data)
 
    Dim Item As Variant
    For Each Item In Results
        Debug.Print Item
    Next
End Sub

[78chris]

Bonjour

Probablement faisable aussi par PowerQuery intégré à Excel

[phal2ip]

Ouh laaa
vous allez très vite pour moi...
C'est quoi les expressions régulières déjà??
Deedolith dans ton exemple ce qui est en rouge ça représente quoi??
Voici un petit exemple de ce que je souhaiterais à la sortie. Ligne 1 la liste complète et dessous la récupération demandée...
Possible???

Exemple VBA.xlsx

[Raccourcix]

Bonjour

Avec les dernières fonctions d'Excel 365

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=TRANSPOSE(TEXTE.APRES(FRACTIONNER.TEXTE(A1;";");"- ";;;1))

FRACTIONNER.TEXTE pour couper le texte sur les ;
TEXTE.APRES( ...."- "... -1) pour extraire ce qu'il y a après le dernier tiret
TRANSPOSE pour mettre le résultat en colonne

Stéphane

[jurassic pork]

En reprenant le code de deedolith et en le modifiant légèrement ce qui suit devrait fonctionner avec ton classeur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Public Function ExtractRegexValues(ByVal Pattern As String, ByVal Target As String) As Collection
    Dim Results As Collection
    Set Results = New Collection
 
    Dim Rx As Object
    Set Rx = CreateObject("VBScript.RegExp")
    Rx.Pattern = Pattern
    Rx.Global = True
    Rx.MultiLine = True
 
    Dim Matchs As Object
    Set Matchs = Rx.Execute(Target)
 
    Dim Match As Object
    For Each Match In Matchs
        Results.Add Match.Value
    Next
    Set ExtractRegexValues = Results
End Function
 
Public Sub test()
    Dim Results As Collection
    Dim data As String, x As Integer
    data = ActiveSheet.Range("A1").Value
    Set Results = ExtractRegexValues("\d{7}[A-Z]", data)
    Dim Item As Variant
    x = 1
    For Each Item In Results
        Debug.Print Item
        ActiveSheet.Range("A1").Offset(x, 0).Value = Item
        x = x + 1
    Next
End Sub

[phal2ip]

Désolé Raccourcix ça ne fonctionne pas mais je viens de voir que je suis encore en Office 2016 alors que ma boite passe doucement en O365...
Peut-être que...

[phal2ip]

Merci Jurrassic Pork cela fonctionne
Je vais étudier ta méthodologie pour la comprendre mieux
Merci encore à tous pour l'aide

[deedolith]

Deedolith dans ton exemple ce qui est en rouge ça représente quoi??

Réponse méchante: Google est ton ami.
Réponse réaliste: Google est ton ami.
Quand on ne sait pas, on se renseigne.
CreateObject: https://learn.microsoft.com/fr-fr/of...bject-function.
Les expressions régulières: https://www.automateexcel.com/fr/vba...nnelles-regex/