Discussion :

[Lolofr]

Bonjour

Je cherche à ma rappeler du dernier enregistrement ouvert d'un formulaire avant sa fermeture.

Je souhaiterais ainsi me rappeler où j'en suis dans les données que j'ai à traiter.

Mon form frm_agence est basé sur une table tbl_agence avec comme numéroauto et clé primaire le champ ID_pro et notamment un champ appelé company

Je souhaite avoir une zone de texte qui me permette donc de savoir quel a été le dernier enregistrement affiché avant la fermeture du formulaire.

Dans ce form j'ai une zone de liste déroulante qui me permet d'accéder à n'importe quel enregistrement en fonction du champ company (nom de l'entreprise)

J'aurai besoin de votre aide svp

[Jean-Philippe André]

Bonjour,

Déjà pour le stockage de l'information, tu peux passer par une table dite de paramètres :
https://jpcheck.developpez.com/tutor...es-initiation/

Les trois événements qui pourront être utilisés pour déclencher ta mise à jour
Unload / Deactivate / Close

[Lolofr]

Bonjour,

Déjà pour le stockage de l'information, tu peux passer par une table dite de paramètres :
https://jpcheck.developpez.com/tutor...es-initiation/

Les trois événements qui pourront être utilisés pour déclencher ta mise à jour
Unload / Deactivate / Close

Merci

[Robert1957]

Bonjour Lolofr, Jean-Philippe André,

@ Jean-Philippe André, une autre façon d'aborder le sujet est d'inscrire directement dans l'objet "CurrentDB.Containers" la valeur du dernier enregistrement utilisé et ensuite à l'ouverture du formulaire se positionner sur celui-ci.
Voici un exemple:
Un module standard:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Compare Database
Option Explicit
 
Public Sub suPreviousRecord(sName As String, lLeNumero As Long)
On Error GoTo gestion_err
 
    Dim db As DAO.Database
    Dim doc As DAO.Document
    Dim prp As DAO.Property
 
    Set db = CurrentDb
 
    Set doc = db.Containers("Forms").Documents(sName)
 
    If Not IsNull(lLeNumero) Then
        doc.Properties!prpReturnToPreviousRecord = lLeNumero
    End If
 
Sortie:
On Error Resume Next
Set doc = Nothing
Set prp = Nothing
Set db = Nothing
Exit Sub
gestion_err:
    Select Case Err.Number
        Case 3270
'Création de la prop si elle n'existe pas
'Déclarée en long pour numéro auto
            Set prp = doc.CreateProperty("prpReturnToPreviousRecord", dbLong, lLeNumero) 
            doc.Properties.Append prp
            Resume Next
        Case Else
            MsgBox "Erreur inatendue :  " & Chr(13) & Err.Description & Chr(13) & "Erreur # :  " & Err.Number
            Resume Sortie
    End Select
End Sub

Et dans notre formulaire sur l'événement "Current" pour récupérer l'ID et sur l'événement "Open" pour se positionner sur le bon enregistrement:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Compare Database
Option Explicit
 
Private Sub Form_Current()
suPreviousRecord Me.Name, Me.ProdID_PK
End Sub
 
Private Sub Form_Open(Cancel As Integer)
On Error GoTo gestion_err
 
    Me.Recordset.FindFirst "ProdID_PK=" & CurrentDb.Containers("Forms").Documents(Me.Name).Properties!prpReturnToPreviousRecord
 
Sortie:
On Error Resume Next
Exit Sub
gestion_err:
    Select Case Err.Number
        Case 3270
            Resume Next
        Case Else
            MsgBox "Erreur inatendue :  " & Chr(13) & Err.Description & Chr(13) & "Erreur # :  " & Err.Number
            Resume Sortie
    End Select
End Sub

Si l'idée peut-être utile...

Bonne journée