Discussion :

[saiddje]

Bonjour
J'ai créé une macro pour afficher automatiquement la date du jour dans une cellule d'une colonne donnée. Mais ça ne fonctionne pas, la macro bug à un moment donné. Merci pour votre aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B") = "" Then Cells(i, "B").Value =Date & " " & Time
Cells(i, "B").NumberFormat = "m/d/yyyy"
 
Next
Range("B:B").EntireColumn.AutoFit
 
End Sub

[Philippe Tulliez]

Bonjour,

J'ai créé une macro pour afficher automatiquement la date du jour dans une cellule d'une colonne donnée

Ce n'est pas dans une cellule données mais bien dans une plage complète (100 lignes )

Mais ça ne fonctionne pas, la macro bug à un moment donné

Mais encore, quel est ce moment donné et surtout lorsque le VBA bogue, en général il envoie un message d'erreur avec un numéro ET un message assez explicite. Cela aiderait de savoir quel message est envoyé et à quel moment dans la boucle (valeur de I) cela se passe.

Autre interrogation.
Vous utilisez la procédure événementielle Worksheet_Change et vous ne vous préoccupez pas de son argument Target qui permet entre-autre de savoir le nombre de cellules concernées par changement grâce à sa propriété Count ou sur quelle colonne ou ligne ou les deux a eu lieu de changement.

Un peu plus de précisions nous aidera à apporter une réponse pertinente

[saiddje]

Bonjour Philippe,
voici le message d'erreur :

Erreur d'exécution :
La méthode " NumberFormat" de l'objet Range a échoué

Merci pour votre aide

[Tête de chat]

Bonjour,

je ne vois rien dans le numberformat que tu nous montres qui puisse attirer les foudres d'Excel

Comme l'a dit l'excellent Pierre Fauconnier que je salue, c'est bien d'avoir le message ET là où ça plante.

Je soupçonne peut-être un autre code événementiel qui serait appelé en cascade ? Ou que le code qui plante n'est pas celui qui est collé ici

À noter déjà que ton sub est appelé 2 fois : le dépôt de la date provoque un autre événement change qui relance le sub. Et si tu fais un copier/coller de 10 valeurs dans la colonne A il sera appelé 11 fois...
Ajoute un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.EnableEvents = False

au début du sub (et un =true) après pour traiter ça. Attention qu'en cas d'erreur il restera à false donc à terme intégrer ça dans une gestion d'erreur pour que le retour à true soit fait systématiquement

[saiddje]

en pj le message erreur
Merci
c'est la ligne Cells(i, "B").NumberFormat = "m/d/yyyy" qui est en surbrillance jaune

[Philippe Tulliez]

Bonjour,
C'est effectivement curieux. Quelle est la valeur de la variable I ?

Pas certain que cela vienne de là mais je constate que la ligne Cells(i, "B").NumberFormat = "m/d/yyyy" n'est pas incluse dans le SI donc le formatage se fait sur toutes les lignes. Qui a t'il dans la celleule B & i ?

[saiddje]

j'ai changé mon code :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "C").Value = "" Then Cells(i, "C") = Date & " " & Time

Next

End Sub

Du coup ça marche bien maintenant.

En plus de cela je voudrais afficher le nom du jour automatiquement dans la colonne B dès que A est complété.
Je n'y arrive pas
J'ai essayé :

Sub AfficheJour()
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Date
Next
End Sub
Merci !!

[Tête de chat]

Re,

en relisant de plus près :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cells(i, "B").Value =Date & " " & Time

ce que tu mets dans la cellule est un string. Donc le NumberFormat que tu essayais de poser ne servait à rien, comme son nom l'indique il sert à formater les numériques (il aurait fallu écrire date + time) pas les chaînes. Sans compter qu'ajouter l'heure alors que le format n'affichait que la date...
Ça n'explique en rien l'erreur que tu avais mais bon...

Là tu as en fait un formatage automatique par VBA à la volée sauf que comme d'hab il hésite entre jj/mm et mm/jj ; essaye de mettre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cells(i, "B").Value =Date -15 & " " & Time

comme si on était en début de mois et regarde ce que tu obtiens.

Avec ce que tu as ajouté :

Déjà je ne vois pas l'appel de AfficheJour ; donc on ne sait pas pas si ton pb est qu'il ne se passe rien ou que ce qui se passe n'est pas ce que tu attends.

Si tu lances AfficheJour "à la main", avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Date

cette fois tu as bien un numérique, et sans format ça doit donner environ 45 313 (en tout cas aujourd'hui 22/01/2024).
Soit tu mets le format dans la foulée, avec le risque de voir revenir le bug (enfin ça serait un moindre mal on pourrait se repencher dessus...) soit tu formates la valeur en la posant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then 
   Cells(i, "B") = Date
   Cells(i, "B").NumberFormat = "dddd"
End If

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Format(Date,"dddd")

Attention en passant : comme tu n'as appliqué ni les recommandations de Philippe sur le test de target, ni les miennes sur le EnableEvents, le sub OnChange va partir plus que jamais pour rien.

Essaye :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private Sub Worksheet_Change(ByVal Target As Range)
Dim MaDate As Double
Dim MesModifs As Range, MaModif As Range
 
Application.EnableEvents = False
On Error GoTo fin_change
MaDate = Date + Time ' en cas de sélection multiple, si la màj est ralentie, toutes les lignes auront * quand même * le même horodatage
Set MesModifs = Application.Intersect(Target, Range("A2:A100"))
If Not MesModifs Is Nothing Then
    For Each MaModif In MesModifs.Cells
        If MaModif.Value <> "" And MaModif.Offset(0, 1).Value = "" Then
           MaModif.Offset(0, 1).Value = MaDate
           MaModif.Offset(0, 1).NumberFormat = "dddd dd/mm/yyyyy hh:mm:ss"
        End If
    Next MaModif
End If
 
fin_change:
If Err <> 0 Then MsgBox "Erreur #" & Err & " " & Err.Description, vbCritical
Application.EnableEvents = True
End Sub

[saiddje]

Finalement
voici ma macro qui fonctionne plutôt bien :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now
Next
End Sub

Merci à tous

[Tête de chat]

Bonjour

voici ma macro qui fonctionne plutôt bien

Je suis plutôt d'accord avec le plutôt
Chaque fois que tu cliques dans ta feuille le selection_change part et donc tu fais une boucle de 99 cycles pour rien. Le Change était un meilleur choix pour ce que tu veux faire.

Et le format, qui est ce qui posait problème à la base, tu l'as posé à la main une fois pour toute sur la colonne B ? Tu as essayé ce que j'ai posté en fin du #8 ?

[saiddje]

j'ai effectivement essayé mais ça n'a pas fonctionné.
pour le format de date/heure , j'ai dû changer le format de cellule de la colonne directement sur ma feuille. C'est pas top !! d'autant plus qu'il n'affiche pas le jour mais juste la date et l'heure ( 07/02/2024 13:03 )
Est-ce que tu aurais une solution "simple" qui afficherait sous format : mercredi 7 février 2024 13:03
Merci

[Tête de chat]

Re,

j'ai effectivement essayé mais ça n'a pas fonctionné.

Mais encore ? Il s'est passé quoi ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Est-ce que tu aurais une solution "simple" qui afficherait sous format : mercredi 7 février 2024 13:03

Dans le format de nombres, en format personnalisé tu mets : JJJJ JJ MMMM AAAA hh:mm

[saiddje]

ok Tête de Chat,
j'ai remodifié le format date en JJJJ JJ MMMM AAAA hh:mm
ça me convient
Merci !!!

[Lamech79]

Bonjour.
Je me permets de rentrer dans cette discussion parce que j'ai exactement le même souci. Je veux avoir sur ma feuille de calcul une cellule qui affiche automatiquement la date du jour. Cela me permettra d'automatiser mes calculs. Je ne connais rien en création de macro ni de vba. Merci de m'aider.
Cordialement.

[saiddje]

utilise celle-ci :
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now
Next
End Sub


En revanche, petite cerise sur le gâteau, je souhaiterais également un affichage de la date et heure en colonne C
j'ai modifié en écrivant :c

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now And Cells(i, "C") = Now
Next
End Sub

j'ai des résultats farfelus du type une date en 00/01/1900 00:00:00 !!!!!??????

[deedolith]

Salut,

Si tu nous expliquais l'ensemble de ton projet ?
Je pense que l'on sera plus à même de te proposer une solution adaptée avec une vision plus globale.

Ce sera mieux que galérer sur un point de détail dont on ne connait ni les tenants, ni les aboutissants.

[Lamech79]

utilise celle-ci :
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now
Next
End Sub


En revanche, petite cerise sur le gâteau, je souhaiterais également un affichage de la date et heure en colonne C
j'ai modifié en écrivant :c

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now And Cells(i, "C") = Now
Next
End Sub

j'ai des résultats farfelus du type une date en 00/01/1900 00:00:00 !!!!!??????

Merci. Je vais essayer et te revenir.
Cordialement

[Tête de chat]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now And Cells(i, "C") = Now

donc tu poses dans la colonne B : Now AND Cells(i,"C") = Now donc 0 ce qui explique ce que tu vois

Tu voulais peut-être écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then 
     Cells(i, "B") = Now 
     Cells(i, "C") = Now
End If

Et je me permets d'insister lourdement :
1. selection_change n'est pas le bon événement pour savoir si une cellule est modifiée
2. exploite target pour savoir quelle cellule est modifiée au lieu de boucler sur tes 100 lignes

[saiddje]

bonjour,
pour revenir plus globalement sur mon besoin :
j'ai un tableau à 3 colonnes, 1000 lignes :
colonne A : contient une information à saisir ou pas
colonne B : si A contient une information, affiche automatiquement la date et heure au moment de la saisie et qui reste fixe ( format : jeudi 8 février 2024 10:24 )
colonne C : si A contient une information, affiche automatiquement le jour de la saisie ( format: jeudi )

Pour l'instant j'en suis à la macro suivante qui fonctionne bien :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim i As Integer
For i = 2 To 100
If Cells(i, "A").Value <> "" And Cells(i, "B").Value = "" Then Cells(i, "B") = Now

Next
End Sub

pour la date en colonne C , j'ai utilisé aujourd'hui mais ce n'est du fixe...

Des idées ???
Merci

[deedolith]

Salut,

Ta macro fonctionne, mais elle fait beaucoup de travail inutile,
et l'évennement Change sera beaucoup plus approprié.

Voici une version plus Efficasse (elle ne 'occupe que d'une "ligne"):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not (Intersect(Target, Me.Range("A2:A100")) Is Nothing) Then
        Dim Rng As Excel.Range
        If Not IsEmpty(Target.Value) Then
            Set Rng = Target.Offset(ColumnOffset:=1)
            If (IsEmpty(Rng.Value)) Then
                Rng.Value = Now
                Rng.NumberFormat = "dddd d mmmm yyyy hh:mm"
            End If
 
            Set Rng = Target.Offset(ColumnOffset:=2)
            If (IsEmpty(Rng.Value)) Then
                Rng.Value = Now
                Rng.NumberFormat = "dddd"
            End If
        Else
            Set Rng = Target.Offset(ColumnOffset:=1)
            Rng.Value = Empty
            Set Rng = Target.Offset(ColumnOffset:=2)
            Rng.Value = Empty
        End If
    End If
End Sub