Pas de génération de fichier avec UTL_FILE si select ne remonte aucune DATA

**Blenderx** · 16/08/2024, 16h08

Bonjour à tous

Dans le cadre d'un projet j'ai du créer une procédure qui permet de généré un fichiers tous les X temps.

J'aimerai que si mon select ne trouve aucune ligne , le fichier ne soit pas crée.

Actuellement il est crée systématiquement avec la première ligne et l'en-tête.

Ci-dessous la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
create or replace PROCEDURE Export_RESERV_ENTRYToCSV AS
  file_handle UTL_FILE.FILE_TYPE;
BEGIN
  -- Ouvrir le fichier pour ecriture 
  file_handle := UTL_FILE.FOPEN('EXPORT_DIR', 'Resa_ENTRY-' || TO_CHAR(SYSDATE, 'YYMMDDHH24MISS') || '.csv', 'W', 32767);
 
  -- Ecrire la premiere ligne contenant la date et le nom du fichier
  UTL_FILE.PUT_LINE(file_handle, TO_CHAR(SYSDATE, 'DD.MM.YYYY HH24:MI:SS') || ';' || 'Resa_ENTRY-' || TO_CHAR(SYSDATE, 'YYMMDDHH24MISS') || '.csv');
 
  -- Ecrire l'en-tete 
  UTL_FILE.PUT_LINE(file_handle, 'NumResaExt;XENTRYTIME');
 
  FOR rec IN (SELECT * FROM RESERV_ENTRY WHERE ExpDateTime IS NULL and LRESERVSTATUS=11 and xentrytime IN(select MAX(xentrytime) from reserv_entry GROUP BY LORDERREF) order by xentrytime desc) LOOP
    UTL_FILE.PUT_LINE(file_handle, 
      '"' || rec.NumResaExt ||'";'|| 
      TO_CHAR(rec.XENTRYTIME, 'DD.MM.YYYY HH24:MI:SS') 
    );
 
    -- Mettre a jour ExpDateTime avec la date et l'heure de l'export
    UPDATE RESERV_ENTRY SET ExpDateTime = SYSTIMESTAMP WHERE NumResaExt = rec.NumResaExt;
  END LOOP;
 
 
  UTL_FILE.FCLOSE(file_handle);
 
 
EXCEPTION
  WHEN OTHERS THEN
    -- ici la gestion des erreurs
    IF UTL_FILE.IS_OPEN(file_handle) THEN
      UTL_FILE.FCLOSE(file_handle);
    END IF;
    RAISE;
END;

Si vous avez une idée je suis preneur

Merci

**JeitEmgie** · 19/08/2024, 13h48

Vous déplacez le code de création du fichier et d'écriture du header dans le FOR et vous le protégez par un flag pour qu'il ne soit exécuté qu'une seule fois.

**Blenderx** · 19/08/2024, 16h16

Envoyé par JeitEmgie

Vous déplacez le code de création du fichier et d'écriture du header dans le FOR et vous le protégez par un flag pour qu'il ne soit exécuté qu'une seule fois.

Bonjour,

Alors déplacer dans le For ok j'ai compris mais qu'entendez vous par le protéger par un Flag pour qu’il ne s'éxécute qu'une seule fois ?

**JeitEmgie** · 19/08/2024, 16h41

Envoyé par Blenderx

Bonjour,

Alors déplacer dans le For ok j'ai compris mais qu'entendez vous par le protéger par un Flag pour qu’il ne s'éxécute qu'une seule fois ?

????

vous créez une variable, lui assigner une valeur initiale, dans le FOR, dans un bloc IF, vous testez si elle vaut cette valeur, si oui vous créez le fichier et ajoutez le header, et vous changez la valeur de la variable , avant de reprendre le code original de la boucle.

**Blenderx** · 20/08/2024, 12h23

Envoyé par JeitEmgie

????

vous créez une variable, lui assigner une valeur initiale, dans le FOR, dans un bloc IF, vous testez si elle vaut cette valeur, si oui vous créez le fichier et ajoutez le header, et vous changez la valeur de la variable , avant de reprendre le code original de la boucle.

Bonjour,

Je comprend et voici ce que j'ai fait. Qu'en pensez vous ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
CREATE OR REPLACE PROCEDURE Export_RESERV_ENTRYToCSV AS
  file_handle UTL_FILE.FILE_TYPE;
  v_count     NUMBER;
BEGIN
  -- Compter les enregistrements à exporter
  SELECT COUNT(*) INTO v_count
  FROM RESERV_ENTRY 
  WHERE ExpDateTime IS NULL 
    AND LRESERVSTATUS = 11 
    AND xentrytime IN (SELECT MAX(xentrytime) 
                       FROM reserv_entry 
                       GROUP BY LORDERREF);
 
  -- Si le nombre d'enregistrements est supérieur à zéro, générer le fichier
  IF v_count > 0 THEN
    -- Ouvrir le fichier pour écriture
    file_handle := UTL_FILE.FOPEN('EXPORT_DIR', 'Resa_ENTRY-' || TO_CHAR(SYSDATE, 'YYMMDDHH24MISS') || '.csv', 'W', 32767);
 
    -- Écrire la première ligne contenant la date et le nom du fichier
    UTL_FILE.PUT_LINE(file_handle, TO_CHAR(SYSDATE, 'DD.MM.YYYY HH24:MI:SS') || ';' || 'Resa_ENTRY-' || TO_CHAR(SYSDATE, 'YYMMDDHH24MISS') || '.csv');
 
    -- Écrire l'en-tête
    UTL_FILE.PUT_LINE(file_handle, 'NumResaExt;XENTRYTIME');
 
    -- Sélection des données et écriture dans le fichier
    FOR rec IN (SELECT * FROM RESERV_ENTRY 
                WHERE ExpDateTime IS NULL 
                  AND LRESERVSTATUS = 11 
                  AND xentrytime IN (SELECT MAX(xentrytime) 
                                     FROM reserv_entry 
                                     GROUP BY LORDERREF) 
                ORDER BY xentrytime DESC) 
    LOOP
      UTL_FILE.PUT_LINE(file_handle, 
        '"' || rec.NumResaExt || '";' || 
        TO_CHAR(rec.XENTRYTIME, 'DD.MM.YYYY HH24:MI:SS')
      );
 
      -- Mettre à jour ExpDateTime avec la date et l'heure de l'export
      UPDATE RESERV_ENTRY 
      SET ExpDateTime = SYSTIMESTAMP 
      WHERE NumResaExt = rec.NumResaExt;
    END LOOP;
 
    -- Effacer les enregistrements où ExpDateTime est inférieur à SYSDATE - 30
    DELETE FROM RESERV_ENTRY 
    WHERE ExpDateTime < (SYSDATE - 400);
 
    -- Effacer les lignes correspondant à l'entrée P2
    DELETE FROM RESERV_ENTRY 
    WHERE xentrytime IN (SELECT MIN(xentrytime) 
                         FROM reserv_entry 
                         GROUP BY LORDERREF 
                         HAVING COUNT(*) > 1);
 
    COMMIT;
 
    -- Fermer le fichier
    UTL_FILE.FCLOSE(file_handle);
  END IF;
 
EXCEPTION
  WHEN OTHERS THEN
    -- Gestion des erreurs
    IF UTL_FILE.IS_OPEN(file_handle) THEN
      UTL_FILE.FCLOSE(file_handle);
    END IF;
    RAISE;
END;

**Michel.Priori** · 25/08/2024, 21h17

Bonsoir,

Personnellement je n'aurais pas fait :
A* dénombrement
B* curseur
C** export de la ligne
D** update de la table pour la ligne

Mais
1* mise en variable de la date
2* update de la table
3* dénombrement en fonction de l'update (ou SQL%rowcount)
4* curseur
5** export de la ligne

Ceci pour garantir qu'il n'y a pas eu de modification de jeu d'enregistrement entre l'étape A* et B*

On aurait pu aussi utiliser SPOOL (https://stackoverflow.com/questions/...-in-a-csv-file)

**escartefigue** · 04/09/2024, 14h29

Envoyé par Michel.Priori

Ceci pour garantir qu'il n'y a pas eu de modification de jeu d'enregistrement entre l'étape A* et B*

Tout à fait, et aussi parce qu'une requête ensembliste est bien plus performante qu'une requête ligne à ligne

Et on peut ajouter que le SELECT * en ligne 26 est à remplacer par une liste des colonnes utiles à la requête.
Voir les explications à ce sujet ICI

**vanagreg** · 04/09/2024, 16h07

Bonjour,

Tu peux stocker le query en bulk collect dans une collection. ça permettra d'une part d'éviter le count(*) préalable, et ensuite de boucler directement sur la collection. Si par exemple la collection s'appelle t:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
if t.count > 0 then
 -- création du fichier
 ...
 -- boucle pour créer les lignes
 for i in 1 .. t.count loop
 ...
 end loop;
 
 -- mis à jour table
 forall i in 1 .. t.count
 UPDATE RESERV_ENTRY 
 SET ExpDateTime = SYSTIMESTAMP 
 WHERE NumResaExt = t(i).NumResaExt;
 
end if;

Pas de génération de fichier avec UTL_FILE si select ne remonte aucune DATA [19c]

PL/SQL Oracle

Discussions similaires

Partager

Partager