Empêcher une incompatibilité dans le choix des items

**dylandusud** · 31/03/2024, 23h49

Bonsoir,

Nouveau sur le forum, j'espère trouver ma réponse ici

J'ai crée un batch en m'inspirant de ce topic du forum:

"Sélection multiples dans .bat [Batch]" (désolé je ne peux pas mettre le lien, ca le détecte en tant que spam)

Dans ce même batch j'ai mis une parti pour installer et désinstaller une (ou plusieurs) application(s).

La je cherche à savoir comment je pourrais rendre incompatible (via une erreur avec message et du coup un retour à zero sur le choix initial) si l'utilisateur coche deux items incompatible (item d'installation du logiciel 2, mais en même temps l'item de désinstallation du logiciel 2)

Tout en sachant qu'il est quand même possible d'installer le logiciel 2 et de désinstaller le logiciel 3...

Merci à tous.

**ericlm128** · 01/04/2024, 12h03

Bonjour,

As tu un bout de code à nous proposer ?

Tous les logiciels installable sont aussi désinstallable ?

**dylandusud** · 01/04/2024, 18h12

Bonjour,

J'ai exactement le même que celui ci pour l'instant (il me reste à compléter les items)

La le but du coup serait de dire que l'item 1 n'est pas compatible avec le 5...

Code BATCH :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Initialize
FOR /L %%I IN (1,1,8) DO SET ITEM%%I=[ ]
 
:Boucle
CLS
ECHO Choisissez les logiciels que vous souhaitez installer :
ECHO.
ECHO %ITEM1% 01. Installation Google Chrome
ECHO %ITEM2% 02. Installation Mozilla Firefox
ECHO %ITEM3% 03. Installation 7Zip
ECHO %ITEM4% 04. Installation NotePad++
ECHO %ITEM5% 05. Desinstallation Google Chrome
ECHO %ITEM6% 06. Desinstallation Mozilla Firefox
ECHO %ITEM7% 07. Desinstallation 7Zip
ECHO %ITEM8% 08. Desinstallation NotePad++
ECHO.
ECHO Taper Q pour Quitter
ECHO Taper R pour lancer l'installation
 
set WhichItem=
SET /P WhichItem=Faites votre choix et appuyer sur ENTER : 
 
IF NOT DEFINED WhichItem GOTO Boucle
IF /I "%WhichItem%"=="Q" GOTO :EOF
IF /I "%WhichItem%"=="R" GOTO RunOptions
 
SET /A WhichItem=%WhichItem%
 
FOR /L %%I IN (1,1,8) DO IF "%%I"=="%WhichItem%" (
	IF "!Item%WhichItem%!"=="[X]" (
		SET Item%WhichItem%=[ ]
	) ELSE (
		SET Item%WhichItem%=[X]
	)
)
GOTO Boucle
 
:RunOptions
FOR /L %%I IN (1,1,8) DO IF "!Item%%I!"=="[X]" call :Item%%I
pause
GOTO :EOF
 
:item1
 
GOTO :EOF
 
:item2
 
GOTO :EOF
 
:item3
 
GOTO :EOF
 
:item4
 
GOTO :EOF

et oui tous les logiciels installable sont aussi désinstallable

**ericlm128** · 01/04/2024, 21h53

Je ferais ceci

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Initialize
FOR /L %%I IN (1,1,8) DO SET ITEM%%I=[ ]
 
:Boucle
CLS
ECHO Choisissez les logiciels que vous souhaitez installer :
ECHO.
ECHO %ITEM1% 01. Installation Google Chrome
ECHO %ITEM2% 02. Installation Mozilla Firefox
ECHO %ITEM3% 03. Installation 7Zip
ECHO %ITEM4% 04. Installation NotePad++
ECHO %ITEM5% 05. Desinstallation Google Chrome
ECHO %ITEM6% 06. Desinstallation Mozilla Firefox
ECHO %ITEM7% 07. Desinstallation 7Zip
ECHO %ITEM8% 08. Desinstallation NotePad++
ECHO.
ECHO Taper Q pour Quitter
ECHO Taper R pour lancer l'installation
 
set WhichItem=
SET /P WhichItem=Faites votre choix et appuyer sur ENTER : 
 
IF NOT DEFINED WhichItem GOTO Boucle
IF /I "%WhichItem%"=="Q" GOTO :EOF
IF /I "%WhichItem%"=="R" GOTO RunOptions
 
SET /A WhichItem=%WhichItem%
 
FOR /L %%I IN (1,1,8) DO IF "%%I"=="%WhichItem%" (
	IF "!Item%WhichItem%!"=="[X]" (
		SET Item%WhichItem%=[ ]
 
	) ELSE (
		SET Item%WhichItem%=[X]
		IF "%WhichItem%"=="1" SET Item5=[ ]
		IF "%WhichItem%"=="2" SET Item6=[ ]
		IF "%WhichItem%"=="3" SET Item7=[ ]
		IF "%WhichItem%"=="4" SET Item8=[ ]
		IF "%WhichItem%"=="5" SET Item1=[ ]
		IF "%WhichItem%"=="6" SET Item2=[ ]
		IF "%WhichItem%"=="7" SET Item3=[ ]
		IF "%WhichItem%"=="8" SET Item4=[ ]
	)
)
GOTO Boucle
 
:RunOptions
FOR /L %%I IN (1,1,8) DO IF "!Item%%I!"=="[X]" call :Item%%I
pause
GOTO :EOF
 
:item1
 
GOTO :EOF
 
:item2
 
GOTO :EOF
 
:item3
 
GOTO :EOF
 
:item4
 
GOTO :EOF

PS : Si tu es sur d'avoir une symétrie parfaite (4 installations / 4 désinstallations, 10/10...) on peux surement faire un calcul pour éviter de tout définir à la main

**dylandusud** · 01/04/2024, 22h16

Merci !
Et oui je suis sûr d’avoir le même nombre d’installation que de désinstallation

**ericlm128** · 02/04/2024, 08h47

Dans ce cas la

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Initialize
FOR /L %%I IN (1,1,8) DO SET ITEM%%I=[ ]
 
:Boucle
CLS
ECHO Choisissez les logiciels que vous souhaitez installer :
ECHO.
ECHO %ITEM1% 01. Installation Google Chrome
ECHO %ITEM2% 02. Installation Mozilla Firefox
ECHO %ITEM3% 03. Installation 7Zip
ECHO %ITEM4% 04. Installation NotePad++
ECHO %ITEM5% 05. Desinstallation Google Chrome
ECHO %ITEM6% 06. Desinstallation Mozilla Firefox
ECHO %ITEM7% 07. Desinstallation 7Zip
ECHO %ITEM8% 08. Desinstallation NotePad++
ECHO.
ECHO Taper Q pour Quitter
ECHO Taper R pour lancer l installation
 
set WhichItem=
SET /P WhichItem=Faites votre choix et appuyer sur ENTER : 
 
IF NOT DEFINED WhichItem GOTO Boucle
IF /I "%WhichItem%"=="Q" GOTO :EOF
IF /I "%WhichItem%"=="R" GOTO RunOptions
 
SET /A WhichItem=%WhichItem%
 
FOR /L %%I IN (1,1,8) DO IF "%%I"=="%WhichItem%" (
	IF "!Item%WhichItem%!"=="[X]" (
		SET Item%WhichItem%=[ ]
	) ELSE (
		SET Item%WhichItem%=[X]
		SET /A "mod=((%%~I-1+(8/2))%%8)+1"
		SET Item!mod!=[ ]
	)
)
GOTO Boucle
 
:RunOptions
FOR /L %%I IN (1,1,8) DO IF "!Item%%I!"=="[X]" call :Item%%I
pause
GOTO :EOF
 
:item1
 
GOTO :EOF
 
:item2
 
GOTO :EOF
 
:item3
 
GOTO :EOF
 
:item4
 
GOTO :EOF

**dylandusud** · 02/04/2024, 13h00

Merci, j'ai décidé de faire un peu plus, le choix de tous installer, ou de tous désinstaller. Donc si je fais le choix 1 et le choix 7, ca me conserve l'ensemble des sélections on peut rajouter se blocage aussi ?

Code BATCH :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Initialize
FOR /L %%I IN (1,1,12) DO SET ITEM%%I=[ ]
 
:Boucle
CLS
ECHO Choisissez les logiciels que vous souhaitez installer :
ECHO.
ECHO %ITEM1% 01. Installation de tous les logiciels
ECHO %ITEM2% 02. Installation Mozilla Firefox
ECHO %ITEM3% 03. Installation 7Zip
ECHO %ITEM4% 04. Installation NotePad++
ECHO %ITEM5% 05. Installation Google Chrome
ECHO %ITEM6% 06. Installation Teams
ECHO.
ECHO %ITEM7% 07. Desinstallation de tous les logiciels
ECHO %ITEM8% 08. Desinstallation Mozilla Firefox
ECHO %ITEM9% 09. Desinstallation 7Zip
ECHO %ITEM10% 10. Desinstallation NotePad++
ECHO %ITEM11% 11. Desinstallation Google Chrome
ECHO %ITEM12% 12. Desinstallation Teams
ECHO.
ECHO Taper Q pour Quitter
ECHO Taper R pour lancer l installation
 
SET WhichItem=
SET /P WhichItem=Faites votre choix et appuyer sur ENTER : 
 
IF NOT DEFINED WhichItem GOTO Boucle
IF /I "%WhichItem%"=="Q" GOTO :EOF
IF /I "%WhichItem%"=="R" GOTO RunOptions
 
SET /A WhichItem=%WhichItem%
 
IF "%WhichItem%"=="1"  (
	IF "!Item%WhichItem%!"=="[X]" (
		FOR /L %%I IN (1,1,6) DO SET Item%%I=[ ]
	) ELSE (
		FOR /L %%I IN (1,1,6) DO SET Item%%I=[X]
	)
)
 
IF "%WhichItem%"=="7"  (
	IF "!Item%WhichItem%!"=="[X]" (
		FOR /L %%I IN (7,1,12) DO SET Item%%I=[ ]
	) ELSE (
		FOR /L %%I IN (7,1,12) DO SET Item%%I=[X]
	)
)
 
FOR /L %%I IN (1,1,12) DO IF "%%I"=="%WhichItem%" (
	IF "!Item%WhichItem%!"=="[X]" (
		SET Item%WhichItem%=[ ]
	) ELSE (
		SET Item%WhichItem%=[X]
		SET /A "mod=((%%~I-1+(12/2))%%12)+1"
		SET Item!mod!=[ ]
	)
)
set Item1=[X]
FOR /L %%I IN (2,1,6) DO IF "!Item%%I!"=="[ ]" SET Item1=[ ]
 
set Item7=[X]
FOR /L %%I IN (7,1,12) DO IF "!Item%%I!"=="[ ]" SET Item7=[ ]
GOTO Boucle
 
:RunOptions
FOR /L %%I IN (1,1,25) DO IF "!Item%%I!"=="[X]" call :Item%%I
pause
GOTO :EOF

J'ai retiré les ITEMS pour alléger le code sur le forum

**ericlm128** · 02/04/2024, 18h33

Il y a peut être mieux en code mais c'est l'idée déjà

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM Initialize
FOR /L %%I IN (1,1,12) DO SET ITEM%%I=[ ]
 
:Boucle
CLS
ECHO Choisissez les logiciels que vous souhaitez installer :
ECHO.
ECHO %ITEM1% 01. Installation de tous les logiciels
ECHO %ITEM2% 02. Installation Mozilla Firefox
ECHO %ITEM3% 03. Installation 7Zip
ECHO %ITEM4% 04. Installation NotePad++
ECHO %ITEM5% 05. Installation Google Chrome
ECHO %ITEM6% 06. Installation Teams
ECHO.
ECHO %ITEM7% 07. Desinstallation de tous les logiciels
ECHO %ITEM8% 08. Desinstallation Mozilla Firefox
ECHO %ITEM9% 09. Desinstallation 7Zip
ECHO %ITEM10% 10. Desinstallation NotePad++
ECHO %ITEM11% 11. Desinstallation Google Chrome
ECHO %ITEM12% 12. Desinstallation Teams
ECHO.
ECHO Taper Q pour Quitter
ECHO Taper R pour lancer l installation
 
set WhichItem=
SET /P WhichItem=Faites votre choix et appuyer sur ENTER : 
 
IF NOT DEFINED WhichItem GOTO Boucle
IF /I "%WhichItem%"=="Q" GOTO :EOF
IF /I "%WhichItem%"=="R" GOTO RunOptions
 
SET /A WhichItem=%WhichItem%
 
SET P1=
SET P2=
 
IF %WhichItem% == 1 (
	SET "P1=[X]"
	SET "P2=[ ]"
)
 
SET /A "idx=12/2+1"
IF %WhichItem% == %idx% (
	SET "P1=[ ]"
	SET "P2=[X]"
)
 
IF DEFINED P1 (
	FOR /L %%I IN (2,1,12) DO (
		IF %%I LSS %idx% SET Item%%I=%P1%
		IF %%I GTR %idx% SET Item%%I=%P2%
	)
GOTO Boucle
)
 
 
FOR /L %%I IN (1,1,12) DO IF "%%I"=="%WhichItem%" (
	IF "!Item%WhichItem%!"=="[X]" (
		SET Item%WhichItem%=[ ]
 
	) ELSE (
		SET Item%WhichItem%=[X]
		SET /A "mod=((%%~I-1+(12/2))%%12)+1"
		SET Item!mod!=[ ]
	)
)
GOTO Boucle
 
:RunOptions
FOR /L %%I IN (1,1,12) DO IF "!Item%%I!"=="[X]" call :Item%%I
pause
GOTO :EOF
 
:item1
 
GOTO :EOF
 
:item2
 
GOTO :EOF
 
:item3
 
GOTO :EOF
 
:item4
 
GOTO :EOF

**dylandusud** · 09/04/2024, 13h42

Ca me suffit largement, merci beaucoup pour ton aide !

Empêcher une incompatibilité dans le choix des items [Batch]

Scripts/Batch

Discussions similaires

Partager

Partager