Discussion :

[cuati]

Bonjour,

Je voudrais savoir s'il est possible d'évaluer un polynôme en une matrice.
Par exemple avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
A = floor(10*rand(3,3));
P = poly(A,"x");

Par théorème de Cayley-Hamilton on sait que P(A) vaut la matrice nulle de taille 3x3.
J'ai essayé horner(P,A) , mais cela évaluae P en chaque coefficients de A au lieu de calculer le polynôme de matrice.
J'ai aussi essayé P(A) mais ça ne marche pas...

Auriez-vous une idée s'il vous plaît ?

[User]

Bonjour,

Est-ce que tu souhaites obtenir le polynôme caractéristique de la matrice pour ensuite pouvoir l'évaluer ?

https://fr.wikipedia.org/wiki/Polyn%...tique#Exemples

[cuati]

En fait l'idée était d'implémenter un algorithme pour obtenir la décomposition de Dunford à partir de n'importe quelle matrice A. Pour cela, j'ai en effet besoin d'évaluer un certain polynôme (obtenu à partir du polynôme caractéristique) en A.
J'ai résolu mon problème en créant la fonction qui évalue P en A :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
//Fonction qui calcule le polynôme de matrice P(A) :
function result = polyvalm(P, A)
    //Initialiser résultat avec la matrice nulle de même taille que A
    n = size(A, 1);
    result = zeros(n, n);
    // Obtenir les coefficients du polynôme
    coeffs = coeff(P);
    // Calculer chaque terme du polynôme
    for i = 1:length(coeffs)
        result = result + coeffs(i) * A^(i-1);
    end
endfunction
 
//Algorithme pour Dunford via Newton
function [D,N] = dunford(A)
    //calcule le polynôme caractéristique
    chi = poly(A,"x")
    chiprime = derivat(chi)
    P = chi / gcd([chi,chiprime])
    //calcule le polynôme P
    P = P('num')
    //calcule de P'
    Pprime = derivat(P)
 
    //initialisation des variables
    k = 0; n = size(A, 1); flag = %T; Ak=A
    //calcule des termes de la suite (A_k)    
    while k < n & flag
        PA = polyvalm(P, Ak)
        if PA == zeros(n,n) then
                flag = %F
        else
            Ak = Ak - PA*(polyvalm(Pprime, Ak))^(-1)
        end
        k = k + 1
    end
    D = Ak; N = A-D
endfunction