Discussion :

[Vince143]

Bonjour, tout d'abord je vous remercie de votre aide, voici ma demande:

Dans l'ajout d'une nouvelle session, je souhaiterais l'enregistrement en BDD de chaque individu sélectionné (dans la propriété de la zone de liste id_individu, la sélection multiple est activée).

Merci

[Robert1957]

Bonjour Vince143,

Votre modèle de données n'est pas optimum. Si comme je comprend la situation il y a une formation qui peut être donnée dans une ou plusieurs sessions selon la date et l'emplacement et que chaque session (toujours selon la date et l'emplacement) peut avoir un ou plusieurs individus qui participent à cette session, il faudrait ajouter une table "Session/Individu" dans votre application. Vous auriez alors la table FORMATION idem à la votre, la table SESSION n'aurait plus de "id_individu" et une nouvelle table qui elle aurait le "id_session" et le "id_individu" en relation avec la table SESSION et la table INDIVIDU. Cela dit pour répondre à votre question, pour parcourir les éléments sélectionnés dans une zone de liste il faut procéder de la façon suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Insérer()
On Error GoTo gestion_err:
 
Dim vaIndividu                      As Variant
 
    If Not IsNull(id_individu.ItemsSelected) Then
        For Each vaIndividu In id_individu.ItemsSelected
            Debug.Print id_individu.ItemData(vaIndividu)
        Next
    End If
 
Sortie:
Exit Sub
gestion_err:
    MsgBox Err.Description & Chr(13) & "Erreur numéro: " & Err.Number & Chr(13) & "Dans la Sub Insérer"
    Resume Sortie
End Sub

Vous n'avez qu'a remplacé le "Debug.Print" par le code que vous désirez.

Bonne journée

[Vince143]

Bonjour Robert1957, veuillez m'excuser pour le temps de réponse, mais je peux y consacrer du temps qu'en fin de semaine.

J'ai rectifié la BDD comme vous l'avez suggérée.

D'autre part, j'ai du mal à compléter le code proposé.

Encore une fois merci de votre aide et de vos explications.

Ici le projet : OSP.rar

[Robert1957]

Bonjour Vince143,

Voici la Bd, j'ai modifié votre formulaire d'inscription/session.

Le code suivant parcours les lignes sélectionnées du "individu_id" pour les inscrire dans la table "Session_Individu" et ensuite mettre à jour le sous-formulaire "Ajout_Session_Individu_SF".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Compare Database
Option Explicit
 
Private Sub Ajout_Session_Individu_Click()
On Error GoTo gestion_err:
 
Dim db                          As DAO.Database
Dim rst                         As DAO.Recordset
Dim vaIndividu                  As Variant
 
    If Not IsNull(individu_id.ItemsSelected) Then
        Set db = CurrentDb
        Set rst = db.OpenRecordset("SELECT Session_Individu.* FROM Session_Individu;", 2, 512)
        For Each vaIndividu In individu_id.ItemsSelected
            rst.AddNew
                rst("session_id") = Me.id_session
                rst("individu_id") = individu_id.ItemData(vaIndividu)
            rst.Update
        Next
    End If
    Me.Ajout_Session_Individu_SF.Requery
 
Sortie:
On Error Resume Next
rst.Close
Set rst = Nothing
Set db = Nothing
Exit Sub
gestion_err:
    MsgBox Err.Description & Chr(13) & "Erreur numéro: " & Err.Number & Chr(13) & "Dans la Sub Insérer"
    Resume Sortie
End Sub

Vous remarquerez que j'ai ajouté en début de module les instructions
"Option Compare Database"
"Option Explicit"
Vous devriez les inscrire par défaut dans tous les modules.
Une autre suggestion est de garder une façon uniforme pour les noms des objets de votre base. Exemple on retrouve: "individu_id" et "id_individu".

Bonne journée

[Vince143]

Bonsoir, Robert1957;
Je vous remercie sincèrement de votre soutien. Je vais appliquer vos conseils.