Discussion :

[SR.SFC]

Bonjour,

Dans un développement VBA, je duplique une feuille.
Cette feuille contient un tableau structuré. Sur ce tableau une plage nommée existe.
Il y a aussi une VD fait appel à une liste basée sur la colonne d'un tableau de paramètre situé sur une autre feuille.

Le duplication duplique aussi les plages nommées "Classeur" sous forme de plage "Feuille".
Je voudrait supprimer toutes les plages nommées "feuille" et conserver celles "Classeur".
Après recherche, je n'ai pas trouvé l'argument permettant de différencier la portée d'une plage, "Classeur" ou "feuille"
Quelqu'un a-t-il une idée ?


Merci de votre collaboration.

[Philippe Tulliez]

Bonjour,
Les noms de portée feuille sont préfixés du nom de la feuille suivi d'un point d'exclamation.
Voici une fonction générique qui renvoie la liste de tous les noms de portée feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function GetSheetScopeNames(Optional oWorkbook As Workbook) As Variant
  Dim n As Name
  Dim t As Variant
  Dim c As Integer
  Dim txt As String
  If oWorkbook Is Nothing Then Set oWorkbook = ActiveWorkbook
  For Each n In oWorkbook.Names
    If InStr(1, n.Name, "!") Then
       If c Then ReDim Preserve t(c) Else ReDim t(c)
       t(c) = n.Name: c = c + 1
    End If
  Next
  If c Then GetSheetScopeNames = t
  Set n = Nothing
End Function

Un exemple d'une procédure qui l'invoque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub TestGetSheetScopeNames()
  Dim l As Variant
  Dim m As String
  l = GetSheetScopeNames(ThisWorkbook)
  If IsArray(l) Then
    m = Join(l, vbCrLf)
   Else
    m = "Pas de nom de portée feuille"
  End If
  MsgBox m
End Sub

Pour supprimer les noms de portée feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
  If IsArray(l) Then
    For e = LBound(l) To UBound(l)
      ThisWorkbook.Names(l(e)).Delete
    Next
  End If