Discussion :

[lmc71]

Bonjour le Forum
Je souhaiterais atteindre la première cellule vide dans une colonne : Exemple - A12 = 4/7/2020 - A13 = 5/7/2020 - A14 = vide
Je voudrais que le curseur se place dans la cellule A14 à l'aide d'une macro activée par un clic sur un bouton.
Dans excel j'utilise le code ci-dessous. Excite t-il un code similaire dans Libre Office.
Cordialement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 Dim DerniereCelluleRemplie
 
    DerniereCelluleRemplie = Columns("Cc:Cc").Find("*", Range("Cc1"), , , xlByRows, xlPrevious).Row
    DerniereCelluleRemplie = DerniereCelluleRemplie + 1
    Range("Cc" & DerniereCelluleRemplie).Select

[Mobydick_62]

Bonjour,

Deux exemples parmi d'autres (voir doc joint pour faire des essais)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 '___________________________________________________________________________________
 'Action bouton sur la feuille 1
 Sub CelluleVide()
  Dim oDoc As Object, oCurseur As Object, oFeuille As Object, oCell As Object 
  Dim x As Integer 
  oDoc = ThisComponent
  oFeuille = oDoc.getSheets.getByName("Feuille1")
  oCurseur = oFeuille.createCursor
  oCurseur.gotoEndOfUsedArea( False )
  x =  oCurseur.RangeAddress.EndRow+2
  oCell = oFeuille.getCellRangeByName("A" & x)
  oDoc.CurrentController.Select(oCell)
 End Sub
 
 '____________________________________________________________________________
 'Récupère cellule vide sur zone définie
 'Action bouton sur la feuille 2
 Sub RecupereCelluleVideSurZone()
  Dim oDoc As Object, oFeuille As Object, oZone As Object, oCell As Object 
  Dim zoneVide As Variant
  Dim x As Integer 
  oDoc = ThisComponent
  oFeuille = oDoc.getSheets.getByName("Feuille2")  
  oZone = oFeuille.getCellRangeByName("D2:D10")
  zoneVide = oZone.queryEmptyCells.RangeAddresses
  x = zoneVide(0).StartRow
  x = x + 1
  oCell = oFeuille.getCellRangeByName("D" & x)
  oDoc.CurrentController.Select(oCell) 
 End Sub

Cordialement

DerniereCelluleRemplie.ods

[lmc71]

Bonjour Mobydick_62
Je te remercie pour ta réponse rapide et excellente.
J' ai incorporé le deuxième code, en le modifiant pour ma feuille, à un code que j'avais enregistré. Tout fonctionne parfaitement.
Est-ce que les codes élaborés sur Libre Office peuvent fonctionner sur Open Office ?
J'aurais une question sur Open Office, est-ce que je dois ouvrir spécifiquement une discussion sur Open Office ?
Cordialement.

[Mobydick_62]

Re,

Est-ce que les codes élaborés sur Libre Office peuvent fonctionner sur Open Office ?

En règle général OUI. Mais au fur et à mesure des avancement de LibreOffice des changements notables sont à prendre en compte.
Sur le forum (lien ci-dessous), les différences sont expliquées. Néanmoins dans certains cas et en "bidouillant" un peu le code on peut faire en sorte que les deux soient compatibles.

Différences de programmation entre AOO et LibO:
https://forum.openoffice.org/fr/foru...225796#p225796

J'aurais une question sur Open Office, est-ce que je dois ouvrir spécifiquement une discussion sur Open Office ?

OUI. Une question ou un problème = nouvelle discussion. Mais dans la question bien précisé que c'est pour Open Office car cette partie du forum traite les deux.

Cordialement

[lmc71]

Re
Je te remercie pour tes explications qui consolide ma pensée. Je travaille plus sur access et Excel que sur LO et OO. Mais pour ne pas mourir idiot j'essaye les deux. Mais sur OO j'ai un problème de java. Donc je ne peux ni effectuer de macros ni utiliser la base de données.
J'ai laissé une discussion sur OO concernant ce problème, pas de réponse pour l'instant.
Je vais mettre résolu pour cette discussion.
Je te remercie encore pour tes codes.
Cordialement