problème de reset color

**Miska59** · 27/06/2024, 21h15

Bonsoir,

j'ai créée un class Label Multiple color mais j'ai ajouter un fonction ResetAllKeyWord dans ma class.

mon code form1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        MarkLabelColor1.ResetAllKeyWord({"Mark", "Label", "Color", "1"}, {Color.Red, Color.Blue, Color.YellowGreen, Color.Green})
    End Sub

dans la class :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public Sub ResetAllKeyWord(ByVal keyList As String(), ByVal ColorList As Color())
        Dim query = From str In keyList Select New MarkKey() With {.KeyWord = str, .KeyColor = ColorList(str.Length - 1)}
        Me.KeyWords = query.ToArray
        Me.Refresh()
    End Sub
 
Public Class MarkKey
    Public Property KeyWord As String
    Public Property KeyColor As Color
 
End Class

mon problème c'est comme puis-je mis prends avec une liste de mot et couleur avec ResetAllKeyWord ?

**umfred** · 28/06/2024, 18h29

c'est quoi le but de ta fonction ? c'est lié à ta question précédente ? https://www.developpez.net/forums/d2...ultiple-color/
pourquoi le principe serait différent de celle-ci ?

**Miska59** · 28/06/2024, 21h37

Bonsoir umfred,

j'ai créé un class label muliple color. le but c'est simplifier les choses que l'utilisateur pourrais choisir une ou plusieurs couleurs dans un label (voir image).
Nom : Capture d’écran 2024-06-28 072448.png
Affichages : 83
Taille : 12,0 Ko

Nom : Capture d’écran 2024-06-28 072448.png
Affichages : 83
Taille : 12,0 Ko

le code par rapport au texte du label:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        MarkLabelColor1.ResetAllKeyWord({"class", "label"}, Color.Red)
    End Sub

dans la class :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Public Sub ResetAllKeyWord(ByVal keyList As String(), ByVal ColorList As Color)
        Dim query As IEnumerable(Of MarkKey) = From str In keyList Select New MarkKey() With {.KeyWord = str, .KeyColor = ColorList}
        Me.KeyWords = query.ToArray
        Me.Refresh()
    End Sub

j'ai essayer plusieurs solution j'arrive pas avec ColorList avec plusieurs couleur par rapport au texte. avez-vous une autre solution pour obtenir plusieurs couleur avec ResetAllKeyWord?

**Miska59** · 29/06/2024, 17h19

Bonsoir a tous,

voici un exemple ce que je voulais faire( voir image).
Nom : Capture d’écran 2024-06-28 220533.png
Affichages : 69
Taille : 12,2 Ko

mon code dans form1_load :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim data As New MarkKey("class", Color.Blue)
        Dim data1 As New MarkKey("label", Color.Red)
        MarkLabelColor1.KeyWords = New MarkKey() {data, data1}

pour simplifier les choses, j'ai refait mon code mais j’obtiens pas le même résultats(voir image).
Nom : Capture d’écran 2024-06-28 220533.png
Affichages : 69
Taille : 11,8 Ko

Nom : Capture d’écran 2024-06-28 220533.png
Affichages : 69
Taille : 11,8 Ko

mon code dans form1_load :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MarkLabelColor1.ResetAllKeyWordColor({"class", "label"}, {Color.Blue, Color.Red})

le code dans MarkLabelColor :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Friend Sub ResetAllKeyWordColor(ByVal keyList As String(), ByVal ColorList As Color())
        Dim query As IEnumerable(Of MarkKey) = From str In keyList From str2 In ColorList Where Not String.IsNullOrEmpty(str) AndAlso Not IsNothing(str2) Select New MarkKey(str, str2)
        Me._Keywords = query.ToArray
        Me.Refresh()
    End Sub

pouvez-vous m'aider à avoir plusieurs couleur par rapport au texte avec ResetAllKeyWordColor?

**chrismonoye** · 30/06/2024, 11h26

bonjour
dans l'esprit de ce que je comprends de votre projet, j'utiliserais une collection de Tuple - couple, où l'on stocke la sélection de mots et leur couleur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
        Dim colorsWordsList As New List(Of (keyword As String, keycolor As Color)) From
            {("class", Color.Blue), ("label", Color.Red), ("contient", Color.Yellow)}
 
        MarkLabelColor1.ResetAllKeyWordColor(colorsWordsList)

Dans la classe MarkLabelColor, la fonction ResetAllKeyWordColor récupère ses valeurs pour créer une liste d'objets Markkey :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
    Private listwordscolors As List(Of MarkKey)
 
    Function ResetAllKeyWordColor(keyList As List(Of (keyword As String, keycolor As Color))) As List(Of MarkKey)
        Dim query = From str In keyList Select New MarkKey() With {.KeyWord = str.keyword, .KeyColor = str.keycolor}
        Me.listwordscolors = query.ToList
        Return listwordscolors
    End Function

toujours dans cette classe, dans la procédure OnPaint reste à écrire les mots de string.
Si le mot appartient à la liste de mots à colorier, alors on l'écrit avec sa couleur, sinon on l'écrit en noir.
Bonne continuation.

**Miska59** · 30/06/2024, 12h41

Bonjour chrismonoye, merci d'avoir répondu. j'ai essayer votre code ça fonctionne très bien. pour encore simplifier le code j'ai fait ceci (voir dessous).

Nom : Capture d’écran 2024-06-29 232915.png
Affichages : 61
Taille : 12,3 Ko

Nom : Capture d’écran 2024-06-29 232915.png
Affichages : 61
Taille : 12,3 Ko

mon code dans form1_load :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        MarkLabelColor1.ResetAllKeyWordColor({("class", Color.Blue), ("label", Color.Red)})
    End Sub

le code dans MarkLabelColor :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Sub ResetAllKeyWordColor(MyList() As (Data As String, MyColor As Color))
        Dim query As IEnumerable(Of MarkKey) = From str In MyList Select New MarkKey(str.Data, str.MyColor)
        Me._Keywords = query.ToArray
        Me.Refresh()
    End Sub

voici la class complet MarkLabelColor pour celui qui est intéressé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
 
Public Class MarkLabelColor : Inherits Control
 
    Private _Keywords As MarkKey()
    Public Property KeyWords As MarkKey()
        Get
            Return _Keywords
        End Get
        Set(value As MarkKey())
            _Keywords = value : Invalidate()
        End Set
    End Property
 
    Public Sub New()
        SetStyle(ControlStyles.OptimizedDoubleBuffer Or ControlStyles.UserPaint, True)
        MyBase.Text = Me.Name
        Me.Font = New Font("Times New Roman", 12, FontStyle.Regular)
        Dim Lab As New MarkKey("Mark", Color.Blue)
        Dim Lab1 As New MarkKey("Label", Color.Red)
        Dim Lab2 As New MarkKey("Color", Color.Lime)
        Dim Lab3 As New MarkKey("1", Color.Fuchsia)
        Me._Keywords = New MarkKey() {Lab, Lab1, Lab2, Lab3}
    End Sub
    Protected Overrides Sub OnPaint(ByVal e As PaintEventArgs)
        TextRenderer.DrawText(e.Graphics, Me.Text, Me.Font, New Point(0, 0), Me.ForeColor)
        If Me.Text.Length <= 0 Then Return
        For i As Integer = 0 To _Keywords.Length - 1
            Dim keyWord As String = _Keywords(i).KeyWord
            Dim keyColor As Color = _Keywords(i).KeyColor
            Dim keyWidth As Integer = TextRenderer.MeasureText(keyWord, Me.Font).Width
            Dim IndexOffset As Integer = Me.Text.IndexOf(keyWord)
            While IndexOffset >= 0
                Dim StrFront As String = Me.Text.Substring(0, IndexOffset)
                If StrFront.Length > 0 Then
                    Dim strWidth As Integer = TextRenderer.MeasureText(StrFront & keyWord, Me.Font).Width
                    TextRenderer.DrawText(e.Graphics, keyWord, Me.Font, New Point((strWidth - keyWidth), 0), keyColor)
                Else
                    TextRenderer.DrawText(e.Graphics, keyWord, Me.Font, New Point(0, 0), keyColor)
                End If
                IndexOffset += keyWord.Length
                If IndexOffset >= Me.Text.Length Then Exit While
                Dim StrBehind As String = Me.Text.Substring(IndexOffset)
                If StrBehind.Length <= 0 Then Exit While
                Dim index2 As Integer = StrBehind.IndexOf(keyWord)
                If index2 < 0 Then Exit While
                IndexOffset += index2
            End While
        Next
    End Sub
 
    'dans Form1_Load :
    'MarkLabelColor1.ResetKeyWord(Label, color.red)
    Public Sub ResetKeyWord(ByVal keyString As String, ByVal keyColor As Color)
        Me._KeyWords = New MarkKey() {New MarkKey(keyString, keyColor)}
        Me.Refresh()
    End Sub
 
    'dans Form1_Load:
    'MarkLabelColor1.ResetAllKeyWord({"Label", "1"}, color.red)
    Public Sub ResetAllKeyWord(ByVal keyList As String(), ByVal MyColor As Color)
        Dim query As IEnumerable(Of MarkKey) = From str In keyList Select New MarkKey(str, MyColor)
        Me._KeyWords = query.ToArray
        Me.Refresh()
    End Sub
 
    'dans Form1_Load:
    'MarkLabelColor1.ResetAllKeyWordColor({("Label", Color.Blue), ("1", Color.Red)})
    Public Sub ResetAllKeyWordColor(MyList() As (Data As String, MyColor As Color))
        Dim query As IEnumerable(Of MarkKey) = From str In MyList Select New MarkKey(str.Data, str.MyColor)
        Me._Keywords = query.ToArray
        Me.Refresh()
    End Sub
 
    Protected Overrides Sub OnAutoSizeChanged(e As System.EventArgs)
        MyBase.OnAutoSizeChanged(e)
        Me.AdjustSize(Me)
        MyBase.Invalidate()
    End Sub
 
    Protected Overrides Sub OnTextChanged(ByVal e As EventArgs)
        MyBase.OnTextChanged(e)
        Me.AdjustSize(Me)
        MyBase.Invalidate()
    End Sub
 
    Protected Overrides Sub OnFontChanged(e As EventArgs)
        MyBase.OnFontChanged(e)
        Me.AdjustSize(Me)
        MyBase.Invalidate()
    End Sub
 
    Private Sub AdjustSize(Label As MarkLabelColor)
        Dim x As Integer = Label.Width - Label.Size.Width
        Dim y As Integer = Label.Height - Label.Size.Height
        Dim size As Size = TextRenderer.MeasureText(Label.Text, Label.Font)
        Label.ClientSize = New Size(size.Width + x, size.Height + y)
        Label.MinimumSize = New Size(size.Width + x, size.Height + y)
        Label.MaximumSize = New Size(size.Width + x, size.Height + y)
    End Sub
End Class
 
Public Class MarkKey
 
    Public Sub New(ByVal word As String, ByVal MyColor As Color)
        _KeyWord = word
        _KeyColor = MyColor
    End Sub
 
    Private _KeyWord As String
    Public Property KeyWord As String
        Get
            Return _KeyWord
        End Get
        Set(value As String)
            If Not String.IsNullOrEmpty(value) Then
                _KeyWord = value
            Else
                Throw New ArgumentException("Veuillez entrer un texte pour étre en couleur !")
            End If
        End Set
    End Property
 
    Private _KeyColor As Color
    Public Property KeyColor As Color
        Get
            Return _KeyColor
        End Get
        Set(value As Color)
            If Not IsNothing(value) Then
                _KeyColor = value
            Else
                Throw New ArgumentException("Veuillez choisir une couleur par rapport au texte !")
            End If
        End Set
    End Property
End Class

problème de reset color

VB.NET

Discussions similaires

Partager

Partager